TTM_Wave For ThinkorSwim

[Dix]

In my watchlists I would like to add a column where I can see the values of the TTM Wave for each stock. Can someone assist with the code part? I know how to add columns to my watchlists, etc. Essentially I want to run a pre-market scan to see for example TTM Waves that are greater than +2 or less than -2 for example. I know how to build the scan but also want to add the TTM Wave values to my watchlist for easier sorting. Thanks!

 

[halcyonguy]

Thank you very much for your corrections. It will not show Wave B or C when I unselect Wave A.

welcome
i think you are looking at the wrong study.
they have similar names. mine has a _00b on the end.

 

[halcyonguy]

Thank you very much for your corrections. It will not show Wave B or C when I unselect Wave A.

welcome
i think you are looking at the wrong study.
they have similar names. mine has a _00b on the end.

mine has a drop down to pick one of the wave letters.
yours had 3 inputs.

input wave = { default "A" , "B" , "C" };

settings - wave select

 

[merryDay]

Here is a Mobius version

# Mobius ABC Waves
# V01.2015
# Long Wave (C), Medium Wave (B), and Short Wave (A)

declare lower;

def c = close;
plot Value = ExpAverage(ExpAverage(c, 5) -
             ExpAverage(c, 13), 3);
     Value.DefineColor("Blue",Color.CYAN);
     Value.DefineColor("Red", Color.RED);
     Value.AssignValueColor(if Value >= Value[1]
                            then Value.color("Blue")
                            else Value.color("Red"));
     Value.HideTitle();
     Value.HideBubble();
# Wave A
def fastMA1 = ExpAverage(c, 5 * 2);
def slowMA1 = ExpAverage(c, 13 * 2);
def macd1 = fastMA1 - slowMA1;
def signal1 = ExpAverage(macd1, 13 * 2);
plot hist1 = macd1 - signal1;
     hist1.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist1.AssignValueColor(if hist1 < 0 and hist1 < hist1[1]
                            then color.dark_red
                            else if hist1 < 0 and
                                    hist1 > hist1[1]
                                 then color.yellow
                            else if hist1 > 0 and
                                    hist1 > hist1[1]
                                 then color.yellow
                            else color.dark_red);
    hist1.HideBubble();
    hist1.HideTitle();
def fastMA2 = ExpAverage(c, 5 * 2);
def slowMA2 = ExpAverage(c, 13 * 3);
def macd2 = fastMA2 - slowMA2;
def signal2 = ExpAverage(macd2, 13 * 3);
plot hist2 = macd2 - signal2;
     hist2.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist2.AssignValueColor(if hist2 < 0 and hist2 < hist2[1]
                            then color.dark_red
                            else if hist2 < 0 and
                                    hist2 > hist2[1]
                                 then color.yellow
                            else if hist2 > 0 and
                                    hist2 > hist2[1]
                                 then color.yellow
                            else color.dark_red);
    hist2.HideBubble();
    hist2.HideTitle();
# Wave B
def fastMA3 = ExpAverage(c, 5 * 2);
def slowMA3 = ExpAverage(c, 13 * 5);
def macd3 = fastMA3 - slowMA3;
def signal3 = ExpAverage(macd3, 13 * 5);
plot hist3 = macd3 - signal3;
     hist3.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist3.AssignValueColor(if hist2 < 0
                            then color.blue
                            else color.cyan);
    hist3.HideBubble();
    hist3.HideTitle();
def fastMA4 = ExpAverage(c, 5 * 2);
def slowMA4 = ExpAverage(c, 13 * 10);
def macd4 = fastMA4 - slowMA4;
def signal4 = ExpAverage(macd4, 13 * 10);
plot hist4 = macd4 - signal4;
     hist4.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist4.AssignValueColor(if hist2 < 0
                            then color.blue
                            else color.cyan);
    hist4.HideBubble();
    hist4.HideTitle();
# Wave C
def fastMA5 = ExpAverage(c, 5 * 2);
def slowMA5 = ExpAverage(c, 13 * 20);
def macd5 = fastMA5 - slowMA5;
def signal5 = ExpAverage(macd5, 13 * 20);
plot hist5 = macd5 - signal5;
     hist5.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist5.AssignValueColor(if hist2 < 0
                            then color.blue
                            else color.cyan);
    hist5.HideBubble();
    hist5.HideTitle();
def fastMA6 = ExpAverage(c, 5 * 2);
def slowMA6 = ExpAverage(c, 13 * 30);
plot macd6 = fastMA6 - slowMA6;
     macd6.SetPaintingStrategy(PaintingStrategy.Histogram);
     macd6.AssignValueColor(if hist2 < 0
                            then color.blue
                            else color.cyan);
    macd6.HideBubble();
    macd6.HideTitle();
plot zero = if isNaN(c) then double.nan else 0;
     zero.SetDefaultColor(Color.yellow);
     zero.HideBubble();
     zero.HideTitle();
# End Code Mobius ABC Waves

 

[SealTrades]

I really liked the idea of creating more screen real estate by making the ABC Wave confluence a simple line on the chart. I created the Bearish condition to plot as well. This is my first attempt at coding anything, and for some reason it wouldn't work as one ThinkScript so my work-around was to create two separate studies (one bear, one bull) and then make the black lines (referred to as Neutral Waves) fully transparent by creating a Global Colors setting that can be manipulated. I then plotted it to the Squeeze indicator vs. the actual chart.

# Draw Vertical Signal when All Histogram Waves are above the Zero Line

DefineGlobalColor("Bullish Waves", Color.DARK_GREEN);
DefineGlobalColor("Neutral Waves", Color.Black);

AddVerticalLine(close, ”” , (if TTM_Wave()."Wave1" >0 and TTM_Wave()."Wave2high" >0 and  TTM_Wave()."Wave2low" >0 then GlobalColor("Bullish Waves") else GlobalColor("Neutral Waves")));

# Draw Vertical Signal when All Histogram Waves are below the Zero Line

DefineGlobalColor("Bearish Waves", Color.Dark_RED);
DefineGlobalColor("Neutral Waves", Color.Black);

AddVerticalLine(close, ”” , (if TTM_Wave()."Wave1" <0 and TTM_Wave()."Wave2high" <0 and  TTM_Wave()."Wave2low" <0 then GlobalColor("Bearish Waves") else GlobalColor("Neutral Waves")));

Photos for Reference
Notice lines on Squeeze Indicator:

Settings (make "Neutral Waves" fully transparent on both studies):

 

[mgnichols]

Good afternoon Members!
Seeking help with script for TOS scanner. Hopefully simple but still above what I'm able to do.

I utilize the TTM Wave (1) or A on my chart. Red and Yellow Histogram.
Looking for scanner code that identifies stocks where the histogram bar is changing today from red to yellow or trending better than the previous day.

Thanks!

 

[bakly]

Good afternoon Members!
Seeking help with script for TOS scanner. Hopefully simple but still above what I'm able to do.

I utilize the TTM Wave (1) or A on my chart. Red and Yellow Histogram.
Looking for scanner code that identifies stocks where the histogram bar is changing today from red to yellow or trending better than the previous day.

Thanks!

plot YellowHistogram = TTM_Wave()."Wave1" is greater than TTM_Wave()."Wave1" from 1 bars ago;
plot RedHistogram = TTM_Wave()."Wave1" is less than TTM_Wave()."Wave1" from 1 bars ago;

 

[WOLVES]

Hi guys,
I am trying to create a ttm wave watchlist, with A,B and C above zero for going long or below zero for going short. with colored background. here is what I have so far:

def waveA = TTM_Wave().Wave1;
def abovezero = waveA > 0;
def belowzero = waveA < 0;
AssignBackgroundColor(
if abovezero and abovezero[1] then Color.GREEN
else if belowzero and !belowzero[1] then Color.RED
else color.black );
plot scan = abovezero && belowzero;


im trying to add below zero as well but, can't figure out how to do it. I would also want to add if its long or short. For example, it C wave is above zero it would be green and say long.

the watchlist is from Dr John Carter lecture timestamp 17:24.The Squeeze" by John F. Carter - As Seen on TradeStation TradingApp Store Showcase

Thanks

 

[WOLVES]

welcome
i think you are looking at the wrong study.
they have similar names. mine has a _00b on the end.

mine has a drop down to pick one of the wave letters.
yours had 3 inputs.

input wave = { default "A" , "B" , "C" };

settings - wave select

Hi,
is it possible to make this into a watchlist?

 

[halcyonguy]

you will need to come up formulas for waves A, B, C before anything can be done.

ttm_wave has 3 plots
plot Wave1 =
plot Wave2High =
plot Wave2Low =

none of them are A , B, C

 

[JustDoIt]

please help,
I am looking for ttmwave1, ttmwave2high and ttmwave2low, crossing above/below zero line, countconsecutive with labels green crossing above, red crossing below
Thank you

 

[halcyonguy]

please help,
I am looking for ttmwave1, ttmwave2high and ttmwave2low, crossing above/below zero line, countconsecutive with labels green crossing above, red crossing below
Thank you

it is unclear what you want to see.
i think you want a watchlist column?

3 main questions to answer,
1. where do you want to see something?
2. what do you want to see?
3. when do you want to see something?

1. i think watchlist column
2. i have no idea
3. when a crossing occurs

so, we have to figure out #2.
you want,
to track 3 variables,
a red or green on a crossing
count something...

i don't know what count consecutive means? count what? when?

i don't know if you want 3 separate columns to track each plot variable?
or all combined into 1 column?

---------------------------


this is a lower study, that should help you decide what you want to see.

it combines all 3 plot signals into 1 label.
also has 3 separate labels.

the labels turn red or green on a crossing.
3 numbers show the count of bars , back to a recent crossing.
. they start at 1 or -1 on a crossing.
. positive numbers if a cross up
. negative numbers if a cross down


https://tlc.thinkorswim.com/center/reference/Tech-Indicators/studies-library/T-U/TTM-Wave

# col_ttmwave_crossings_00_lower

#https://usethinkscript.com/threads/ttmwave-custom-column.14545/
#I am looking for ttmwave1, ttmwave2high and ttmwave2low, crossing above/below zero line, count consecutive with labels green crossing above, red crossing below



#this combines all 3 into 1 col
#red green on cross
#3 numbers show the count of bars , back  to a recent cross , for the 3 plots.
#they start at 1 or -1 on a cross
#pos# if was up
#neg# if was dwn


#--------------

declare lower;

def bn = barnumber();
def na = Double.NaN;

def w1 = TTM_Wave().Wave1;
def w2hi = TTM_Wave().Wave2High;
def w2lo = TTM_Wave().Wave2Low;
def wz = TTM_Wave().ZeroLine;

input show_lines = yes;
plot z1 = if show_lines then w1 else na;
plot z2 = if show_lines then w2hi else na;
plot z3 = if show_lines then w2lo else na;
plot z4 = if show_lines then wz else na;


# count from recent crossing,
#.  cnt pos after a cross up
#.  cnt neg after a cross down

def w1x = if bn == 1 then 0
 else if w1 crosses above wz then 1
 else if w1 crosses below wz then -1
 else w1x[1] + sign(w1x[1]) ;

def w2hix = if isnan(w2hix[1]) or bn == 1 then 0
 else if w2hi crosses above wz then 1
 else if w2hi crosses below wz then -1
 else w2hix[1] + sign(w2hix[1]) ;

def w2lox = if bn == 1 then 0
 else if w2lo crosses above wz then 1
 else if w2lo crosses below wz then -1
 else w2lox[1] + sign(w2lox[1]) ;


#assignbackgroundcolor(
#if (w1x == 1 or w2hix == 1 or w2lox == 1) then color.green
#else if (w1x == -1 or w2hix == -1 or w2lox == -1) then color.red
#else color.gray);


#------------------------


addlabel(1,
((if w1x > 0 then " " else "") +
w1x + " | " +
(if w2hix > 0 then " H" else "H") +
w2hix + " | " +
(if w2lox > 0 then " L" else "L") +
w2lox)
, color.yellow);
#, color.black);

#------------------------

addlabel(1, " ", color.black);
addlabel(1,
 "wave1 " + (if w1x > 0 then " " else "") + w1x 
, if w1x == 1 then color.green else if w1x == -1 then color.red else color.gray);

#------------------------

addlabel(1, " ", color.black);
addlabel(1,
 "wave2 hi " + (if w2hix > 0 then " " else "") + w2hix
, if w2hix == 1 then color.green else if w2hix == -1 then color.red else color.gray);

#------------------------

addlabel(1, " ", color.black);
addlabel(1,
 "wave2 lo " + (if w2lox > 0 then " " else "") + w2lox
, if w2lox == 1 then color.green else if w2lox == -1 then color.red else color.gray);

#-------------------------
#

 

[JustDoIt]

@halcyonguy custom column, need to know when ttmwave1, ttmwave2 high or ttmwave2 low above zero line, the counts +1,2,3 so on the same when crossing below zero line counts -1,-2,-3, and so on

 

[Piper2808t]

#
# TD Ameritrade IP Company, Inc. (c) 2010-2023
#
# Source code isn't available.

declare lower;

plot Wave1 = Double.NaN;
plot Wave2High = Double.NaN;
plot Wave2Low = Double.NaN;
plot ZeroLine = Double.NaN;



curious if this can be made into mtf?

 

[merryDay]

#
# TD Ameritrade IP Company, Inc. (c) 2010-2023
#
# Source code isn't available.

declare lower;

plot Wave1 = Double.NaN;
plot Wave2High = Double.NaN;
plot Wave2Low = Double.NaN;
plot ZeroLine = Double.NaN;



curious if this can be made into mtf?

The script is proprietary. Without the script, it is not possible to modify the script.

There are many other non-proprietary scripts in this thread that you could adapt.
Here is how to create an MTF:
https://usethinkscript.com/threads/converting-indicator-to-multi-timeframe-mtf-in-thinkorswim.8050/

 

[dj45]

Here is a Mobius version

# Mobius ABC Waves
# V01.2015
# Long Wave (C), Medium Wave (B), and Short Wave (A)

declare lower;

def c = close;
plot Value = ExpAverage(ExpAverage(c, 5) -
             ExpAverage(c, 13), 3);
     Value.DefineColor("Blue",Color.CYAN);
     Value.DefineColor("Red", Color.RED);
     Value.AssignValueColor(if Value >= Value[1]
                            then Value.color("Blue")
                            else Value.color("Red"));
     Value.HideTitle();
     Value.HideBubble();
# Wave A
def fastMA1 = ExpAverage(c, 5 * 2);
def slowMA1 = ExpAverage(c, 13 * 2);
def macd1 = fastMA1 - slowMA1;
def signal1 = ExpAverage(macd1, 13 * 2);
plot hist1 = macd1 - signal1;
     hist1.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist1.AssignValueColor(if hist1 < 0 and hist1 < hist1[1]
                            then color.dark_red
                            else if hist1 < 0 and
                                    hist1 > hist1[1]
                                 then color.yellow
                            else if hist1 > 0 and
                                    hist1 > hist1[1]
                                 then color.yellow
                            else color.dark_red);
    hist1.HideBubble();
    hist1.HideTitle();
def fastMA2 = ExpAverage(c, 5 * 2);
def slowMA2 = ExpAverage(c, 13 * 3);
def macd2 = fastMA2 - slowMA2;
def signal2 = ExpAverage(macd2, 13 * 3);
plot hist2 = macd2 - signal2;
     hist2.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist2.AssignValueColor(if hist2 < 0 and hist2 < hist2[1]
                            then color.dark_red
                            else if hist2 < 0 and
                                    hist2 > hist2[1]
                                 then color.yellow
                            else if hist2 > 0 and
                                    hist2 > hist2[1]
                                 then color.yellow
                            else color.dark_red);
    hist2.HideBubble();
    hist2.HideTitle();
# Wave B
def fastMA3 = ExpAverage(c, 5 * 2);
def slowMA3 = ExpAverage(c, 13 * 5);
def macd3 = fastMA3 - slowMA3;
def signal3 = ExpAverage(macd3, 13 * 5);
plot hist3 = macd3 - signal3;
     hist3.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist3.AssignValueColor(if hist2 < 0
                            then color.blue
                            else color.cyan);
    hist3.HideBubble();
    hist3.HideTitle();
def fastMA4 = ExpAverage(c, 5 * 2);
def slowMA4 = ExpAverage(c, 13 * 10);
def macd4 = fastMA4 - slowMA4;
def signal4 = ExpAverage(macd4, 13 * 10);
plot hist4 = macd4 - signal4;
     hist4.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist4.AssignValueColor(if hist2 < 0
                            then color.blue
                            else color.cyan);
    hist4.HideBubble();
    hist4.HideTitle();
# Wave C
def fastMA5 = ExpAverage(c, 5 * 2);
def slowMA5 = ExpAverage(c, 13 * 20);
def macd5 = fastMA5 - slowMA5;
def signal5 = ExpAverage(macd5, 13 * 20);
plot hist5 = macd5 - signal5;
     hist5.SetPaintingStrategy(PaintingStrategy.Histogram);
     hist5.AssignValueColor(if hist2 < 0
                            then color.blue
                            else color.cyan);
    hist5.HideBubble();
    hist5.HideTitle();
def fastMA6 = ExpAverage(c, 5 * 2);
def slowMA6 = ExpAverage(c, 13 * 30);
plot macd6 = fastMA6 - slowMA6;
     macd6.SetPaintingStrategy(PaintingStrategy.Histogram);
     macd6.AssignValueColor(if hist2 < 0
                            then color.blue
                            else color.cyan);
    macd6.HideBubble();
    macd6.HideTitle();
plot zero = if isNaN(c) then double.nan else 0;
     zero.SetDefaultColor(Color.yellow);
     zero.HideBubble();
     zero.HideTitle();
# End Code Mobius ABC Waves

Can someone please explain how to interpret this? It looks like the yellow/red histogram is Wave A (the shortest term wave). Not clear to me if the blue/cyan histogram is Wave B or C. And it looks like the plotted line is none of the waves.

What I ended up doing is adding TOS default TTM_Wave script to the chart 3 times as lower panels so I could have each of wave A, B, and C plotted separately. According to some site I found, for:
Wave A: turn off plots for Wave2High and Wave2Low (Wave1 is Wave A)
Wave B: turn off plots for Wave1 and Wave2Low (Wave2High is Wave B)
Wave C: turn off plots for Wave1 and Wave2High (Wave2Low is Wave C)

Does anyone know if this is correct regarding TOS default TTM_Wave script? Since it's a TOS built-in script, the code is not available for viewing.

 

[GNFblade]

Im trying to make a script that uses the ttm_wave but i cant find the source code or a replaca. I have my own ttm_wave version, but its not exatcly like the original and well, im stuck. Would appreciate any advice or help, thanks.

 

[useThinkScript]

Im trying to make a script that uses the ttm_wave but i cant find the source code or a replaca. I have my own ttm_wave version, but its not exatcly like the original and well, im stuck. Would appreciate any advice or help, thanks.

Your question was moved here. These thread contains a few attempts.

 

[GNFblade]

Im trying to make a script that uses the ttm_wave but i cant find the source code or a replaca. I have my own ttm_wave version, but its not exatcly like the original and well, im stuck. Would appreciate any advice or help, thanks.

Here is the exact TTM_Wave code from thinkorswim. It’s a combo of all the fib macds. Took me a month to figure this out because of all the misleading and incorrect information about how the TTM_wave works.

declare lower;

def macd1 = ExpAverage(close, 8) - ExpAverage(close, 34);
def macd2 = ExpAverage(close, 8) - ExpAverage(close, 55);
def macd3 = ExpAverage(close, 8) - ExpAverage(close, 89);
def macd4 = ExpAverage(close, 8) - ExpAverage(close, 144);
def macd5 = ExpAverage(close, 8) - ExpAverage(close, 233);

plot Wave1 = macd1;
Wave1.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Wave1.SetDefaultColor(Color.CYAN);

def w2high =
if macd1 >= macd2 and macd1 >= macd3 and macd1 >= macd4 and macd1 >= macd5 then macd1
else if macd2 >= macd1 and macd2 >= macd3 and macd2 >= macd4 and macd2 >= macd5 then macd2
else if macd3 >= macd1 and macd3 >= macd2 and macd3 >= macd4 and macd3 >= macd5 then macd3
else if macd4 >= macd1 and macd4 >= macd2 and macd4 >= macd3 and macd4 >= macd5 then macd4
else macd5;

def w2low =
if macd1 <= macd2 and macd1 <= macd3 and macd1 <= macd4 and macd1 <= macd5 then macd1
else if macd2 <= macd1 and macd2 <= macd3 and macd2 <= macd4 and macd2 <= macd5 then macd2
else if macd3 <= macd1 and macd3 <= macd2 and macd3 <= macd4 and macd3 <= macd5 then macd3
else if macd4 <= macd1 and macd4 <= macd2 and macd4 <= macd3 and macd4 <= macd5 then macd4
else macd5;

plot Wave2High = w2high;
Wave2High.SetDefaultColor(Color.GREEN);
Wave2High.SetLineWeight(2);

plot Wave2Low = w2low;
Wave2Low.SetDefaultColor(Color.RED);
Wave2Low.SetLineWeight(2);

plot ZeroLine = 0;
ZeroLine.SetDefaultColor(Color.GRAY);
ZeroLine.SetStyle(Curve.SHORT_DASH);

 

[BillW]

I asked CoPilot to script TTM_Wave. It was pretty good then got really good after I added a MACD Histogram. In keeping up with the coming season the Easter Bunny has hidden an indicator if you upload the hyperlink.

declare lower;

plot ZeroLine = 0;
ZeroLine.SetDefaultColor(CreateColor(64, 64, 64));

ZeroLine.HideTitle();

input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;
input showBreakoutSignals = no;

plot Diff = MACD(fastLength, slowLength, MACDLength, averageType).Diff *2;




Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.DefineColor("Positive and Up", CreateColor(64, 234, 255));
Diff.DefineColor("Positive and Down", CreateColor(0, 167, 0));
Diff.DefineColor("Negative and Down", CreateColor (167,0,0));
Diff.DefineColor("Negative and Up", CreateColor (255,64,134));
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.color("Positive and Up") else Diff.color("Positive and Down") else if Diff < Diff[1] then Diff.color("Negative and Down") else Diff.color("Negative and Up"));

input price = close;

# --- A Wave (Wave1): average of short-term MACDs using Fib EMAs ---

def macd1 = ExpAverage(price, 8)  - ExpAverage(price, 34);
def macd2 = ExpAverage(price, 8)  - ExpAverage(price, 55);
def macd3 = ExpAverage(price, 8)  - ExpAverage(price, 89);
def macd4 = ExpAverage(price, 8)  - ExpAverage(price, 144);
def macd5 = ExpAverage(price, 8)  - ExpAverage(price, 233);

plot Wave1 = (macd1 + macd2 + macd3 + macd4 + macd5) / 5;

Wave1.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Wave1.SetLineWeight(3);
Wave1.AssignValueColor(
    if Wave1 > 0 then Color.dark_orange
    else if Wave1 < 0 then Color.RED
    else Color.GRAY
);

# --- C Wave (Wave2High / Wave2Low): envelope of longer-term MACDs ---

def macd6  = ExpAverage(price, 13) - ExpAverage(price, 34);
def macd7  = ExpAverage(price, 13) - ExpAverage(price, 55);
def macd8  = ExpAverage(price, 13) - ExpAverage(price, 89);
def macd9  = ExpAverage(price, 13) - ExpAverage(price, 144);
def macd10 = ExpAverage(price, 13) - ExpAverage(price, 233);

plot Wave2High = Max(Max(Max(Max(macd6, macd7), macd8), macd9), macd10);
plot Wave2Low  = Min(Min(Min(Min(macd6, macd7), macd8), macd9), macd10);

Wave2High.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Wave2Low.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Wave2High.SetLineWeight(2);
Wave2Low.SetLineWeight(2);
Wave2High.AssignValueColor(Color.BLUE);
Wave2Low.AssignValueColor(Color.BLUE);

Hyperlink with Shared chart including an egg in your Easter basket

https://tos.mx/!djF7V3VQ