Average Volume

[K_O_Trader]

Im looking for a script that draws a strait line on todays chart of what the average volume is for all of the previous day 5 minute candles are, but only while the market was open, for example there is 78 5 minute candles while the market is open, I want the average of those 5 minute candles

 

[SleepyZ]

Im looking for a script that draws a strait line on todays chart of what the average volume is for all of the previous day 5 minute candles are, but only while the market was open, for example there is 78 5 minute candles while the market is open, I want the average of those 5 minute candles

See if this helps

#Define Days
def ymd = GetYYYYMMDD();
def candles  = !IsNaN(close);
def capture  = candles and ymd != ymd[1];
def dayCount = CompoundValue(1, if capture then dayCount[1] + 1 else dayCount[1], 0);
def thisDay  = (HighestAll(dayCount) - dayCount) ;

#Define Regular Trading Hours
def rth = Between(GetTime(), RegularTradingStart(GetYYYYMMDD()), RegularTradingEnd(GetYYYYMMDD()));

#Define Number of Bars based upon Chart Aggregation
def bars = 390 / (GetAggregationPeriod() / 60000);

#Define RTH volume for Prior Day to Current Day
def rthvol = if thisDay == 1 and rth then rthvol[1] + volume else rthvol[1];

#Plot Prior Day's RTH Average Volume on Today's Chart
plot prior_rth_volume = rthvol / bars;
AddLabel(1, "Prior Day Total RTH Volume: " + rthvol + " /  " + bars + " Bars  = Average Volume: " + round(prior_rth_volume,0), color.cyan);

 

[halcyonguy]

Im looking for a script that draws a strait line on todays chart of what the average volume is for all of the previous day 5 minute candles are, but only while the market was open, for example there is 78 5 minute candles while the market is open, I want the average of those 5 minute candles

sometimes i think i see things a little differently.
here is my version,

i took this
...a straight line on todays chart of the average volume for all of the previous day 5 minute candles...
to mean,
find an average from the previous bars of today. not previous days.

as more volume bars appear on the current day, an average of just those is calculated.

# vol_avg_per_day_0

declare on_volume;

def istoday = if GetLastDay() == GetDay() then 1 else 0;
def diffday = if getDay()[1] != GetDay() then 1 else 0;

def na = Double.NaN;
def bn = BarNumber();
def lastbn = HighestAll( if IsNaN(close) then 0 else bn);
def v = volume;

#Define Regular Trading Hours
def rth = Between(GetTime(), RegularTradingStart(GetYYYYMMDD()), RegularTradingEnd(GetYYYYMMDD()));

def vol_ttl = if diffday then v
  else if rth then vol_ttl[1] + v
  else 0;

def daybarcnt = if diffday then 1
  else if rth then daybarcnt[1] + 1
  else 0;

def volavg = if daybarcnt > 0 then (vol_ttl / daybarcnt) else 0;

# horz avg
def curr_avg = if diffday then GetValue( volavg , -(lastbn - bn) )
  else curr_avg[1];

# draw a horz line, of the vol avg, on current bar
plot horz_avg = if istoday and !isnan(close) then curr_avg else na;
horz_avg.setdefaultcolor(color.lime);

# draw vol avg for today
plot today_avg = if istoday and !isnan(close) then volavg else na;
today_avg.setdefaultcolor(color.magenta);
#

purple line, is average for today
lime line, horizontal line from the average on current bar