Can we plot RSI of one stock/indicator on a different stock?

[Futures_Beginner]

Can we plot RSI of one stock/indicator on a different stock?

Friends,

checking if there is a possibility of plotting RSI of one stock on a different stocks chart in TOS?

Ex: I like to see ES RSI on TSLA or NVDA.

If yes, how can I do that

 

[TreydingStocks]

Close() has a parameter of 'symbol' and RSI() has a parameter of 'price' so you simply nest the reference.

Example:
Def googRSI = rsi(price = close(symbol = "goog"));

 

[Futures_Beginner]

Close() has a parameter of 'symbol' and RSI() has a parameter of 'price' so you simply nest the reference.

Example:
Def googRSI = rsi(price = close(symbol = "goog"));

Thanks. Good to know.

But when I tried to plot I dont see the line the usual way we see for RSI.
I see the line is fragmented when I tired to plot the RSI of VIX in in the lower section on a TSLA 5 Min chart

am I doing it wrong?

INPUT LOOKUP_RSI = "VIX";
def LOOKUPRSI= rsi(price = close(symbol = LOOKUP_RSI), length = 5);
PLOT OBRSI = LOOKUPRSI;

 

[TreydingStocks]

To plot a study in the separate lower sections on ThinkorSwim you need to add

"Declare lower;"

Add that to the top of your code and I believe it'll solve the issue you're asking

 

[SleepyZ]

To plot a study in the separate lower sections on ThinkorSwim you need to add

"Declare lower;"

Add that to the top of your code and I believe it'll solve the issue you're asking

Since VIX does not plot bars at the same times as TSLA, we need to provide values for missing bars. To do this, we need to use a 'recursive' to have the missing bars use the close price of the prior bar's close:
def c = if isnan( close(symbol = LOOKUP_RSI)) then ] else close(symbol = LOOKUP_RSI);
As the RSI uses an average, this change is also needed to provide the missing bars average values.

Here is the revised code with added overbought and oversold lines and RSI line coloring

The image shows the TSLA with the revised code and the VIX with the TOS native RSI indicator

declare lower;

input LOOKUP_RSI = "VIX";
def c = if IsNaN( close(symbol = LOOKUP_RSI)) then c[1] else  close(symbol = LOOKUP_RSI);
def LOOKUPRSI = RSI(price = c, length = 5);
plot OBRSI = LOOKUPRSI;

input over_Bought = 70;
input over_Sold   = 30;
plot OverSold   = over_Sold;
plot OverBought = over_Bought;

#

 

[Futures_Beginner]

Since VIX does not plot bars at the same times as TSLA, we need to provide values for missing bars. To do this, we need to use a 'recursive' to have the missing bars use the close price of the prior bar's close:
def c = if isnan( close(symbol = LOOKUP_RSI)) then ] else close(symbol = LOOKUP_RSI);
As the RSI uses an average, this change is also needed to provide the missing bars average values.

Here is the revised code with added overbought and oversold lines and RSI line coloring

The image shows the TSLA with the revised code and the VIX with the TOS native RSI indicator

Thanks...makes sense.

Getting error while using your code. anything missing here?

INPUT LOOKUP_RSI = "VIX";
def LOOKUPRSI= rsi(price = close(symbol = LOOKUP_RSI), length = 5);
def c = if isnan(close(symbol = LOOKUP_RSI)) then ] else close(symbol = LOOKUP_RSI);
PLOT OBRSI = LOOKUPRSI;

 

[SleepyZ]

Thanks...makes sense.

Getting error while using your code. anything missing here?

INPUT LOOKUP_RSI = "VIX";
def LOOKUPRSI= rsi(price = close(symbol = LOOKUP_RSI), length = 5);
def c = if isnan(close(symbol = LOOKUP_RSI)) then ] else close(symbol = LOOKUP_RSI);
PLOT OBRSI = LOOKUPRSI;

This is the code with line coloring

declare lower;

input LOOKUP_RSI = "VIX";
def c = if IsNaN( close(symbol = LOOKUP_RSI)) then c[1] else  close(symbol = LOOKUP_RSI);
def LOOKUPRSI = RSI(price = c, length = 5);
plot RSI = LOOKUPRSI;

input over_Bought = 70;
input over_Sold   = 30;
plot OverSold   = over_Sold;
plot OverBought = over_Bought;

RSI.DefineColor("OverBought", GetColor(5));
RSI.DefineColor("Normal", GetColor(7));
RSI.DefineColor("OverSold", GetColor(1));
RSI.AssignValueColor(if RSI > over_Bought then RSI.color("OverBought") else if RSI < over_Sold then RSI.color("OverSold") else RSI.color("Normal"));



#

 

[Futures_Beginner]

This is the code with line coloring

Thanks a ton. Reviewing while we talk.

 

[Futures_Beginner]

Thanks a ton. Reviewing while we talk.

@SleepyZ ~ This is great stuff. working as expected.

If I can ask can you add a code in the upper chart to draw a rectangle (previous 2 bars and current bar) if VIX RSI is overbought (say > 80) or VIX RSI is oversold (say < 20) and color the boxes differently (not to worry it is complicated)

 

[SleepyZ]

@SleepyZ ~ This is great stuff. working as expected.

If I can ask can you add a code in the upper chart to draw a rectangle (previous 2 bars and current bar) if VIX RSI is overbought (say > 80) or VIX RSI is oversold (say < 20) and color the boxes differently (not to worry it is complicated)

This will plot dashed lines over the 3 bars you wanted at their highest(highs)/lowest(lows) with changeable colors (green for above overbought (UP) and red for below oversold (DN)) at the input screen. The extended portions of the dashed lines beyond three bars are colored black to match RTHours background and dark_gray to match the chart's ExtendHours to attempt to hide them.

input LOOKUP_RSI = "VIX";
def c = if IsNaN( close(symbol = LOOKUP_RSI)) then c[1] else  close(symbol = LOOKUP_RSI);
def LOOKUPRSI = RSI(price = c, length = 5);
def RSI = LOOKUPRSI;

input overBought = 80;
input overSold   = 20;
input lineweight = 2;
input arrows     = no;

def rth = SecondsFromTime(0930) >= 0 and SecondsTillTime(1600) > 0;

plot up = RSI crosses above overBought;
up.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
up.SetHiding(!arrows);

def uph = if up[-2] then Highest(high[-2], 3) else uph[1];
def upl = if up[-2] then Lowest(low[-2], 3) else upl[1];

plot xuph = uph;
xuph.SetPaintingStrategy(PaintingStrategy.DASHES);
xuph.AssignValueColor(if up or up[-1] or up[-2] then GlobalColor("UP") else if rth then GlobalColor("RTH") else GlobalColor("EXT"));
xuph.SetLineWeight(lineweight);

plot xupl = upl;
xupl.SetPaintingStrategy(PaintingStrategy.DASHES);
xupl.AssignValueColor(if up or up[-1] or up[-2] then GlobalColor("UP") else if rth then GlobalColor("RTH") else GlobalColor("EXT"));
xupl.SetLineWeight(lineweight);

plot dn = RSI crosses below overSold;
dn.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
dn.SetHiding(!arrows);

def dnh = if dn[-2] then Highest(high[-2], 3) else dnh[1];
def dnl = if dn[-2] then Lowest(low[-2], 3) else dnl[1];

plot xdnh = dnh;
xdnh.SetPaintingStrategy(PaintingStrategy.DASHES);
xdnh.AssignValueColor(if dn or dn[-1] or dn[-2] then GlobalColor("DN") else if rth then GlobalColor("RTH") else GlobalColor("EXT"));
xdnh.SetLineWeight(lineweight);

plot xdnl = dnl;
xdnl.SetPaintingStrategy(PaintingStrategy.DASHES);
xdnl.AssignValueColor(if dn or dn[-1] or dn[-2] then GlobalColor("DN") else if rth then GlobalColor("RTH") else GlobalColor("EXT"));
xdnl.SetLineWeight(lineweight);

DefineGlobalColor("UP", Color.GREEN);
DefineGlobalColor("DN", Color.RED);
DefineGlobalColor("RTH", Color.BLACK);
DefineGlobalColor("EXT", Color.DARK_GRAY);

#

 

[Futures_Beginner]

@SleepyZ ~ Excellent Sir.
Hope this should work. Will check how this works real time

 

[majidg]

This is the code with line coloring

Hi SleepyZ, can the above be written for any symbol?

 

[SleepyZ]

Hi SleepyZ, can the above be written for any symbol?

Go to the input screen and type in LookupRSI the new symbol and hit enter

The image shows AAL chart using UAL RSI