ATR Trailing Stop

[SHJ]

Hi Team,

I am trying to use the following script in a way that the color of the candles will change when candles are "at or closer" to the bottoms and tops. Therefore, can somebody help me add an input field so the ATR Trailing Stop length can be customized (or any other feature that can provide a better result)?

def st = ATRTrailingStop().state;
AssignPriceColor(if st == 1
then GetColor(6)
else if st == 2
then GetColor(5)
else Color.CURRENT);
def bs = !IsNaN(close) and ATRTrailingStop().BuySignal == yes;
def ss = !IsNaN(close) and ATRTrailingStop().SellSignal == yes;

 

[halcyonguy]

Hi Team,

I am trying to use the following script in a way that the color of the candles will change when candles are "at or closer" to the bottoms and tops. Therefore, can somebody help me add an input field so the ATR Trailing Stop length can be customized (or any other feature that can provide a better result)?

def st = ATRTrailingStop().state;
AssignPriceColor(if st == 1
then GetColor(6)
else if st == 2
then GetColor(5)
else Color.CURRENT);
def bs = !IsNaN(close) and ATRTrailingStop().BuySignal == yes;
def ss = !IsNaN(close) and ATRTrailingStop().SellSignal == yes;

you are trying to read data from another study, that has a variable defined by def.
. def st = ATRTrailingStop().state;
. ATRTrailingStop().BuySignal

can't do that.
can only read plot variables.

if you want to interact with the study, copy all of the study code and paste it into a new study. then you can use all the variables.

------------------

i think you want to check when a candle is close to the trail dotted line.
and you want to alter input parameters.
so what i do is go to the original study, ATRTrailingStop, and copy the inputs and the plots.
then i know what i can work with.

when close is within (0.15% x close) of the trail line, candles will be drawn in blue or yellow.

#atr_trail_stop_chgbarcolor

#https://usethinkscript.com/threads/atr-trailing-stop.20754/
#ATR Trailing Stop

def na = double.nan;
def bn = barnumber();

#copy inputs from orig, ATRTrailingStop
input trailType = {default modified, unmodified};
input ATRPeriod = 5;
input ATRFactor = 3.5;
input firstTrade = {default long, short};
input averageType = AverageType.WILDERS;

# trail line
def trailline = ATRTrailingStop(trailType, ATRPeriod, ATRFactor, firstTrade, averageType);

plot z = trailline;
z.SetPaintingStrategy(PaintingStrategy.POINTS);
z.AssignValueColor(if trailline < close then GetColor(1) else GetColor(0));

# is close near trail line?
input near_percent = 0.15;
def near_dollars = (close * near_percent/100);

def isnear_topline = if (close < trailline and (close + near_dollars) > trailline) then 1 else 0;
def isnear_botline = if (close > trailline and (close - near_dollars) < trailline) then 1 else 0;

AssignPriceColor(
 if isnear_topline then color.blue
 else if isnear_botline then color.yellow
 else color.current);

# ----------------

input test_near_triangles = no;
plot zup = if test_near_triangles and isnear_topline then high*1.002 else na;
zup.SetPaintingStrategy(PaintingStrategy.triangles);
zup.SetDefaultColor(Color.white);
zup.setlineweight(5);
zup.hidebubble();

input test_show_per_line = no;
plot zper = if !test_show_per_line then na
 else if close < trailline then (close + near_dollars)
 else (close - near_dollars); 
#