Add mid-price line to DailyHighLow study

[ARL]

Greetings! I'd like to add a mid-price horizontal line to the TOS study DailyHighLow which would indicate the average price of the prior trading day's high and low price. This would probably be a simple modification for an experienced coder and I would appreciate the help. I didn't find anything in the forums but maybe I overlooked an existing post that addresses this. Just direct me there, please, if that's the case. Here's the existing DailyHighLow script:

input aggregationPeriod = AggregationPeriod.DAY;
input length = 1;
input displace = -1;
input showOnlyLastPeriod = no;

plot DailyHigh;
plot DailyLow;
if showOnlyLastPeriod and !IsNaN(close(period = aggregationPeriod)[-1]) {
DailyHigh = Double.NaN;
DailyLow = Double.NaN;
} else {
DailyHigh = Highest(high(period = aggregationPeriod)[-displace], length);
DailyLow = Lowest(low(period = aggregationPeriod)[-displace], length);
}

DailyHigh.SetDefaultColor(GetColor(4));
DailyHigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
DailyLow.SetDefaultColor(GetColor(4));
DailyLow.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

 

[Pensar]

@ARL

input aggregationPeriod = AggregationPeriod.DAY;
input length = 1;
input displace = -1;
input showOnlyLastPeriod = no;

plot DailyHigh;
plot DailyLow;
plot DailyMid;
if showOnlyLastPeriod and !IsNaN(close(period = aggregationPeriod)[-1]) {
DailyHigh = Double.NaN;
DailyLow = Double.NaN;
DailyMid = Double.NaN;
} else {
DailyHigh = Highest(high(period = aggregationPeriod)[-displace], length);
DailyLow = Lowest(low(period = aggregationPeriod)[-displace], length);
DailyMid = (DailyHigh + DailyLow)/2;
}

DailyHigh.SetDefaultColor(GetColor(4));
DailyHigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
DailyLow.SetDefaultColor(GetColor(4));
DailyLow.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
DailyMid.SetDefaultColor(GetColor(4));
DailyMid.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

 

[ARL]

Great! Thank you, Pensar. Looking at the code, it makes perfect sense & once again learned something about thinkscript. =A=

 

[johns52]

I modified this to add the Prior Day's Close and Labels. Hope you find it useful. Prior Day's Close is often an important S/R line.

#
# JS_Prior_HighLowMidClose with Labels
#
input showLabel = yes;

input aggregationPeriod = AggregationPeriod.DAY;
input length = 1;
input displace = -1;
input showOnlyLastPeriod = no;

plot DailyHigh;
plot DailyLow;
plot DailyMid;
plot DailyClose;

if showOnlyLastPeriod and !IsNaN(close(period = aggregationPeriod)[-1]) {
    DailyHigh = Double.NaN;
    DailyLow = Double.NaN;
    DailyMid = Double.NaN;
    DailyClose = Double.NaN;

} else {
    DailyHigh = Highest(high(period = aggregationPeriod)[-displace], length);
    DailyLow = Lowest(low(period = aggregationPeriod)[-displace], length);
    DailyMid = (DailyHigh + DailyLow) / 2;
    DailyClose = close(period = aggregationPeriod)[-displace];
}

DailyHigh.SetDefaultColor(GetColor(1));
DailyHigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
DailyLow.SetDefaultColor(GetColor(2));
DailyLow.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
DailyMid.SetDefaultColor(GetColor(3));
DailyMid.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
DailyClose.SetDefaultColor(GetColor(4));
DailyClose.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

def aboveHigh = Close > DailyHigh;
def aboveMid = Close > DailyMid and Close <= DailyHigh;
def belowMid = Close < DailyMid and close >= DailyLow;
def belowLow = close < DailyLow;

AddLabel(showLabel, if aboveHigh then "Day>HI" else if aboveMid then "Day>ML" else if belowMid then "Day<ML" else "Day<LO", if aboveHigh then color.green else if aboveMid then color.light_Green else if belowMid then color.Light_red else color.red);