#//Indicator for TOS
#// © QuantAlgo
#indicator(title="Adaptive Trend Flow [QuantAlgo]", overlay=true, max_labels_count=500)
# Converted by Sam4Cok@Samer800 - 03/2025
input timeframe = AggregationPeriod.MIN;
input ColorBars = yes; # "Color Bars?"
input BackgroundColor = yes; # "Background Color?"
input showSignals = yes; # "Show Signals?"
input source = FundamentalType.HLC3;
input MovAvgType = AverageType.EXPONENTIAL;
input mainLength = 10; # "Main Length"
input SmoothingLength = 14; # "Smoothing Length"
input sensitivity = 2.0; # "Sensitivity"
def na = Double.NaN;
def last = isNaN(close);
def pos = Double.POSITIVE_INFINITY;
def neg = Double.NEGATIVE_INFINITY;
def cap = GetAggregationPeriod();
def tf = Max(cap, timeframe);
def typical = Fundamental(FundamentalType = source, Period = tf);
#--Col
DefineGlobalColor("up", CreateColor(0, 37, 0));
DefineGlobalColor("dn", CreateColor(37, 0, 0));
#calculate_trend_levels() =>
def fast_ema = MovingAverage(MovAvgType, typical, mainLength);
def slow_ema = MovingAverage(MovAvgType, typical, mainLength * 2);
def basis = (fast_ema + slow_ema) / 2;
def vol = stdev(typical, mainLength);
def smooth_vol = MovingAverage(MovAvgType, vol, SmoothingLength);
def upper = basis + (smooth_vol * sensitivity);
def lower = basis - (smooth_vol * sensitivity);
#get_trend_state(upper, lower, basis) =>
def level;
def trend;
if !level[1] {
trend = if close(Period = tf) > basis then 1 else -1;
level = if trend == 1 then lower else upper;
} else if trend[1] == 1 {
if close(Period = tf) < lower {
trend = -1;
level = upper;
} else {
trend = trend[1];
level = lower;
}
} else {
if close(Period = tf) > upper {
trend = 1;
level = lower;
} else {
trend = trend[1];
level = upper;
}
}
#// Background gradient coloring
def intensity;
def intensity1;
def prev_trend;
#// Reset intensity on trend change
if trend != prev_trend[1] {
intensity1 = 0;
prev_trend = trend;
} else {
intensity1 = intensity[1];
prev_trend = trend;
}
#// Increment intensity based on trend
intensity = if trend == 1 then min(intensity1 + 3, 20) else
if trend == -1 then min(intensity1 + 3, 20) else intensity1;
# VISUALIZATION
#// Signal detection
def long_signal = trend == 1 and trend[1] == -1;
def short_signal = trend == -1 and trend[1] == 1;
#// Plot average/basis line
plot basisLine = basis;
basisLine.SetLineWeight(2);
basisLine.AssignValueColor(if trend==1 then CreateColor(0, intensity * 12.75, intensity * 12.75) else
CreateColor(intensity * 12.75, 0, intensity * 12.75));
#// Plot trend line with breaks
plot trendLine = level;
trendLine.AssignValueColor(if close > level then Color.GREEN else Color.RED);
AddCloud(basisLine, trendLine, Color.DARK_GREEN, Color.DARK_RED);
def int = if BackgroundColor then intensity else na;
def tr = if !last then trend else na;
AddCloud(if tr == 1 and (int > 0 or int[-1] > 0) then pos else na, neg, GlobalColor("up"));
AddCloud(if tr == 1 and (int > 10 or int[-1] > 10) then pos else na, neg, GlobalColor("up"));
AddCloud(if tr ==-1 and (int > 0 or int[-1] > 0) then pos else na, neg, GlobalColor("dn"));
AddCloud(if tr ==-1 and (int > 10 or int[-1] > 10) then pos else na, neg, GlobalColor("dn"));
#// Add labels for crossovers
def crosUp = (close > level) and (close[1] <= level[1]);
def crosDn = (close < level) and (close[1] >= level[1]);
def sigDn = if showsignals and crosDn then level else na;
def sigUp = if showsignals and crosUp then level else na;
AddChartBubble(sigDn and !crosUp[-1], sigDn, "S", Color.MAGENTA);
AddChartBubble(sigUp and !crosDn[-1], sigUp, "B", Color.CYAN, no);
#/ Bar Coloring
AssignPriceColor(if !ColorBars then Color.CURRENT else
if trend == 1 then CreateColor(0, intensity * 12.75, 0) else CreateColor(intensity * 12.75, 0, 0));
#-- END of CODE
