Adaptive Aroon, MACD, Schaff Trend Cycle, and Williams %R Indicators for ThinkOrSwim

S

Sesqui

Member
VIP
Screenshot from 2025-08-29 09-10-23.png


The scripts for the indicators are provided below and enable the user to make them adaptive using the TOS AutoCorrelationPeriodogram or to tune them to the market dominant cycle using the Band-Pass Filter method from CH 5 of Dr Ehlers book, "Cycle Analytics for Traders".

The screenshot above shows what they look like on the lower portion of the chart when using the TOS Periodogram to make them adaptive. The following screenshot shows what they look like when the dominant cycle is more precisely obtained using the Band-Pass Filter method per CH 5 of Dr Ehlers' book, "Cycle Analytics for Traders":
1760815580992.png


Here is the script code for each.

Adaptive Aroon Indicator:

CSS: 
# Adaptive Aroon indicator script by Sesqui 
# [29AUG2025]: TOS periodogram method used to make it adaptive. However, TOS does not support matrices
# as needed to precisely nail down the dominant cycle periods. Furthermore, it take a lot of computational 
# power and can bog down some computers. As a result this method is not recommended
#
# [18OCT2025]: Sesqui added a more precise method of obtaining the dominant cycle periods, the Band-Pass
# filter method per ch5 of Dr Ehlers' book, "Cycle Analytics for Traders". When tested against sinewaves
# across a wide range of periods, this method obtains precise dominant cycle period values and does not
# appear to bog down the computer in TOS.  

declare lower;
input Beta = 1.0;
input showUpDownLines = no;
#===========================================================================================================================
script GetCycle { 
    # Returns the dominant market cycle for use in adaptive indicators

    #------------------------------------------
    # Charles Schwab & Co. (c) 2016-2025
    #
    def lag = 48;
    def x = EhlersRoofingFilter("cutoff length" = 8, "roof cutoff length" = 48);
    def cosinePart = fold i = 3 to 48 with cosPart do cosPart + (3 * (x * GetValue(x, i) + GetValue(x, 1) * GetValue(x, i + 1) + GetValue(x, 2) * GetValue(x, i + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, i) * GetValue(x, i) +  GetValue(x, i + 1) * GetValue(x, i + 1) + GetValue(x, i + 2) * GetValue(x, i + 2)) - Sqr(GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2)))) * Cos(2 * Double.Pi * i / lag);
    def sinePart = fold j = 3 to 48 with sinPart do sinPart + (3 * (x * GetValue(x, j) + GetValue(x, 1) * GetValue(x, j + 1) + GetValue(x, 2) * GetValue(x, j + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, j) * GetValue(x, j) +  GetValue(x, j + 1) * GetValue(x, j + 1) + GetValue(x, j + 2) * GetValue(x, j + 2)) - Sqr(GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2)))) * Sin(2 * Double.Pi * j / lag);
    def sqSum = Sqr(cosinePart) + Sqr(sinePart);

    plot Cycle = ExpAverage(sqSum, 9);
    #------------------------------------------
}# end Script GetCycle{}

script getOffsetToRecentMax {
    input CycleLength = 25;
    def Length = if IsNaN(Floor(CycleLength)) then Length[1] else Floor(CycleLength);
    def OffsetToRecentMax = fold i = 0 to Length with index = 0 do if GetValue(high, i) > GetValue(high, index) then index + 1 else index;
    plot BarsToMaxHigh = OffsetToRecentMax;
    BarsToMaxHigh.HideBubble();
}# end script getOffsetToRecentMax

#------------------------------------------------------

script getOffsetToRecentMin {
    input CycleLength = 25;
    def Length = if IsNaN(Floor(CycleLength)) then Length[1] else Floor(CycleLength);
    def OffsetToRecentMin = fold i = 0 to Length with index = 0 do if GetValue(low, i) < GetValue(low, index) then index + 1 else index;
    plot BarsToMaxLow = OffsetToRecentMin;
    BarsToMaxLow.HideBubble();
}# end script getOffsetToRecentMin
#---------------------------------------------------
#===================================================================================
#*** Script to measure dominant cycle length using band-pass 
#*** filter zero crossings method per Dr Ehlers
#*** Chapter 5 of "Cycle Analytics for Traders".  
Script GetCycleViaBandPassFilter{
    input source = ohlc4;
    input Period = 20;
    input Bandwidth = 0.70;

    def cosPart = Cos(0.25 * Bandwidth * 2.0 * Double.Pi / Period);
    def sinPart = Sin(0.25 * Bandwidth * 2.0 * Double.Pi / Period);

    def alpha2 = (cosPart + sinPart - 1) / cosPart;
    def HP = (1 + alpha2 / 2) * (source - source[1]) + (1 - alpha2) * HP[1];

    def beta1 = Cos(2.0 * Double.Pi / Period);
    def gamma1 = 1 / Cos(2.0 * Double.Pi * Bandwidth / Period);

    def alpha1 = gamma1 - Sqrt(gamma1 * gamma1 - 1);

    def BP = If BarNumber() == 1 or BarNumber() == 2 then 0 else 0.5 * (1 - alpha1) * (HP - HP[2]) + beta1 * (1 + alpha1) * BP[1] - alpha1 * BP[2];

    def Peak = if absValue(BP) > 0.991*Peak[1] then AbsValue(BP) else 0.991*Peak[1];

    def Real = if Peak <> 0 then BP/Peak else Double.NaN;

    def crossAbove = Real crosses above 0;
    def crossBelow = Real crosses below 0;
    def zeroCrossing = crossAbove or crossBelow;

    # Uses a recursive variable to count the bars between zero-crossings
    # If a zero-crossing happens, resets the count to 0.
    # Otherwise, increments the count by 1.
    def barsSinceCross = if zeroCrossing then 0 else barsSinceCross[1] + 1;
    def barsBetweenCrossings = barsSinceCross + 1;    
    def val = if barsBetweenCrossings < barsBetweenCrossings[1] then 2*barsBetweenCrossings[1] else val[1];

    # The following line is a port of Dr Ehlers EasyLanguage program, kept here for reference
    #def DC = If barsBetweenCrossings < 3 then 3 else If 2*(barsBetweenCrossings) > 1.25*DC[1] then 1.25*DC[1] else if 2*(barsBetweenCrossings) < 0.8*DC[1] then 0.8*DC[1] else DC[1];

    plot DC = val;
    DC.HideBubble();

} # End script GetCycleViaBandPassFilter{}
#=============================================================================
# *** Computes the Adaptive Aroon indicator in this section ***

input BandPassSource = ohlc4;
input BandPassPeriod = 20;
input BandPassBandwidth = 0.70;

def Cycle = GetCycleViaBandPassFilter(BandPassSource, BandPassPeriod, BandPassBandwidth).DC;
def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);

def Up_ = (Floor(Beta*(CycleLength/2)) - 1 - getOffsetToRecentMax(Floor(Beta*(CycleLength/2)))) * 100.0 / (Floor(Beta*0.5*CycleLength) - 1);
def Down_ = (Floor(Beta*(CycleLength/2)) - 1 - getOffsetToRecentMin(Floor(Beta*(CycleLength/2)))) * 100.0 / (Floor(Beta*0.5*CycleLength) - 1);
plot Trend = Up_ - Down_;

Trend.AssignvalueColor(Color.PLUM);
Trend.SetLineWeight(2);

plot Up = if showUpDownLines then Up_ else Double.NaN;
plot Down = if showUpDownLines then Down_ else Double.NaN;

plot OverBought = 50;
plot OverSold = -50;

Up.SetDefaultColor(GetColor(1));
Down.SetDefaultColor(GetColor(5));
OverBought.SetDefaultColor(GetColor(8));
OverSold.SetDefaultColor(GetColor(8));


Adaptive MACD indicator:

CSS: 
# Adaptive MACD (AMACD) script by Sesqui
# [5AUG2025]: TOS Periodogram method applied. However, TOS does not suppotr matrices as needed to compute
# the precise dominant market cycles and this method bogs down the computer. As a result it is not recomended.
#
# [18OCT2025]: Sesqui added a precise method of obtaining the dominant cycle, the Band-Pass filter method per
# CH 5 of Dr Ehlers' book, "Cycle Analytics for Traders". This method when tested using a sinewave across a wide
# range of periods, obtained precise dominant cycle values and was shown to perform wwell in TOS

declare lower;
declare real_size;

input FastMACDLength = 3;
input MACDSmoothLength = 16;

input ShowHISTogram = yes;
input ShowZeroLine = yes;

#===========================================================================================================================
script GetCycle { 
    # Returns the dominant market cycle for use in adaptive indicators

    #------------------------------------------
    # Charles Schwab & Co. (c) 2016-2025
    #

    def lag = 48;
    def x = EhlersRoofingFilter("cutoff length" = 8, "roof cutoff length" = 48);
    def cosinePart = fold i = 3 to 48 with cosPart do cosPart + (3 * (x * GetValue(x, i) + GetValue(x, 1) * GetValue(x, i + 1) + GetValue(x, 2) * GetValue(x, i + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, i) * GetValue(x, i) +  GetValue(x, i + 1) * GetValue(x, i + 1) + GetValue(x, i + 2) * GetValue(x, i + 2)) - Sqr(GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2)))) * Cos(2 * Double.Pi * i / lag);
    def sinePart = fold j = 3 to 48 with sinPart do sinPart + (3 * (x * GetValue(x, j) + GetValue(x, 1) * GetValue(x, j + 1) + GetValue(x, 2) * GetValue(x, j + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, j) * GetValue(x, j) +  GetValue(x, j + 1) * GetValue(x, j + 1) + GetValue(x, j + 2) * GetValue(x, j + 2)) - Sqr(GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2)))) * Sin(2 * Double.Pi * j / lag);
    def sqSum = Sqr(cosinePart) + Sqr(sinePart);

    plot Cycle = ExpAverage(sqSum, 9);
    #----------------------------------------------
}# end Script GetCycle{}
#------------------------------------------------
# Adaptive EMA used by Adaptive MACD (AMACD)
script AdaptiveEMA {
    input src = close;
    input Cycle = 10;

    def length = if IsNaN(Floor(Cycle)) then length[1] else Floor(Cycle);
    def ExpMovAvg = if !IsNaN(ExpMovAvg[1]) then src*(2/(1+length))+ExpMovAvg[1]*(1-(2/(1+length))) else src*(2/(1+length));
    plot EMA = ExpMovAvg;
    EMA.HideBubble();

}# endScript AdaptiveEMA{}

#------------------------------------------------
Script AdaptiveMACD {
    # Computes the Adaptive MACD
    input fastLength = 3;
    input Cycle = 10; # pass Cycle into this parameter for adaptive MACD
    input SmoothLength = 16;
    input averageType = AverageType.EXPONENTIAL;

    def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);
    plot Value = MovingAverage(averageType,close,fastLength) - AdaptiveEMA(close, CycleLength).EMA;
    plot Avg = MovingAverage(averageType, Value, SmoothLength);
    Value.HideBubble();
    Avg.HideBubble();

}# end AdaptiveMACD{}
#-----------------------------------------------
#===================================================================================
#*** Script to measure dominant cycle length using band-pass 
#*** filter zero crossings method per Dr Ehlers
#*** Chapter 5 of "Cycle Analytics for Traders".  
Script GetCycleViaBandPassFilter{
    input source = ohlc4;
    input Period = 20;
    input Bandwidth = 0.70;

    def cosPart = Cos(0.25 * Bandwidth * 2.0 * Double.Pi / Period);
    def sinPart = Sin(0.25 * Bandwidth * 2.0 * Double.Pi / Period);

    def alpha2 = (cosPart + sinPart - 1) / cosPart;
    def HP = (1 + alpha2 / 2) * (source - source[1]) + (1 - alpha2) * HP[1];

    def beta1 = Cos(2.0 * Double.Pi / Period);
    def gamma1 = 1 / Cos(2.0 * Double.Pi * Bandwidth / Period);

    def alpha1 = gamma1 - Sqrt(gamma1 * gamma1 - 1);

    def BP = If BarNumber() == 1 or BarNumber() == 2 then 0 else 0.5 * (1 - alpha1) * (HP - HP[2]) + beta1 * (1 + alpha1) * BP[1] - alpha1 * BP[2];

    def Peak = if absValue(BP) > 0.991*Peak[1] then AbsValue(BP) else 0.991*Peak[1];

    def Real = if Peak <> 0 then BP/Peak else Double.NaN;

    def crossAbove = Real crosses above 0;
    def crossBelow = Real crosses below 0;
    def zeroCrossing = crossAbove or crossBelow;

    # Uses a recursive variable to count the bars between zero-crossings
    # If a zero-crossing happens, resets the count to 0.
    # Otherwise, increments the count by 1.
    def barsSinceCross = if zeroCrossing then 0 else barsSinceCross[1] + 1;
    def barsBetweenCrossings = barsSinceCross + 1;    
    def val = if barsBetweenCrossings < barsBetweenCrossings[1] then 2*barsBetweenCrossings[1] else val[1];

    # The following line is a port of Dr Ehlers EasyLanguage program, kept here for reference
    #def DC = If barsBetweenCrossings < 3 then 3 else If 2*(barsBetweenCrossings) > 1.25*DC[1] then 1.25*DC[1] else if 2*(barsBetweenCrossings) < 0.8*DC[1] then 0.8*DC[1] else DC[1];

    plot DC = val;
    DC.HideBubble();

} # End script GetCycleViaBandPassFilter{}
#=============================================================================

#=============================================================================
# *** Computes the Adaptive MACD (AMACD) indicator in this section ***

input BandPassSource = ohlc4;
input BandPassPeriod = 20;
input BandPassBandwidth = 0.70;

def Cycle = GetCycleViaBandPassFilter(BandPassSource, BandPassPeriod, BandPassBandwidth).DC;
def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);

plot val = AdaptiveMACD( FastMACDLength , CycleLength).Value;
plot ave = AdaptiveMACD(FastMACDLength , CycleLength).Avg;
plot Diff = if ShowHISTogram == 1 then val - ave else Double. NaN;
plot ZeroLine = if ShowZeroLine == 1 then 0 else Double.NaN;

ZeroLine.SetDefaultColor(GetColor(0));

val.SetDefaultColor(GetColor(1));
ave.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor("Positive and Up", Color.GREEN);
Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.Color("Positive and Up") else Diff.Color("Positive and Down") else if Diff < Diff[1] then Diff.Color("Negative and Down") else Diff.Color("Negative and Up"));

AddCloud(val, ave, Color.GREEN, Color.RED);



Adaptive Williams % R indicator:

CSS: 
#Adpative Williams Percent R Indicator script by Sesqui 
# [29AUG2025]: Added the TOS Periodogram method. However, TOS does not support matrices as needed to compute
# the precise dominant cycle values as needed. Furthermore, since this method is also computatioanlly demanding
# on computers, it is not recommended. 
#
# [18OCT2025]: Sesqui added a more precise method of obtaining dominant cycle values, the Band-Pass Filter method per
# CH 5 of Dr Ehlers' "Cycle analytics for Traders". This method is not as computatioanlly demanding and when tested
# against sinewaves across a wide range of periods, it obtained precise dominant cycle values. 
 
declare lower;

input length = 10;
input overBought = -20;
input overSold = -80;

#===========================================================================================================================
script GetCycle { 
    # Returns the dominant market cycle for use in adaptive indicators

    #------------------------------------------
    # Charles Schwab & Co. (c) 2016-2025
    #
    def lag = 48;
    def x = EhlersRoofingFilter("cutoff length" = 8, "roof cutoff length" = 48);
    def cosinePart = fold i = 3 to 48 with cosPart do cosPart + (3 * (x * GetValue(x, i) + GetValue(x, 1) * GetValue(x, i + 1) + GetValue(x, 2) * GetValue(x, i + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, i) * GetValue(x, i) +  GetValue(x, i + 1) * GetValue(x, i + 1) + GetValue(x, i + 2) * GetValue(x, i + 2)) - Sqr(GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2)))) * Cos(2 * Double.Pi * i / lag);
    def sinePart = fold j = 3 to 48 with sinPart do sinPart + (3 * (x * GetValue(x, j) + GetValue(x, 1) * GetValue(x, j + 1) + GetValue(x, 2) * GetValue(x, j + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, j) * GetValue(x, j) +  GetValue(x, j + 1) * GetValue(x, j + 1) + GetValue(x, j + 2) * GetValue(x, j + 2)) - Sqr(GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2)))) * Sin(2 * Double.Pi * j / lag);
    def sqSum = Sqr(cosinePart) + Sqr(sinePart);

    plot Cycle = ExpAverage(sqSum, 9);
    #-------------------------------------------
}# end Script GetCycle{}
#--------------
script get_Highest {
    input CycleLength = 10;
    input source = high;
    def length = if IsNaN(Floor(CycleLength)) then length[1] else Floor(CycleLength);
    def cur = source[0];
    def val = fold i = 0 to Length with max = cur do if max >= GetValue(source, i + 1) then max else GetValue(source, i+1);
    plot Highest = val;
    Highest.HideBubble();
}# end Script getHighest{}

#--------------
script get_Lowest {
    input CycleLength = 10;
    input source = low;
    def length = if IsNaN(Floor(CycleLength)) then length[1] else Floor(CycleLength);
    def cur = source[0];
    def val = fold i = 0 to Length with min = cur do if min <= GetValue(source, i + 1) then min else GetValue(source, i+1);
    plot Lowest = val;
    Lowest.HideBubble();
}# end Script getLowest{}
#---------------------------------------------------------------
#===================================================================================
#*** Script to measure dominant cycle length using band-pass 
#*** filter zero crossings method per Dr Ehlers
#*** Chapter 5 of "Cycle Analytics for Traders".  
Script GetCycleViaBandPassFilter{
    input source = ohlc4;
    input Period = 20;
    input Bandwidth = 0.70;

    def cosPart = Cos(0.25 * Bandwidth * 2.0 * Double.Pi / Period);
    def sinPart = Sin(0.25 * Bandwidth * 2.0 * Double.Pi / Period);

    def alpha2 = (cosPart + sinPart - 1) / cosPart;
    def HP = (1 + alpha2 / 2) * (source - source[1]) + (1 - alpha2) * HP[1];

    def beta1 = Cos(2.0 * Double.Pi / Period);
    def gamma1 = 1 / Cos(2.0 * Double.Pi * Bandwidth / Period);

    def alpha1 = gamma1 - Sqrt(gamma1 * gamma1 - 1);

    def BP = If BarNumber() == 1 or BarNumber() == 2 then 0 else 0.5 * (1 - alpha1) * (HP - HP[2]) + beta1 * (1 + alpha1) * BP[1] - alpha1 * BP[2];

    def Peak = if absValue(BP) > 0.991*Peak[1] then AbsValue(BP) else 0.991*Peak[1];

    def Real = if Peak <> 0 then BP/Peak else Double.NaN;

    def crossAbove = Real crosses above 0;
    def crossBelow = Real crosses below 0;
    def zeroCrossing = crossAbove or crossBelow;

    # Uses a recursive variable to count the bars between zero-crossings
    # If a zero-crossing happens, resets the count to 0.
    # Otherwise, increments the count by 1.
    def barsSinceCross = if zeroCrossing then 0 else barsSinceCross[1] + 1;
    def barsBetweenCrossings = barsSinceCross + 1;    
    def val = if barsBetweenCrossings < barsBetweenCrossings[1] then 2*barsBetweenCrossings[1] else val[1];

    # The following line is a port of Dr Ehlers EasyLanguage program, kept here for reference
    #def DC = If barsBetweenCrossings < 3 then 3 else If 2*(barsBetweenCrossings) > 1.25*DC[1] then 1.25*DC[1] else if 2*(barsBetweenCrossings) < 0.8*DC[1] then 0.8*DC[1] else DC[1];

    plot DC = val;
    DC.HideBubble();

} # End script GetCycleViaBandPassFilter{}
#=============================================================================
# *** Computes the adaptive Williams Percent R indicator in this section ***

input BandPassSource = ohlc4;
input BandPassPeriod = 20;
input BandPassBandwidth = 0.70;

def Cycle = GetCycleViaBandPassFilter(BandPassSource, BandPassPeriod, BandPassBandwidth).DC;
def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);

def hh = get_Highest(CycleLength, high);
def ll = get_Lowest(CycleLength, low);
def result = if hh == ll then -100 else (hh - close) / (hh - ll) * (-100);

plot WR = if result > 0 then 0 else result;
WR.SetDefaultColor(GetColor(1));

plot Over_Sold = overSold;
Over_Sold.SetDefaultColor(GetColor(8));

plot Over_Bought = overBought;
Over_Bought.SetDefaultColor(GetColor(8));

plot midline = -50;
midline.AssignValueColor(Color.White);
midline.hidebubble();
midline.SetPaintingStrategy(PaintingStrategy.DASHES);


Adaptive Schaff Trend Cycle (ASTC) indicator:

CSS: 
# Adaptive Schaff Trend Cycle script by Sesqui
#
# [25AUG2025]: TOS Periodogram method applied. However, TOS does not support matrices as needed to precisely
# obtain the dominant cycle periods. Furthermore, the method is computatioanlly demanding and can slow down
# the computer. As a result, it is not recommneded.
#
# [18OCT2025]: Sesqui added a more precise method of obtaining the Dominant Cycle lengths, the Band-Pass
# Filter method per Ch 5 of Dr Ehlers' book, "Cycle Analytics for Traders". When tested against sinewaves with 
# a wide range of periods, this method obtians precise values for the dominant cycle and performs well in TOS.
#================================================================================================

declare lower;

#===========================================================================================================================
script GetCycle { 
    # Returns the dominant market cycle for use in adaptive indicators

    #------------------------------------------
    # Charles Schwab & Co. (c) 2016-2025
    #
    def lag = 48;
    def x = EhlersRoofingFilter("cutoff length" = 8, "roof cutoff length" = 48);
    def cosinePart = fold i = 3 to 48 with cosPart do cosPart + (3 * (x * GetValue(x, i) + GetValue(x, 1) * GetValue(x, i + 1) + GetValue(x, 2) * GetValue(x, i + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, i) * GetValue(x, i) +  GetValue(x, i + 1) * GetValue(x, i + 1) + GetValue(x, i + 2) * GetValue(x, i + 2)) - Sqr(GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2)))) * Cos(2 * Double.Pi * i / lag);
    def sinePart = fold j = 3 to 48 with sinPart do sinPart + (3 * (x * GetValue(x, j) + GetValue(x, 1) * GetValue(x, j + 1) + GetValue(x, 2) * GetValue(x, j + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, j) * GetValue(x, j) +  GetValue(x, j + 1) * GetValue(x, j + 1) + GetValue(x, j + 2) * GetValue(x, j + 2)) - Sqr(GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2)))) * Sin(2 * Double.Pi * j / lag);
    def sqSum = Sqr(cosinePart) + Sqr(sinePart);

    plot Cycle = ExpAverage(sqSum, 9);
    #-------------------------------------------
}# end Script GetCycle{}
#------------------------------------------------
# Adaptive EMA used by Adaptive MACD (AMACD)
script AdaptiveEMA {
    input src = close;
    input Cycle = 10;

    def length = if IsNaN(Floor(Cycle)) then length[1] else Floor(Cycle);
    def ExpMovAvg = if !IsNaN(ExpMovAvg[1]) then src * (2 / (1 + length)) + ExpMovAvg[1] * (1 - (2 / (1 + length))) else src * (2 / (1 + length));
    plot EMA = ExpMovAvg;
    EMA.HideBubble();

}# endScript AdaptiveEMA{}
#------------------------------------------------
script AdaptiveMACD {
    # Computes the Adaptive MACD
    input source = close;
    input fastLength = 3;
    input Cycle = 10; # pass Cycle into this parameter for adaptive MACD
    input SmoothLength = 16;
    input averageType = AverageType.EXPONENTIAL;

    def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);
    plot Value = MovingAverage(averageType, source, fastLength) - AdaptiveEMA(source, CycleLength).EMA;

    plot Avg = MovingAverage(averageType, Value, SmoothLength);

}# end AdaptiveMACD{}
#---------------------------------------------------
#===================================================================================
#*** Script to measure dominant cycle length using band-pass 
#*** filter zero crossings method per Dr Ehlers
#*** Chapter 5 of "Cycle Analytics for Traders".  
script GetCycleViaBandPassFilter {
    input source = ohlc4;
    input Period = 20;
    input Bandwidth = 0.70;

    def cosPart = Cos(0.25 * Bandwidth * 2.0 * Double.Pi / Period);
    def sinPart = Sin(0.25 * Bandwidth * 2.0 * Double.Pi / Period);

    def alpha2 = (cosPart + sinPart - 1) / cosPart;
    def HP = (1 + alpha2 / 2) * (source - source[1]) + (1 - alpha2) * HP[1];

    def beta1 = Cos(2.0 * Double.Pi / Period);
    def gamma1 = 1 / Cos(2.0 * Double.Pi * Bandwidth / Period);

    def alpha1 = gamma1 - Sqrt(gamma1 * gamma1 - 1);

    def BP = if BarNumber() == 1 or BarNumber() == 2 then 0 else 0.5 * (1 - alpha1) * (HP - HP[2]) + beta1 * (1 + alpha1) * BP[1] - alpha1 * BP[2];

    def Peak = if AbsValue(BP) > 0.991 * Peak[1] then AbsValue(BP) else 0.991 * Peak[1];

    def Real = if Peak <> 0 then BP / Peak else Double.NaN;

    def crossAbove = Real crosses above 0;
    def crossBelow = Real crosses below 0;
    def zeroCrossing = crossAbove or crossBelow;

    # Uses a recursive variable to count the bars between zero-crossings
    # If a zero-crossing happens, resets the count to 0.
    # Otherwise, increments the count by 1.
    def barsSinceCross = if zeroCrossing then 0 else barsSinceCross[1] + 1;
    def barsBetweenCrossings = barsSinceCross + 1;
    def val = if barsBetweenCrossings < barsBetweenCrossings[1] then 2 * barsBetweenCrossings[1] else val[1];

    # The following line is a port of Dr Ehlers EasyLanguage program, kept here for reference
    #def DC = If barsBetweenCrossings < 3 then 3 else If 2*(barsBetweenCrossings) > 1.25*DC[1] then 1.25*DC[1] else if 2*(barsBetweenCrossings) < 0.8*DC[1] then 0.8*DC[1] else DC[1];

    plot DC = val;
    DC.HideBubble();

} # End script GetCycleViaBandPassFilter{}
#----------------------------------------------------------
#--------------
script get_Highest {
    input source = high;
    input CycleLength = 10;

    def length = if IsNaN(Floor(CycleLength)) then length[1] else Floor(CycleLength);
    def cur = source[0];
    def val = fold i = 0 to length with max = cur do if max >= GetValue(source, i + 1) then max else GetValue(source, i + 1);
    plot Highest = val;
    Highest.HideBubble();
}# end Script getHighest{}

#--------------
script get_Lowest {
    input source = low;
    input CycleLength = 10;

    def length = if IsNaN(Floor(CycleLength)) then length[1] else Floor(CycleLength);
    def cur = source[0];
    def val = fold i = 0 to length with min = cur do if min <= GetValue(source, i + 1) then min else GetValue(source, i + 1);
    plot Lowest = val;
    Lowest.HideBubble();
}# end Script getLowest{}
#------------------------------------------------------------------------------
script AdaptSMA {
    input source = close;
    input CycleLength = 10;

    def length = if IsNaN(Floor(CycleLength)) then length[1] else Floor(CycleLength);
    def sum = fold index = 0 to length with s = 0 do s + GetValue(source, index);
    plot SMA = sum / CycleLength;
    SMA.HideBubble();
}# End Script AdaptSMA{}
#======================================================================================
# *** Computes the Adaptive SchaffTrendCycle Trend Cycle (ASTC) in this section ***

input BandPassSource = ohlc4;
input BandPassPeriod = 20;
input BandPassBandwidth = 0.70;

#def Cycle = GetCycle().Cycle;
def Cycle = GetCycleViaBandPassFilter(BandPassSource, BandPassPeriod, BandPassBandwidth).DC;
def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);

input KPeriod = 5;
input DPeriod = 3;
input over_bought = 80;
input over_sold = 20;
input averageType = AverageType.EXPONENTIAL;


def STC_SOURCE = close;

def macd = AdaptiveMACD(STC_SOURCE, 3, CycleLength).Value;

# Computes (Close - Low)/(High - Low) over a lookback of KPeriod:
def fastK1 = FastKCustom(macd, KPeriod);
def fastD1 = MovingAverage(averageType, fastK1, DPeriod);
def fastK2 = FastKCustom(fastD1, KPeriod);

plot STC = MovingAverage(averageType, fastK2, DPeriod);
STC.HideBubble();

plot CenterLine = 50;
CenterLine.HideBubble();
CenterLine.AssignValueColor(Color.GRAY);
CenterLine.SetPaintingStrategy(PaintingStrategy.DASHES);

plot OverBought = over_bought;
OverBought.HideBubble();

plot OverSold = over_sold;
OverSold.HideBubble();

STC.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
OverSold.SetDefaultColor(GetColor(7));

def Diff = STC - STC[1];
STC.SetLineWeight(3);

STC.DefineColor("Positive and Up", Color.GREEN);
STC.DefineColor("Positive and Down", Color.DARK_GREEN);
STC.DefineColor("Negative and Down", Color.RED);
STC.DefineColor("Negative and Up", Color.DARK_RED);
STC.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then STC.Color("Positive and Up") else STC.Color("Positive and Down") else if Diff < Diff[1] then STC.Color("Negative and Down") else STC.Color("Negative and Up"));

AddCloud(OverSold, 0, Color.LIGHT_GREEN);
AddCloud(100, OverBought, Color.LIGHT_RED);


Note: Articles from Dr Ehlers use arrays to normalize the periodogram data and then a center of gravity method to pin point the dominant cycle. However, thinkscript does not support arrays as needed to do the drill down further from the periodogram to the precise dominant cycle, per se. However, the cycle value provided by the periodogram in TOS appears to be capable of finding more trading opportunities than found with static fixed length values. Be sure to test it out before using it.

Indeed, if your strategy requires a more precise identification of the market dominant cycle test drive the Band-Pass Filter method provided above. When tested using sinewaves across a wide range of periods, the Band-Pass filter method obtained precise dominant cycle values and did not seem to bog down the computer.
 
Last edited:

Join useThinkScript to post your question to a community of 21,000+ developers and traders.

SIGN UP NOW LEARN MORE
That indicator is the " Support and Resistance Levels with Breaks [LuxAlgo]" converted and mod by Sam4Cok@Samer800 - 01/2023 Update Added Fibo LEvel - 09/2023; with some minor modifications to make the red and green lines into zones.

Here is the script as-is displayed in the screenshot you are referring to:

CSS: 
#// This work is licensed under a Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) https://creativecommons.org/licenses/by-nc-sa/4.0/
#// © LuxAlgo
#study(title=" Support and Resistance Levels with Breaks",shorttitle = " Support and Resistance Levels with Breaks [LuxAlgo]", overlay = true ,  max_bars_back=1000)
# Converted and mod by Sam4Cok@Samer800   - 01/2023
# Update Added Fibo LEvel - 09/2023

input TimeFrame = 1; # Use 1 = LTF, 2 = MTF and 3= HTF
input SupplyDemandAggro = AggregationPeriod.MIN;
input zoneThickness = 0.05;
input ShowLabels = no;
input PlotSupplyDemandZones = yes;
input ShowHhLlDOTS = yes;
input RepaintingType   = {default "Off: High & Low", "On", "Off: Candle Confirmation"};# 'Repainting'
input rightBars  = 1;#, title = "Right Bars")
input leftBars  = 1;#(15, title = "Left Bars ")


###------------------------------------------------------------------------------------------
input OpenTime = 900;   #hint OpenTime: Time you want backtesting to start the session at
input CloseTime = 1600;  #hint CloseTime: Time you want backtesting to stop the session at

def Begin = SecondsFromTime(OpenTime) + 60; #Note that then +60 limits this to using 1min candles
def End = SecondsTillTime(CloseTime);
# Only use market hours when using intraday timeframe
def isIntraDay = if GetAggregationPeriod() > 14400000 or GetAggregationPeriod() == 0 then 0 else 1;
def MarketOpen = if !isIntraDay then 1 else if isIntraDay and  Begin > 0 and End > 0 then 1 else 0;
###--------------------------------------------------------------------------------------------------

script fixnan {
    input source = close;
    def fix = if !IsNaN(source) then source else fix[1];
    plot result = fix;
}
#drawBox(condition, y1, y2, color) =>
script drawBox {
    input TimeFrame = 1;
    input aggro = AggregationPeriod.MIN;
    input condition = yes;
    input y1        = high;
    input y2        = low;
    def boxHi = if condition then y1 else boxHi[1];
    def boxLo = if condition then y2 else boxLo[1];
    def extension = if TimeFrame == 1 then 5 else if TimeFrame == 2 then 1 else if TimeFrame == 3 then 1 else 1;
    plot ph = if !IsNaN(close(period = aggro)[extension]) then if !boxHi then high(period = aggro) else boxHi else Double.NaN;
    plot pl = if !IsNaN(close(period = aggro)[extension]) then if !boxLo then low(period = aggro) else boxLo else Double.NaN;

}

#repaint(c1, c2, c3) =>
script repaint {
    input type = "On";
    input c1 = no;
    input c2 = no;
    input c3 = no;
    def rTon = type == "On";
    def rTcc = type == "Off: Candle Confirmation";
    def rThv = type == "Off: High & Low";
    def repaint = if rTon then c1 else if rThv then c2 else if rTcc then c3 else Double.NaN;
    plot out = repaint;
}
script FindPivots {
    input dat = close; # default data or study being evaluated
    input HL  = 0;    # default high or low pivot designation, -1 low, +1 high
    input lbL = 5;    # default Pivot Lookback Left
    input lbR = 1;    # default Pivot Lookback Right
    ##############
    def _nan;    # used for non-number returns
    def _BN;     # the current barnumber
    def _VStop;  # confirms that the lookforward period continues the pivot trend
    def _V;      # the Value at the actual pivot point
    ##############
    _BN  = BarNumber();
    _nan = Double.NaN;
    _VStop = if !IsNaN(dat) and lbR > 0 and lbL > 0 then
                fold a = 1 to lbR + 1 with b=1 while b do
                    if HL > 0 then dat > GetValue(dat, -a) else dat < GetValue(dat, -a) else _nan;
    if (HL > 0) {
        _V = if _BN > lbL and dat == Highest(dat, lbL + 1) and _VStop
            then dat else _nan;
    } else {
        _V = if _BN > lbL and dat == Lowest(dat, lbL + 1) and _VStop
            then dat else _nan;
    }
    plot result = if !IsNaN(_V) and _VStop then _V else _nan;
}# end script FindPivots{}

#===========================================================================
# Main Supply Demand Zones Computation is In This Section

def src = close(period = SupplyDemandAggro);
def na = Double.NaN;
def last = IsNaN(src);

def ph = FindPivots(high(period =  SupplyDemandAggro), 1 , leftBars, rightBars);
def pl = FindPivots(low(period =  SupplyDemandAggro), -1, leftBars, rightBars);
def highUsePivot = fixnan(ph);
def lowUsePivot  = fixnan(pl);
#// Box Height
def s_yLoc = if low(period =  SupplyDemandAggro)[1]  > low(period =  SupplyDemandAggro)[-1]  then low(period =  SupplyDemandAggro)[-1] else low(period =  SupplyDemandAggro)[1];
def r_yLoc = if high(period =  SupplyDemandAggro)[1] > high(period =  SupplyDemandAggro)[-1] then high(period =  SupplyDemandAggro)[1] else high(period =  SupplyDemandAggro)[-1];

def r1 = if MarketOpen and PlotSupplyDemandZones then drawBox(TimeFrame,  SupplyDemandAggro, (highUsePivot - highUsePivot[1]), highUsePivot, r_yLoc).ph else na;
#def r2 = if MarketOpen then drawBox2(TimeFrame, aggro, (highUsePivot - highUsePivot[1]), highUsePivot, r_yLoc).pl else na;
def r2 = if MarketOpen and PlotSupplyDemandZones then r1 - zoneThickness else na;

AddCloud(r1, r2, if TimeFrame == 3 then Color.YELLOW else if TimeFrame == 2 then Color.DARK_RED else if TimeFrame == 1 then CreateColor(255, 51, 51) else Color.RED);

#def s1 = if MarketOpen then drawBox(aggro, (lowUsePivot - lowUsePivot[1]), s_yLoc, lowUsePivot).ph else na;

def s2 = if MarketOpen and PlotSupplyDemandZones then drawBox(TimeFrame,  SupplyDemandAggro, (lowUsePivot - lowUsePivot[1]), s_yLoc, lowUsePivot).pl else na;
def s1 = if MarketOpen and PlotSupplyDemandZones then s2 + zoneThickness else na;

AddCloud(s1, s2, if TimeFrame == 3 then Color.PLUM else if TimeFrame == 2 then Color.DARK_GREEN else if TimeFrame == 1 then CreateColor(153, 255, 153) else Color.PLUM);

#=====================================================================================
# Dots are plotted in this section to indicate Demand Zones with Red Dots Above Bars
# And Supply Zones with Green Dots Below Bars

def hh = if MarketOpen and highUsePivot > highUsePivot[1] then highUsePivot else na;
def ll = if MarketOpen and lowUsePivot  < lowUsePivot[1]  then lowUsePivot else na;
def hl = if MarketOpen and lowUsePivot  > lowUsePivot[1]  then lowUsePivot else na;
def lh = if MarketOpen and highUsePivot < highUsePivot[1] then highUsePivot else na;

plot my_LL = if MarketOpen and ShowHhLlDOTS and ll then ll else Double.NaN;
my_LL.SetPaintingStrategy(PaintingStrategy.POINTS);
my_LL.AssignValueColor(Color.GREEN);
my_LL.SetLineWeight(5);
my_LL.HideBubble();

plot my_HL = if MarketOpen and ShowHhLlDOTS and hl then hl else Double.NaN;
my_HL.SetPaintingStrategy(PaintingStrategy.POINTS);
my_HL.AssignValueColor(Color.DARK_GREEN);
my_HL.SetLineWeight(5);
my_HL.HideBubble();

plot my_HH = if MarketOpen and ShowHhLlDOTS and hh then hh else Double.NaN;
my_HH.SetPaintingStrategy(PaintingStrategy.POINTS);
my_HH.AssignValueColor(Color.RED);
my_HH.SetLineWeight(5);
my_HH.HideBubble();

plot my_LH = if MarketOpen and ShowHhLlDOTS and lh then lh else Double.NaN;
my_LH.SetPaintingStrategy(PaintingStrategy.POINTS);
my_LH.AssignValueColor(Color.DARK_RED);
my_LH.SetLineWeight(5);
my_LH.HideBubble();


#-- END of Code
 
@Sesqui

Static lengths are an indicator killer, so your Adaptive Cycle script could be a game changer.

But I am struggling, to understand the implementation throughout your various scripts.
For example:
If you are going to create an AdaptiveEMA subscript;
Why only use it for one of the EMA calculations?
And then create an additional MACD subscript to calculate the other moving averages.

Rich (BB code): 
# Is this subscript necessary?
script AdaptiveMACD {
    # Computes the Adaptive MACD
    input fastLength = 3;
    input Cycle = 10; # pass Cycle into this parameter for adaptive MACD
    input SmoothLength = 16;
    input averageType = AverageType.EXPONENTIAL;

    def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);

    plot Value = MovingAverage(averageType, close, fastLength) #AdaptiveEMA NOT used here
-AdaptiveEMA(close, CycleLength).EMA;  #AdaptiveEMA used here
  
    plot Avg = MovingAverage(averageType, Value, SmoothLength); #AdaptiveEMA NOT used here

}# end AdaptiveMACD{}

The ToS inability to define variables with constants has been a barrier to creating dynamic lagging indicators.
I am hoping you can explain how you chose to implement your subscript; to provide better understanding.


Thank you for walking me through this exciting development.
 
Last edited:
MerryDay, Good catch pointing out that the adaptive MACD script only used one adaptive EMA in its formula. The script was biased in favor of my own preferences having been trading much prior with a static MACD(3,10,16). As a result, when I made this adaptive MACD I kept the fastLength set at 3 because that worked for my purposes. Thus only the MACD's slowLength was adaptively set to the CycleLength.
With respect to the last line in the script which also uses a non-adaptive moving average, my rationale was that moving average is simply a smoothing function to smooth out the MACD signal before plotting it. I liked 16 so kept it that way.

However, for those who would prefer an adaptive MACD that connects the slowLength, fastLength and smoothing Length of the MACD to a function of the Cycle Length, here is a script that helps to do that. Hope this helps!


CSS: 
# FULLY Adaptive MACD (AMACD) script by Sesqui
# 1SEP2025

declare lower;
declare real_size;

input FastMACDLengthCycleFactor = 0.333;
input MACDSmoothingLengthFactor = 0.50;

input ShowHIST = yes;
input ShowZeroLine = yes;

#===========================================================================================================================
script GetCycle {
    # Returns the dominant market cycle for use in adaptive indicators

    #------------------------------------------
    # Charles Schwab & Co. (c) 2016-2025
    #

    def lag = 48;
    def x = EhlersRoofingFilter("cutoff length" = 8, "roof cutoff length" = 48);
    def cosinePart = fold i = 3 to 48 with cosPart do cosPart + (3 * (x * GetValue(x, i) + GetValue(x, 1) * GetValue(x, i + 1) + GetValue(x, 2) * GetValue(x, i + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, i) * GetValue(x, i) +  GetValue(x, i + 1) * GetValue(x, i + 1) + GetValue(x, i + 2) * GetValue(x, i + 2)) - Sqr(GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2)))) * Cos(2 * Double.Pi * i / lag);
    def sinePart = fold j = 3 to 48 with sinPart do sinPart + (3 * (x * GetValue(x, j) + GetValue(x, 1) * GetValue(x, j + 1) + GetValue(x, 2) * GetValue(x, j + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, j) * GetValue(x, j) +  GetValue(x, j + 1) * GetValue(x, j + 1) + GetValue(x, j + 2) * GetValue(x, j + 2)) - Sqr(GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2)))) * Sin(2 * Double.Pi * j / lag);
    def sqSum = Sqr(cosinePart) + Sqr(sinePart);

    plot Cycle = ExpAverage(sqSum, 9);
    #----------------------------------------------
}# end Script GetCycle{}
#------------------------------------------------
script AdaptiveEMA {
    input src = close;
    input Cycle = 10;
    input numCycles = 1;

    def length = if IsNaN(Floor(numCycles * Cycle)) then length[1] else Floor(numCycles*Cycle);
    def ExpMovAvg = src*(2/(1+length))+ExpMovAvg[1]*(1-(2/(1+length)));
    plot EMA = ExpMovAvg;
    EMA.HideBubble();

}# endScript AdaptiveEMA{}

#------------------------------------------------
script AdaptiveMACD {
    # Computes the Adaptive MACD
    input fastLength = 3;
    input Cycle = 10; # pass Cycle into this parameter for adaptive MACD
    input SmoothLength = 16;
    input averageType = AverageType.EXPONENTIAL;

    def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);
    #plot Value = MovingAverage(averageType, close, fastLength) - AdaptiveEMA(close, CycleLength).EMA;
    plot Value = AdaptiveEMA(close,fastLength).EMA - AdaptiveEMA(close, CycleLength).EMA;
    
    #plot Avg = MovingAverage(averageType, Value, SmoothLength);
    plot Avg = AdaptiveEMA(value,SmoothLength).EMA;

}# end AdaptiveMACD{}
#==============================================================================================

def Cycle = GetCycle().Cycle;

def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);

plot val = AdaptiveMACD( CycleLength*FastMACDLengthCycleFactor , CycleLength, CycleLength*MACDSmoothingLengthFactor).Value;
plot ave = AdaptiveMACD(CycleLength*FastMACDLengthCycleFactor , CycleLength, CycleLength*MACDSmoothingLengthFactor).Avg;
plot Diff = if ShowHIST == 1 then val - ave else Double. NaN;
plot ZeroLine = if ShowZeroLine == 1 then 0 else Double.NaN;
ZeroLine.SetDefaultColor(GetColor(0));

val.SetDefaultColor(GetColor(1));
ave.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor("Positive and Up", Color.GREEN);
Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.Color("Positive and Up") else Diff.Color("Positive and Down") else if Diff < Diff[1] then Diff.Color("Negative and Down") else Diff.Color("Negative and Up"));

AddCloud(val, ave, Color.GREEN, Color.RED);
 
@Sesqui Thank you for the quick response. I wanted to make sure that there was not a computational reason for the multi-prong approach.

I agree, the dynamic cycle subscript would not be appropriate for smoothing, which should be a fixed length.

Over on the VIP forum, you will notice almost all indicators use Ehlers Smoother
Check it out:
https://usethinkscript.com/threads/smoothing-calculation.21513/

I have used Gaussian and other smoothers and have found the above to provide the least lag and most efficient solution
 
Sesqui said:
That indicator is the " Support and Resistance Levels with Breaks [LuxAlgo]" converted and mod by Sam4Cok@Samer800 - 01/2023 Update Added Fibo LEvel - 09/2023; with some minor modifications to make the red and green lines into zones.

Here is the script as-is displayed in the screenshot you are referring to:

CSS: 
#// This work is licensed under a Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) https://creativecommons.org/licenses/by-nc-sa/4.0/
#// © LuxAlgo
#study(title=" Support and Resistance Levels with Breaks",shorttitle = " Support and Resistance Levels with Breaks [LuxAlgo]", overlay = true ,  max_bars_back=1000)
# Converted and mod by Sam4Cok@Samer800   - 01/2023
# Update Added Fibo LEvel - 09/2023

input TimeFrame = 1; # Use 1 = LTF, 2 = MTF and 3= HTF
input SupplyDemandAggro = AggregationPeriod.MIN;
input zoneThickness = 0.05;
input ShowLabels = no;
input PlotSupplyDemandZones = yes;
input ShowHhLlDOTS = yes;
input RepaintingType   = {default "Off: High & Low", "On", "Off: Candle Confirmation"};# 'Repainting'
input rightBars  = 1;#, title = "Right Bars")
input leftBars  = 1;#(15, title = "Left Bars ")


###------------------------------------------------------------------------------------------
input OpenTime = 900;   #hint OpenTime: Time you want backtesting to start the session at
input CloseTime = 1600;  #hint CloseTime: Time you want backtesting to stop the session at

def Begin = SecondsFromTime(OpenTime) + 60; #Note that then +60 limits this to using 1min candles
def End = SecondsTillTime(CloseTime);
# Only use market hours when using intraday timeframe
def isIntraDay = if GetAggregationPeriod() > 14400000 or GetAggregationPeriod() == 0 then 0 else 1;
def MarketOpen = if !isIntraDay then 1 else if isIntraDay and  Begin > 0 and End > 0 then 1 else 0;
###--------------------------------------------------------------------------------------------------

script fixnan {
    input source = close;
    def fix = if !IsNaN(source) then source else fix[1];
    plot result = fix;
}
#drawBox(condition, y1, y2, color) =>
script drawBox {
    input TimeFrame = 1;
    input aggro = AggregationPeriod.MIN;
    input condition = yes;
    input y1        = high;
    input y2        = low;
    def boxHi = if condition then y1 else boxHi[1];
    def boxLo = if condition then y2 else boxLo[1];
    def extension = if TimeFrame == 1 then 5 else if TimeFrame == 2 then 1 else if TimeFrame == 3 then 1 else 1;
    plot ph = if !IsNaN(close(period = aggro)[extension]) then if !boxHi then high(period = aggro) else boxHi else Double.NaN;
    plot pl = if !IsNaN(close(period = aggro)[extension]) then if !boxLo then low(period = aggro) else boxLo else Double.NaN;

}

#repaint(c1, c2, c3) =>
script repaint {
    input type = "On";
    input c1 = no;
    input c2 = no;
    input c3 = no;
    def rTon = type == "On";
    def rTcc = type == "Off: Candle Confirmation";
    def rThv = type == "Off: High & Low";
    def repaint = if rTon then c1 else if rThv then c2 else if rTcc then c3 else Double.NaN;
    plot out = repaint;
}
script FindPivots {
    input dat = close; # default data or study being evaluated
    input HL  = 0;    # default high or low pivot designation, -1 low, +1 high
    input lbL = 5;    # default Pivot Lookback Left
    input lbR = 1;    # default Pivot Lookback Right
    ##############
    def _nan;    # used for non-number returns
    def _BN;     # the current barnumber
    def _VStop;  # confirms that the lookforward period continues the pivot trend
    def _V;      # the Value at the actual pivot point
    ##############
    _BN  = BarNumber();
    _nan = Double.NaN;
    _VStop = if !IsNaN(dat) and lbR > 0 and lbL > 0 then
                fold a = 1 to lbR + 1 with b=1 while b do
                    if HL > 0 then dat > GetValue(dat, -a) else dat < GetValue(dat, -a) else _nan;
    if (HL > 0) {
        _V = if _BN > lbL and dat == Highest(dat, lbL + 1) and _VStop
            then dat else _nan;
    } else {
        _V = if _BN > lbL and dat == Lowest(dat, lbL + 1) and _VStop
            then dat else _nan;
    }
    plot result = if !IsNaN(_V) and _VStop then _V else _nan;
}# end script FindPivots{}

#===========================================================================
# Main Supply Demand Zones Computation is In This Section

def src = close(period = SupplyDemandAggro);
def na = Double.NaN;
def last = IsNaN(src);

def ph = FindPivots(high(period =  SupplyDemandAggro), 1 , leftBars, rightBars);
def pl = FindPivots(low(period =  SupplyDemandAggro), -1, leftBars, rightBars);
def highUsePivot = fixnan(ph);
def lowUsePivot  = fixnan(pl);
#// Box Height
def s_yLoc = if low(period =  SupplyDemandAggro)[1]  > low(period =  SupplyDemandAggro)[-1]  then low(period =  SupplyDemandAggro)[-1] else low(period =  SupplyDemandAggro)[1];
def r_yLoc = if high(period =  SupplyDemandAggro)[1] > high(period =  SupplyDemandAggro)[-1] then high(period =  SupplyDemandAggro)[1] else high(period =  SupplyDemandAggro)[-1];

def r1 = if MarketOpen and PlotSupplyDemandZones then drawBox(TimeFrame,  SupplyDemandAggro, (highUsePivot - highUsePivot[1]), highUsePivot, r_yLoc).ph else na;
#def r2 = if MarketOpen then drawBox2(TimeFrame, aggro, (highUsePivot - highUsePivot[1]), highUsePivot, r_yLoc).pl else na;
def r2 = if MarketOpen and PlotSupplyDemandZones then r1 - zoneThickness else na;

AddCloud(r1, r2, if TimeFrame == 3 then Color.YELLOW else if TimeFrame == 2 then Color.DARK_RED else if TimeFrame == 1 then CreateColor(255, 51, 51) else Color.RED);

#def s1 = if MarketOpen then drawBox(aggro, (lowUsePivot - lowUsePivot[1]), s_yLoc, lowUsePivot).ph else na;

def s2 = if MarketOpen and PlotSupplyDemandZones then drawBox(TimeFrame,  SupplyDemandAggro, (lowUsePivot - lowUsePivot[1]), s_yLoc, lowUsePivot).pl else na;
def s1 = if MarketOpen and PlotSupplyDemandZones then s2 + zoneThickness else na;

AddCloud(s1, s2, if TimeFrame == 3 then Color.PLUM else if TimeFrame == 2 then Color.DARK_GREEN else if TimeFrame == 1 then CreateColor(153, 255, 153) else Color.PLUM);

#=====================================================================================
# Dots are plotted in this section to indicate Demand Zones with Red Dots Above Bars
# And Supply Zones with Green Dots Below Bars

def hh = if MarketOpen and highUsePivot > highUsePivot[1] then highUsePivot else na;
def ll = if MarketOpen and lowUsePivot  < lowUsePivot[1]  then lowUsePivot else na;
def hl = if MarketOpen and lowUsePivot  > lowUsePivot[1]  then lowUsePivot else na;
def lh = if MarketOpen and highUsePivot < highUsePivot[1] then highUsePivot else na;

plot my_LL = if MarketOpen and ShowHhLlDOTS and ll then ll else Double.NaN;
my_LL.SetPaintingStrategy(PaintingStrategy.POINTS);
my_LL.AssignValueColor(Color.GREEN);
my_LL.SetLineWeight(5);
my_LL.HideBubble();

plot my_HL = if MarketOpen and ShowHhLlDOTS and hl then hl else Double.NaN;
my_HL.SetPaintingStrategy(PaintingStrategy.POINTS);
my_HL.AssignValueColor(Color.DARK_GREEN);
my_HL.SetLineWeight(5);
my_HL.HideBubble();

plot my_HH = if MarketOpen and ShowHhLlDOTS and hh then hh else Double.NaN;
my_HH.SetPaintingStrategy(PaintingStrategy.POINTS);
my_HH.AssignValueColor(Color.RED);
my_HH.SetLineWeight(5);
my_HH.HideBubble();

plot my_LH = if MarketOpen and ShowHhLlDOTS and lh then lh else Double.NaN;
my_LH.SetPaintingStrategy(PaintingStrategy.POINTS);
my_LH.AssignValueColor(Color.DARK_RED);
my_LH.SetLineWeight(5);
my_LH.HideBubble();


#-- END of Code
Click to expand...
Thank you for the code. For some reason, my chart doesn't show them.
Also, would you have a code for the lower indicator, Volume Price Analysis?
Thank you.
 
@Sesqui can you share the upper part of the script for the chart please.

Sesqui said:
View attachment 25588

The indicators provided below use the dominant cycle period obtained from Dr Ehlers AutoCorrelationPeriodogram to make them adaptive to the market cycle. The screenshot above shows what they look like on the lower portion of the chart.

Here is the script code for each.

Adaptive Aroon Indicator:

CSS: 
# Adaptive Aroon Indicator script by Sesqui 29AUG2025

declare lower;
input Beta = 1.0;
input showUpDownLines = no;
#===========================================================================================================================
script GetCycle {
    # Returns the dominant market cycle for use in adaptive indicators

    #------------------------------------------
    # Charles Schwab & Co. (c) 2016-2025
    #
    def lag = 48;
    def x = EhlersRoofingFilter("cutoff length" = 8, "roof cutoff length" = 48);
    def cosinePart = fold i = 3 to 48 with cosPart do cosPart + (3 * (x * GetValue(x, i) + GetValue(x, 1) * GetValue(x, i + 1) + GetValue(x, 2) * GetValue(x, i + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, i) * GetValue(x, i) +  GetValue(x, i + 1) * GetValue(x, i + 1) + GetValue(x, i + 2) * GetValue(x, i + 2)) - Sqr(GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2)))) * Cos(2 * Double.Pi * i / lag);
    def sinePart = fold j = 3 to 48 with sinPart do sinPart + (3 * (x * GetValue(x, j) + GetValue(x, 1) * GetValue(x, j + 1) + GetValue(x, 2) * GetValue(x, j + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, j) * GetValue(x, j) +  GetValue(x, j + 1) * GetValue(x, j + 1) + GetValue(x, j + 2) * GetValue(x, j + 2)) - Sqr(GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2)))) * Sin(2 * Double.Pi * j / lag);
    def sqSum = Sqr(cosinePart) + Sqr(sinePart);

    plot Cycle = ExpAverage(sqSum, 9);
    #------------------------------------------
}# end Script GetCycle{}

script getOffsetToRecentMax {
    input CycleLength = 25;
    def Length = if IsNaN(Floor(CycleLength)) then Length[1] else Floor(CycleLength);
    def OffsetToRecentMax = fold i = 0 to Length with index = 0 do if GetValue(high, i) > GetValue(high, index) then index + 1 else index;
    plot BarsToMaxHigh = OffsetToRecentMax;
    BarsToMaxHigh.HideBubble();
}# end script getOffsetToRecentMax

#------------------------------------------------------

script getOffsetToRecentMin {
    input CycleLength = 25;
    def Length = if IsNaN(Floor(CycleLength)) then Length[1] else Floor(CycleLength);
    def OffsetToRecentMin = fold i = 0 to Length with index = 0 do if GetValue(low, i) < GetValue(low, index) then index + 1 else index;
    plot BarsToMaxLow = OffsetToRecentMin;
    BarsToMaxLow.HideBubble();
}# end script getOffsetToRecentMin

#==============================================================================================

def DCLength= GetCycle().Cycle;
def CycleLength = if IsNaN(Floor(DCLength)) then CycleLength[1] else Floor(DCLength);

def Up_ = (Floor(Beta*(CycleLength/2)) - 1 - getOffsetToRecentMax(Floor(Beta*(CycleLength/2)))) * 100.0 / (Floor(Beta*0.5*CycleLength) - 1);
def Down_ = (Floor(Beta*(CycleLength/2)) - 1 - getOffsetToRecentMin(Floor(Beta*(CycleLength/2)))) * 100.0 / (Floor(Beta*0.5*CycleLength) - 1);
plot Trend = Up_ - Down_;

Trend.AssignvalueColor(Color.PLUM);
Trend.SetLineWeight(2);

plot Up = if showUpDownLines then Up_ else Double.NaN;
plot Down = if showUpDownLines then Down_ else Double.NaN;

plot OverBought = 50;
plot OverSold = -50;

Up.SetDefaultColor(GetColor(1));
Down.SetDefaultColor(GetColor(5));
OverBought.SetDefaultColor(GetColor(8));
OverSold.SetDefaultColor(GetColor(8));


Adaptive MACD indicator:

CSS: 
# Adaptive MACD (AMACD) script by Sesqui
# 5AUG2025

declare lower;
declare real_size;

input ShowHIST = yes;
input ShowZeroLine = yes;

#===========================================================================================================================
script GetCycle {
    # Returns the dominant market cycle for use in adaptive indicators

    #------------------------------------------
    # Charles Schwab & Co. (c) 2016-2025
    #

    def lag = 48;
    def x = EhlersRoofingFilter("cutoff length" = 8, "roof cutoff length" = 48);
    def cosinePart = fold i = 3 to 48 with cosPart do cosPart + (3 * (x * GetValue(x, i) + GetValue(x, 1) * GetValue(x, i + 1) + GetValue(x, 2) * GetValue(x, i + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, i) * GetValue(x, i) +  GetValue(x, i + 1) * GetValue(x, i + 1) + GetValue(x, i + 2) * GetValue(x, i + 2)) - Sqr(GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2)))) * Cos(2 * Double.Pi * i / lag);
    def sinePart = fold j = 3 to 48 with sinPart do sinPart + (3 * (x * GetValue(x, j) + GetValue(x, 1) * GetValue(x, j + 1) + GetValue(x, 2) * GetValue(x, j + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, j) * GetValue(x, j) +  GetValue(x, j + 1) * GetValue(x, j + 1) + GetValue(x, j + 2) * GetValue(x, j + 2)) - Sqr(GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2)))) * Sin(2 * Double.Pi * j / lag);
    def sqSum = Sqr(cosinePart) + Sqr(sinePart);

    plot Cycle = ExpAverage(sqSum, 9);
    #----------------------------------------------
}# end Script GetCycle{}
#------------------------------------------------
script AdaptiveEMA {
    input src = close;
    input Cycle = 10;
    input numCycles = 1;

    def length = if IsNaN(Floor(numCycles * Cycle)) then length[1] else Floor(numCycles*Cycle);
    def ExpMovAvg = src*(2/(1+length))+ExpMovAvg[1]*(1-(2/(1+length)));
    plot EMA = ExpMovAvg;
    EMA.HideBubble();

}# endScript AdaptiveEMA{}

#------------------------------------------------
script AdaptiveMACD {
    # Computes the Adaptive MACD
    input fastLength = 3;
    input Cycle = 10; # pass Cycle into this parameter for adaptive MACD
    input SmoothLength = 16;
    input averageType = AverageType.EXPONENTIAL;

    def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);
    plot Value = MovingAverage(averageType, close, fastLength) - AdaptiveEMA(close, CycleLength).EMA;
   
    plot Avg = MovingAverage(averageType, Value, SmoothLength);

}# end AdaptiveMACD{}
#==============================================================================================

def CycleLength = GetCycle().Cycle;

plot val = AdaptiveMACD(3, CycleLength).Value;
plot ave = AdaptiveMACD(3, CycleLength).Avg;
plot Diff = if ShowHIST == 1 then val - ave else Double. NaN;
plot ZeroLine = if ShowZeroLine == 1 then 0 else Double.NaN;
ZeroLine.SetDefaultColor(GetColor(0));

val.SetDefaultColor(GetColor(1));
ave.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor("Positive and Up", Color.GREEN);
Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.Color("Positive and Up") else Diff.Color("Positive and Down") else if Diff < Diff[1] then Diff.Color("Negative and Down") else Diff.Color("Negative and Up"));

AddCloud(val, ave, Color.GREEN, Color.RED);



Adaptive Williams % R indicator:

CSS: 
# Adpative Aroon Indicator script by Sesqui 29AUG2025
declare lower;

input length = 10;
input overBought = -20;
input overSold = -80;

#===========================================================================================================================
script GetCycle {
    # Returns the dominant market cycle for use in adaptive indicators

    #------------------------------------------
    # Charles Schwab & Co. (c) 2016-2025
    #
    def lag = 48;
    def x = EhlersRoofingFilter("cutoff length" = 8, "roof cutoff length" = 48);
    def cosinePart = fold i = 3 to 48 with cosPart do cosPart + (3 * (x * GetValue(x, i) + GetValue(x, 1) * GetValue(x, i + 1) + GetValue(x, 2) * GetValue(x, i + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, i) * GetValue(x, i) +  GetValue(x, i + 1) * GetValue(x, i + 1) + GetValue(x, i + 2) * GetValue(x, i + 2)) - Sqr(GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2)))) * Cos(2 * Double.Pi * i / lag);
    def sinePart = fold j = 3 to 48 with sinPart do sinPart + (3 * (x * GetValue(x, j) + GetValue(x, 1) * GetValue(x, j + 1) + GetValue(x, 2) * GetValue(x, j + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, j) * GetValue(x, j) +  GetValue(x, j + 1) * GetValue(x, j + 1) + GetValue(x, j + 2) * GetValue(x, j + 2)) - Sqr(GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2)))) * Sin(2 * Double.Pi * j / lag);
    def sqSum = Sqr(cosinePart) + Sqr(sinePart);

    plot Cycle = ExpAverage(sqSum, 9);
    #-------------------------------------------
}# end Script GetCycle{}
#--------------
script get_Highest {
    input CycleLength = 10;
    input source = high;
    def length = if IsNaN(Floor(CycleLength)) then length[1] else Floor(CycleLength);
    def cur = source[0];
    def val = fold i = 0 to Length with max = cur do if max >= GetValue(source, i + 1) then max else GetValue(source, i+1);
    plot Highest = val;
    Highest.HideBubble();
}# end Script getHighest{}

#--------------
script get_Lowest {
    input CycleLength = 10;
    input source = low;
    def length = if IsNaN(Floor(CycleLength)) then length[1] else Floor(CycleLength);
    def cur = source[0];
    def val = fold i = 0 to Length with min = cur do if min <= GetValue(source, i + 1) then min else GetValue(source, i+1);
    plot Lowest = val;
    Lowest.HideBubble();
}# end Script getLowest{}

#==============================================================================================

def CycleLength = GetCycle().Cycle;

def hh = get_Highest(CycleLength, high);
def ll = get_Lowest(CycleLength, low);
def result = if hh == ll then -100 else (hh - close) / (hh - ll) * (-100);

plot WR = if result > 0 then 0 else result;
WR.SetDefaultColor(GetColor(1));

plot Over_Sold = overSold;
Over_Sold.SetDefaultColor(GetColor(8));

plot Over_Bought = overBought;
Over_Bought.SetDefaultColor(GetColor(8));


Adaptive Schaff Trend Cycle (ASTC) indicator:

CSS: 
# Adaptive Schaff Trend Cycle script by Sesqui
# 25AUG2025

declare lower;

#===========================================================================================================================
script GetCycle {
    # Returns the dominant market cycle for use in adaptive indicators

    #------------------------------------------
    # Charles Schwab & Co. (c) 2016-2025
    #
    def lag = 48;
    def x = EhlersRoofingFilter("cutoff length" = 8, "roof cutoff length" = 48);
    def cosinePart = fold i = 3 to 48 with cosPart do cosPart + (3 * (x * GetValue(x, i) + GetValue(x, 1) * GetValue(x, i + 1) + GetValue(x, 2) * GetValue(x, i + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, i) * GetValue(x, i) +  GetValue(x, i + 1) * GetValue(x, i + 1) + GetValue(x, i + 2) * GetValue(x, i + 2)) - Sqr(GetValue(x, i) + GetValue(x, i + 1) + GetValue(x, i + 2)))) * Cos(2 * Double.Pi * i / lag);
    def sinePart = fold j = 3 to 48 with sinPart do sinPart + (3 * (x * GetValue(x, j) + GetValue(x, 1) * GetValue(x, j + 1) + GetValue(x, 2) * GetValue(x, j + 2)) - (x + GetValue(x, 1) + GetValue(x, 2)) * (GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2))) / Sqrt((3 * (x * x + GetValue(x, 1) * GetValue(x, 1) + GetValue(x, 2) * GetValue(x, 2)) - Sqr(x + GetValue(x, 1) + GetValue(x, 2))) * (3 * (GetValue(x, j) * GetValue(x, j) +  GetValue(x, j + 1) * GetValue(x, j + 1) + GetValue(x, j + 2) * GetValue(x, j + 2)) - Sqr(GetValue(x, j) + GetValue(x, j + 1) + GetValue(x, j + 2)))) * Sin(2 * Double.Pi * j / lag);
    def sqSum = Sqr(cosinePart) + Sqr(sinePart);

    plot Cycle = ExpAverage(sqSum, 9);
    #-------------------------------------------
}# end Script GetCycle{}
#------------------------------------------------
script AdaptiveEMA {
    input src = close;
    input Cycle = 10;
    input numCycles = 1;

    def length = if IsNaN(Floor(numCycles * Cycle)) then length[1] else Floor(numCycles*Cycle);
    def ExpMovAvg = src*(2/(1+length))+ExpMovAvg[1]*(1-(2/(1+length)));
    plot EMA = ExpMovAvg;
    EMA.HideBubble();

}# endScript AdaptiveEMA{}

#------------------------------------------------
script AdaptiveMACD {
    # Computes the Adaptive MACD
    input source = close;
    input fastLength = 3;
    input Cycle = 10; # pass Cycle into this parameter for adaptive MACD
    input SmoothLength = 16;
    input averageType = AverageType.EXPONENTIAL;

    def CycleLength = if IsNaN(Floor(Cycle)) then CycleLength[1] else Floor(Cycle);
    plot Value = MovingAverage(averageType, source, fastLength) - AdaptiveEMA(source, CycleLength).EMA;
   
    plot Avg = MovingAverage(averageType, Value, SmoothLength);

}# end AdaptiveMACD{}
#==============================================================================================

def CycleLength = GetCycle().Cycle;

input fastLength = 3;

input KPeriod = 5;
input DPeriod = 3;
input over_bought = 80;
input over_sold = 20;
input averageType = AverageType.EXPONENTIAL;

def STC_SOURCE = close;
def macd = AdaptiveMACD(STC_SOURCE, fastLength, CycleLength).Value;

def fastK1 = FastKCustom(macd, KPeriod);
def fastD1 = MovingAverage(averageType, fastK1, DPeriod);
def fastK2 = FastKCustom(fastD1, KPeriod);

plot STC = MovingAverage(averageType, fastK2, DPeriod);
STC.HideBubble();

plot CenterLine = 50;
CenterLine.HideBubble();
CenterLine.AssignValueColor(Color.GRAY);
CenterLine.SetPaintingStrategy(PaintingStrategy.DASHES);

plot OverBought = over_bought;
OverBought.HideBubble();

plot OverSold = over_sold;
OverSold.HideBubble();

STC.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
OverSold.SetDefaultColor(GetColor(7));

def Diff = STC - STC[1];
STC.SetLineWeight(3);

STC.DefineColor("Positive and Up", Color.GREEN);
STC.DefineColor("Positive and Down", Color.DARK_GREEN);
STC.DefineColor("Negative and Down", Color.RED);
STC.DefineColor("Negative and Up", Color.DARK_RED);
STC.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then STC.color("Positive and Up") else STC.color("Positive and Down") else if Diff < Diff[1] then STC.color("Negative and Down") else STC.color("Negative and Up"));

AddCloud(OverSold,0,Color.LIGHT_GREEN);
AddCloud(100,OverBought,Color.LIGHT_RED);
Click to expand...
can you share upper part of the chart
 
@Sesqui - Can you share the TOS chart link that we can import in TOS so that all the studies get in. Appreciate your help and I am looking forward to testing this.

​

 
@Sesqui:

Adaptive Williams % R indicator:

CSS:Copy to clipboard
# Adpative Aroon Indicator script by Sesqui 29AUG2025
declare lower;

Ok- The script says %R, but the code is fo Adaptive Aroon indicator- am I missing something??
 
Ramesh16 said:
@Sesqui:

Adaptive Williams % R indicator:

CSS:Copy to clipboard
# Adpative Aroon Indicator script by Sesqui 29AUG2025
declare lower;

Ok- The script says %R, but the code is fo Adaptive Aroon indicator- am I missing something??
Click to expand...

It is true that the header in the %R indicator is mislabeled. Understandable given that @Sesqui mass-produced so many excellent indicators.

It does appear to be a Williams %R study. Were you expecting it to behave differently?
Scroll 3/4 down the beginning post and re-copy and paste...
 
You must log in or register to reply here.
Thread starter Similar threads Forum Replies Date
chewie76 Adaptive RSI Overlay and Zones conversion for Thinkorswim Custom 10
S Adaptive True Momentum Oscillator for ThinkOrSwim Custom 6
S Adaptive StochasticFull for ThinkOrSwim Custom 0
S Adaptive Universal Oscillator for ThinkOrSwim Custom 5
S Adaptive CCI for ThinkOrSwim Custom 2

Similar threads

Not the exact question you're looking for?

Start a new thread and receive assistance from our community.

87k+ Posts
792 Online
Create Post

Similar threads

Similar threads

The Market Trading Game Changer

Join 2,500+ subscribers inside the useThinkScript VIP Membership Club
  • Exclusive indicators
  • Proven strategies & setups
  • Private Discord community
  • ‘Buy The Dip’ signal alerts
  • Exclusive members-only content
  • Add-ons and resources
  • 1 full year of unlimited support
Try VIP Club Today

Frequently Asked Questions

What is useThinkScript?

useThinkScript is the #1 community of stock market investors using indicators and other tools to power their trading strategies. Traders of all skill levels use our forums to learn about scripting and indicators, help each other, and discover new ways to gain an edge in the markets.

How do I get started?

We get it. Our forum can be intimidating, if not overwhelming. With thousands of topics, tens of thousands of posts, our community has created an incredibly deep knowledge base for stock traders. No one can ever exhaust every resource provided on our site.

If you are new, or just looking for guidance, here are some helpful links to get you started.

What are the benefits of VIP Membership?
VIP members get exclusive access to these proven and tested premium indicators: Buy the Dip, Advanced Market Moves 2.0, Take Profit, and Volatility Trading Range. In addition, VIP members get access to over 50 VIP-only custom indicators, add-ons, and strategies, private VIP-only forums, private Discord channel to discuss trades and strategies in real-time, customer support, trade alerts, and much more. Learn all about VIP membership here.
How can I access the premium indicators?
To access the premium indicators, which are plug and play ready, sign up for VIP membership here.
Back
Top