Bollinger Band Opening Watchlist Alert?

[DasAbs]

I have a BB Watchlist on TC2000 I would like to replicate on ToS for a Strategy of Volatility Rising
When Upper BB and Lower BB are both widening at a certain rate, it triggers a Tickle, and it is very very useful when applied to several Timefframes, eg, i have it for 1m, 15m, Hr and Day. when 3 or 4 are lit, things are really moving!

I Share here the coding for TC2000, as well as an image of the Watchlist (it may be useful and profitable for many)

Maybe in ToS it wont show a tickle, but change to white background above certain level might be useful

I hope someone could help me to code it for ToS, it is a very simple, yet useful and powerful indicator

thanks Folks!!

 

[halcyonguy]

I have a BB Watchlist on TC2000 I would like to replicate on ToS for a Strategy of Volatility Rising
When Upper BB and Lower BB are both widening at a certain rate, it triggers a Tickle, and it is very very useful when applied to several Timefframes, eg, i have it for 1m, 15m, Hr and Day. when 3 or 4 are lit, things are really moving!

I Share here the coding for TC2000, as well as an image of the Watchlist (it may be useful and profitable for many)

Maybe in ToS it wont show a tickle, but change to white background above certain level might be useful

I hope someone could help me to code it for ToS, it is a very simple, yet useful and powerful indicator

thanks Folks!!

here is an upper study to experiment with, tweak it, get the formulas how you want it.
then come back and ask for a MTF version

this one is not MTF

#bollband_mtf_slope_tickle

#https://usethinkscript.com/threads/bollinger-band-opening-watchlist-alert.19549/
#--------------------------------------------
def na = double.nan;
def bn = barnumber();

# BollingerBands
input price = close;
input displace = 0;
input length = 20;
input Num_Dev_Dn = -2.0;
input Num_Dev_up = 2.0;
input averageType = AverageType.Simple;

def sDev = stdev(data = price[-displace], length = length);

plot MidLine = MovingAverage(averageType, data = price[-displace], length = length);
plot LowerBand = MidLine + num_Dev_Dn * sDev;
plot UpperBand = MidLine + num_Dev_Up * sDev;

LowerBand.SetDefaultColor(GetColor(0));
MidLine.SetDefaultColor(GetColor(1));
UpperBand.SetDefaultColor(GetColor(5));


# determine lines slopes
def upper_slope = (UpperBand - UpperBand[1]);
def lower_slope = (LowerBand - LowerBand[1]);
def mid_slope = (midline - midline[1]);

# check mid slope and determine price direction

# calc % chg of slope
def upper_slope_chg = round(100*(upper_slope/UpperBand[1]), 2);
def lower_slope_chg = round(100*(lower_slope/LowerBand[1]),2);
def mid_slope_chg = round(100*(mid_slope/midline[1]),2);

input per_limit = 0.07;

def up = (mid_slope > 0
 and upper_slope_chg > per_limit
 and lower_slope_chg < -per_limit);

def dwn = (mid_slope < 0
 and upper_slope_chg > per_limit
 and lower_slope_chg < -per_limit);

plot zu = if up then low * 0.998 else na;
#plot zu = if up then midline else na;
zu.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
zu.SetDefaultColor(Color.cyan);
zu.setlineweight(3);
zu.hidebubble();


plot zd = if dwn then high * 1.002 else na;
#plot zd = if dwn then midline else na;
zd.SetPaintingStrategy(PaintingStrategy.ARROW_down);
zd.SetDefaultColor(Color.yellow);
zd.setlineweight(3);
zd.hidebubble();



input test_slopes = no;
addchartbubble(test_slopes, upperband,
 upper_slope + "\n" +
 upper_slope_chg + " %"
, color.yellow, yes);

addchartbubble(test_slopes, lowerband,
 lower_slope + "\n" +
 lower_slope_chg + " %"
, color.yellow, no);

addchartbubble(test_slopes, midline,
 mid_slope + "\n" +
 mid_slope_chg + " %"
, color.yellow, no);


#plot zu = expaverage(upperband, 3);
#plot zd = expaverage(lowerband, 3);
#