VWAP deviations as horizontal lines?

[Alex]

Make the vwap and its 2 standard deviations appear as self adjusting extended horizontal lines? would it be possible to make?

 

[Alex]

@generic Not quite... As the vwap and the deviations adjust throughout the trading day I'd like them to display as horizontal lines instead of the "typical" vwap. I think its possible...

Standard VWAP:

what I mean:

 

[BenTen]

@Alex You said it yourself, VWAP move throughout the day. It's not static. As a result, you can't display it as a horizontal line.

 

[Alex]

@Alex You said it yourself, VWAP move throughout the day. It's not static. As a result, you can't display it as a horizontal line.

Sorry I meant that the horizontal lines would adjust and move accordingly to the vwap bubbles to the right. Instead of the traditional vwap bands.

 

[generic]

@Alex So let me get this straight you want the horizontal bands to be constantly updated to the newest VWAP value? If so, then that is doable.

 

[germanburrito]

Correct

This would actually be a great idea

Can you think of a study that has that coded in it, we can take the code from there.

 

[BenTen]

@germanburrito @Alex Take a look at this script by @Welkin https://usethinkscript.com/threads/...e-at-moving-average-crossover.3551/post-33109

 

[generic]

@Alex @germanburrito Not exactly what you want but this is the extent of my copy and paste coding skills.

input numDevDn = -2.0;
input numDevUp = 2.0;
input timeFrame = {default DAY, WEEK, MONTH};

def cap = getAggregationPeriod();
def errorInAggregation =
    timeFrame == timeFrame.DAY and cap >= AggregationPeriod.WEEK or
    timeFrame == timeFrame.WEEK and cap >= AggregationPeriod.MONTH;
assert(!errorInAggregation, "timeFrame should be not less than current chart aggregation period");

def yyyyMmDd = getYyyyMmDd();
def periodIndx;
switch (timeFrame) {
case DAY:
    periodIndx = yyyyMmDd;
case WEEK:
    periodIndx = Floor((daysFromDate(first(yyyyMmDd)) + getDayOfWeek(first(yyyyMmDd))) / 7);
case MONTH:
    periodIndx = roundDown(yyyyMmDd / 100, 0);
}
def isPeriodRolled = compoundValue(1, periodIndx != periodIndx[1], yes);

def volumeSum;
def volumeVwapSum;
def volumeVwap2Sum;

if (isPeriodRolled) {
    volumeSum = volume;
    volumeVwapSum = volume * vwap;
    volumeVwap2Sum = volume * Sqr(vwap);
} else {
    volumeSum = compoundValue(1, volumeSum[1] + volume, volume);
    volumeVwapSum = compoundValue(1, volumeVwapSum[1] + volume * vwap, volume * vwap);
    volumeVwap2Sum = compoundValue(1, volumeVwap2Sum[1] + volume * Sqr(vwap), volume * Sqr(vwap));
}
def price = volumeVwapSum / volumeSum;
def deviation = Sqrt(Max(volumeVwap2Sum / volumeSum - Sqr(price), 0));
def upper = price + numDevUp * deviation;
def lower = price + numDevDn * deviation;

def currentbar = if !isnan(close) && isnan(close[-1]) then barnumber() else double.nan;
def vwap_line = if barnumber() == currentbar then price else double.nan;
def upper_line = if barnumber() == currentbar then upper else double.nan;
def lower_line = if barnumber() == currentbar then lower else double.nan;

plot VWAP = highestall(vwap_line);
plot UpperBand = highestall(upper_line);
plot LowerBand = highestall(lower_line);

VWAP.setDefaultColor(getColor(0));
UpperBand.setDefaultColor(getColor(2));
LowerBand.setDefaultColor(getColor(4));

 

[germanburrito]

@generic this is great thank you so much, was trying to figuere it out all night.

 

[BenTen]

Saw this in the OneNote drive:

# Horizontal Line at current VWAP JQ
# chatroom request for generic
# 2020-11-18

def currentbar = if !isnan(close) && isnan(close[-1]) then barnumber() else double.nan;
def var1 = if barnumber() == currentbar then vwap else double.nan;
plot currentVWAP = highestall(var1);

#plot debug = vwap;
# That's All Folks!

 

[Alex]

@generic

 

[generic]

@Alex @germanburrito Updated the code above to do exactly what you want. Thanks to @BenTen
Heres the link if you need it

http://tos.mx/cZOtww6

 

[germanburrito]

@Alex @germanburrito Updated the code above to do exactly what you want. Thanks to @BenTen
Heres the link if you need it

http://tos.mx/cZOtww6

thank you much guys, this community is truly great!

 

[Soloways]

@BenTen Is there a way to display VWAP Deviations on a longer timeframe? Like on this chart??

 

[germanburrito]

@Soloways With this you can set the bar where you want the count to start from, youre goiont to need a bar counter that goes in the lower study

declare lower;
plot b = barnumber();
#VM_MIDAS_StandartDeviationBands;
def Data = BarNumber();
input Number_Of_Bar = 1;
input price = close;
def bar =  Data >= Number_Of_Bar;
def pv = if bar then pv[1] + price * volume else 0;
def cumvolume = if bar then cumvolume[1] + volume else 0;
plot vw = pv / cumvolume;
def bars = Data - Number_Of_Bar;
def sample = if bar then sample[1] + Sqr(price - vw) else 0;
def var = sample / bars;
def dev = Sqrt(var);

plot dev1 =  vw + dev * 2;
plot dev2 = vw - (dev * 2);
plot dev3 = vw + (dev * 1);
plot devN1 =  vw - dev * 1;


vw.setdefaultColor(color.yellow);
dev1.SetDefaultColor(Color.White);
dev2.SetDefaultColor(Color.White);
dev3.SetDefaultColor(Color.White);
devn1.SetDefaultColor(Color.White);


dev1.Setlineweight(2);
dev2.Setlineweight(2);
dev3.Setlineweight(2);
devn1.Setlineweight(2);

 

[Soloways]

@Soloways With this you can set the bar where you want the count to start from, youre goiont to need a bar counter that goes in the lower study

You mean something like this Consecutive Bar Counter?

https://usethinkscript.com/threads/consecutive-bar-count-indicator-for-thinkorswim.324/

I am not entirely sure what you mean by Bar Counter.....and setting it

 

[germanburrito]

You mean something like this Consecutive Bar Counter?

https://usethinkscript.com/threads/consecutive-bar-count-indicator-for-thinkorswim.324/

I am not entirely sure what you mean by Bar Counter.....and setting it

no the settings on the indicator ask for a bar number, to tell what the needed bar number you use a lower indicator

 

[Soloways]

no the settings on the indicator ask for a bar number, to tell what the needed bar number you use a lower indicator

ok thank you
I appreciate your help

 

[Soloways]

no the settings on the indicator ask for a bar number, to tell what the needed bar number you use a lower indicator

to be honest, i am completely lost
so i loaded your code you put together
and added it to XPEV 30D 1HR chart and this is what i get

so to change the bar number in the settings of the indicator.....
i understood it to be this.....

so what number of bars should i enter in order for the my chart to look like the example chart i posted in the beginning
like this....

 

[germanburrito]

to be honest, i am completely lost
so i loaded your code you put together
and added it to XPEV 30D 1HR chart and this is what i get

so to change the bar number in the settings of the indicator.....
i understood it to be this.....

so what number of bars should i enter in order for the my chart to look like the example chart i posted in the beginning
like this....

YOU NEED LOWER INDICATOR THAT TELL YOU WHAT THE NUMBER BAR YOU WANT TO START THE CALCULATION FROM IS HERES IT IS....
WHAT YOU DO IS YOU HOVER OVER THE BAR YOU WANT TO START FROM, YOU SEE THE BAR NUMBER AND YOU INPUT IT IN THE VWAP


declare lower;
plot b = barnumber();