AGAIG Renko Charting Labels For ThinkOrSwim

[Pooze]

@cando13579 and @csricksdds you guys should try your hand at developing a renko upper chart with your indicator work. I'm curious to see what both of you could do with the format.

 

[csricksdds]

AGAIG RENKO CHARTING LABELS​

Many traders use Renko Charting for determining direction. However, on TOS it is sometimes onerous trying to count bricks (they don’t size larger/smaller on TOS) and so I have taken the parameters of RENKO and developed a chart label that lets you know if RENKO is in an upward trend, static, or in a lower trend including how many bars movement has made.

This indicator behaves like a scorecard that only refreshes on the actual event, rather than a live counter. On a flip the label resets to 1 and the label switches color/direction immediately according to the Renko parameters. You can turn the bricks on/off in the “Added studies and strategies” by going to the AGAIG_RenkoCurrentLabel and click on the wheel on the right and on “show brick line” dropdown click on Yes or No.

The label is best suited for at-a-glance monitoring.

Indicator Link: http://tos.mx/!u688FL6H

# Renko Direction Label (live count of current trend by AGAIG)
declare upper;

input boxSize = 1.0;
input showBrickLine = yes;
input LabelSize     = fontsize.large;
input LabelLocation = location.bottom_left;

def price = close;

rec brick = CompoundValue(1,
    if IsNaN(brick[1])
    then Round(price / boxSize) * boxSize
    else if price - brick[1] >= boxSize
         then brick[1] + boxSize * Floor((price - brick[1]) / boxSize)
    else if brick[1] - price >= boxSize
         then brick[1] - boxSize * Floor((brick[1] - price) / boxSize)
    else brick[1],
    Round(price / boxSize) * boxSize
);

rec dir = CompoundValue(1,
    if brick > brick[1] then 1
    else if brick < brick[1] then -1
    else dir[1],
    0
);

def changed = dir != dir[1] and !IsNaN(dir[1]);

rec barsInTrend = CompoundValue(1,
    if changed then 1
    else barsInTrend[1] + 1,
    1
);

# --- Optional brick overlay line ---
plot Renko = if showBrickLine then brick else Double.NaN;
Renko.SetPaintingStrategy(PaintingStrategy.SQUARES);
Renko.SetLineWeight(3);
Renko.AssignValueColor(
    if dir == 1 then Color.GREEN
    else if dir == -1 then Color.RED
    else Color.GRAY
);

# --- Label: live count of the current (just-started) trend ---
AddLabel(
    dir != 0,
    "RENKO " + (if dir == 1 then "UP" else "DOWN") + " " + barsInTrend + " bars",
    if dir == 1 then Color.GREEN
    else if dir == -1 then Color.RED
    else Color.YELLOW, LabelLocation, LabelSize
);

@Pooze

 

[useThinkScript]

Sadly, ToS RENKO bars have issues.
Read more:
https://usethinkscript.com/threads/renko-or-tick-chart-for-trading-oil-futures.22292/#post-162064
https://usethinkscript.com/threads/renko-or-tick-chart-for-trading-oil-futures.22292/#post-162852

Also many studies cannot be added to RENKO charts:
https://usethinkscript.com/threads/...tick-range-renko-charts-in-thinkorswim.18400/

Some fixes:
https://usethinkscript.com/threads/renko-tick-chart-not-updating-promptly.13972/#post-116344

 

[csricksdds]

Sadly, ToS RENKO bars have issues.
Read more:
https://usethinkscript.com/threads/renko-or-tick-chart-for-trading-oil-futures.22292/#post-162064
https://usethinkscript.com/threads/renko-or-tick-chart-for-trading-oil-futures.22292/#post-162852

Also many studies cannot be added to RENKO charts:
https://usethinkscript.com/threads/...tick-range-renko-charts-in-thinkorswim.18400/

Some fixes:
https://usethinkscript.com/threads/renko-tick-chart-not-updating-promptly.13972/#post-116344

That's why I just used some of the parameters and a label for direction?