ATR static line as stoploss and profit target. NOT trailing stop

[3AMBH]

This code is very helpful. Thanks for coding it for us. How could I modify it so when a trade is placed the levels will show across the chart and NOT just over each bar?

I use the code today and the levels showed a small mark above the first candle, etc. I am using the code on an options chart. Thanks

 

[cmenzel]

Hi,

I am looking to create a strategy were the value of the ATR on the bar of my entry price is my stoploss and profit target, but since the ATR value is changing from candle to candle, it becomes the classic ATR trailing stop.

Here is the code I have but havent figure how to only take the value the atr had on my entry price.

#ATR

def entryPrice = entryPrice();

input length = 14;
input averageType = AverageType.WILDERS;

def ATR = MovingAverage(averageType, TrueRange(high, close, low), length);

plot SL= entryprice + (ATR * 1.5);
plot PT = entryprice - (ATR * 3) ;

If anyone could help I would really appreciate it!

 

[mashume]

assuming you have some sort of signal for long or short entry, you can assign a value to an array like this to be able to reference it later:

def signal = if condition then 1 else 0;
def one_atr = if signal == 1 then ATR() else one_atr[1];

plot sl = entryprice + ( one_atr * 1.5 );
plot pt = entryprice - ( one_atr * 3 );

I've had code like this running previously, so the idea should work.

-mashume

 

[cmenzel]

Thanks @mashume! this is exactly what I was looking for. Is there a way to add labels to the values?

 

[mashume]

since I trade futures, tick size and tick value are important to me... but this should work on anything, I think:

addLabel(yes, " ATR: " + one_atr + ",   1 ATR Value: " + asDollars(one_atr / tickSize() * TickValue()) + "    ", color.blue);

-mashume

 

[Vorlauf]

I tend to use a multiple of ATR as a stop loss. Does anyone have or know of an ATR stop loss % label that would calculate the percentage from the current price?

 

[MerryDay]

I tend to use a multiple of ATR as a stop loss. Does anyone have or know of an ATR stop loss % label that would calculate the percentage from the current price?

start reading from here:
https://usethinkscript.com/threads/...it-target-not-trailing-stop.11138/#post-97495
https://usethinkscript.com/threads/search-the-forum.12626/

 

[Docbrown83]

Hi guys,

Just looking for a something to script a horizontal line that would plot a stop loss at 1.5 ATR of the current candle close and a first Target price of 1 ATR of the same candle close.

I tried using the above, but I don't have a "condition". I tried plotting without, but I don't see anything. This may be super easy but I am relatively new to this and would appreciate any help.

Cheers!

 

[MerryDay]

Hi guys,

Just looking for a something to script a horizontal line that would plot a stop loss at 1.5 ATR of the current candle close and a first Target price of 1 ATR of the same candle close.

I tried using the above, but I don't have a "condition". I tried plotting without, but I don't see anything. This may be super easy but I am relatively new to this and would appreciate any help.

Cheers!

# #################################
# ATR Stop & Target based on current candle
# requested by Docbrown83
input ATRStopMultiple = 1.5;
input ATRTargetMultiple = 1.0;
input length = 14;
input averageType = AverageType.WILDERS;
def ATR = MovingAverage(averageType, TrueRange(high, close, low), length);
def Target = close + (ATR * ATRTargetMultiple);
def Stop =  close - (ATR * ATRStopMultiple) ;

# #################################
# Charting & Formatting
addlabel(yes, "TARGET: " + round(Target,2) +" | "+ " STOP: " + round(Stop,2) , color.dark_orange);
plot TargetLine = HighestAll(if IsNaN(Close[-1]) then Target else double.NaN);
plot StopLine = HighestAll(if IsNaN(Close[-1]) then Stop else double.NaN);

 

[Docbrown83]

Awesome! You have made my weekend. Thank you so much

 

[TigerWares]

Is there a way to input your actual buy price and have it calculate the SL & Targets? And whether it is a long or short trade?

 

[MerryDay]

Is there a way to input your actual buy price and have it calculate the SL & Targets? And whether it is a long or short trade?

# #################################
# ATR Stop & Target based on buy price
# requested by tigerWares
input ATRStopMultiple = 1.5;
input ATRTargetMultiple = 1.0;
input length = 14;
input averageType = AverageType.WILDERS;
def ATR = MovingAverage(averageType, TrueRange(high, close, low), length);
def BuyPrice = GetAveragePrice();
def PL = GetOpenPL();
def Target = BuyPrice + (ATR * ATRTargetMultiple);
def Stop =  BuyPrice - (ATR * ATRStopMultiple) ;

# #################################
# Charting & Formatting
addlabel(yes, "TARGET: " + round(Target,2) +" | "+ " STOP: " + round(Stop,2) , color.dark_orange);
plot TargetLine = HighestAll(if IsNaN(Close[-1]) then Target else double.NaN);
plot StopLine = HighestAll(if IsNaN(Close[-1]) then Stop else double.NaN);
#Sase
#Add bubble above the the current candle if there is an open position
#If PL is positive then green else yellow
AddChartBubble (GetQuantity () != 0 and isnan(close[-1]), high, "buy price" +"\n"+ round(BuyPrice,2),if PL > 0 Then Color.GREEN Else Color.YELLOW, Yes);

 

[khpro59]

View attachment 17801

# #################################
# ATR Stop & Target based on buy price
# requested by tigerWares
input ATRStopMultiple = 1.5;
input ATRTargetMultiple = 1.0;
input length = 14;
input averageType = AverageType.WILDERS;
def ATR = MovingAverage(averageType, TrueRange(high, close, low), length);
def BuyPrice = GetAveragePrice();
def PL = GetOpenPL();
def Target = BuyPrice + (ATR * ATRTargetMultiple);
def Stop =  BuyPrice - (ATR * ATRStopMultiple) ;

# #################################
# Charting & Formatting
addlabel(yes, "TARGET: " + round(Target,2) +" | "+ " STOP: " + round(Stop,2) , color.dark_orange);
plot TargetLine = HighestAll(if IsNaN(Close[-1]) then Target else double.NaN);
plot StopLine = HighestAll(if IsNaN(Close[-1]) then Stop else double.NaN);
#Sase
#Add bubble above the the current candle if there is an open position
#If PL is positive then green else yellow
AddChartBubble (GetQuantity () != 0 and isnan(close[-1]), high, "buy price" +"\n"+ round(BuyPrice,2),if PL > 0 Then Color.GREEN Else Color.YELLOW, Yes);

This is awesome, Merry. This line right here is gold: (GetQuantity () != 0 and isnan(close[-1]), high, "buy price" +"\n"+ round(BuyPrice,2),if PL > 0 Then Color.GREEN Else Color.YELLOW, Yes);

So the plot lines will only show up if holding a position, looks like?