Volume Strength Finder For ThinkOrSwim

[Katsu]

Author states,
Generally, Volume indicator shows total Volume of a candle. In this Volume Strength Finder Indicator, I tried to separate Strength of buyers and sellers based on the candle stick pattern. Calculating Buyer and Seller Strength each and every candle of the day based on the pattern formation.

High - close => Buyers
Close - low => Sellers

in this way, cumulative volume separates for buyer and sellers and comparing with total volume of the day and showing results.

Here is the original Tradingview code:
https://www.tradingview.com/script/yYa3hro5-Volume-Strength-Finder/


For the new ThinkOrSwim code, you must scroll down to the next post

 

[samer800]

https://www.tradingview.com/script/yYa3hro5-Volume-Strength-Finder/

check the below:

#// Indicator for TOS
#// © Saravanan_Ragavan
#indicator('Volume Strength Finder', 'VSF', overlay = true)
# Converted by Sam4Cok@Samer800    - 03/2025

input showLabel = yes;
input colorBars = yes;
input startTime = 0930;

def na = Double.NaN;
def last = isNaN(close);
def bar = bar[1] + 1;
def T1 = SecondsFromTime(startTime) == 0;
def z1 = if T1 then bar else z1[1];
def L = Max(bar - Z1 + 1, 1);
def pdw = volume[0] * (close[0] - low[0]) / (high[0] - low[0]);
def ndw = volume[0] * (high[0] - close[0]) / (high[0] - low[0]);
def SSPV1 = fold i = 1 to L with p=pdw do
           p + (GetValue(volume, i) * (GetValue(close, i) - GetValue(low, i)) / (GetValue(high, i) - GetValue(low, i)));
def SSNV1 = fold j = 1 to L with q=ndw do
           q + (GetValue(volume, j) * (GetValue(high, j) - GetValue(close, j)) / (GetValue(high, j) - GetValue(low, j)));

def SSPV = if IsNaN(SSPV1) then 0 else SSPV1;
def SSNV = if IsNaN(SSNV1) then 0 else SSNV1;
def total_v = SSPV1 + SSNV1;
def Pos = SSPV / total_v * 100;
def Neg = SSNV / total_v * 100;
def todVol = if !last then total_v else na;
def BuyVol = if !last then Round(SSPV, 0) else na;
def SellVol = if !last then Round(SSNV, 0) else na;
def BuyPer = if !last then Round(Pos, 0) else na;
def SellPer = if !last then Round(Neg, 0) else na;


AssignPriceColor(if !colorBars then Color.CURRENT else
                 if SSPV > SSNV then Color.CYAN else
                 if SSPV < SSNV then Color.MAGENTA else Color.GRAY);

AddLabel(showLabel, "Today's Vol (" + todVol + ")", Color.WHITE);
AddLabel(showLabel, "Buyers Vol (" + BuyVol + ")", Color.GREEN);
AddLabel(showLabel, "Sellers Vol (" + SellVol + ")", Color.RED);
AddLabel(showLabel, "Buyers Strength (" + BuyPer + "%)", Color.GREEN);
AddLabel(showLabel, "Sellers Strength (" + SellPer + "%)", Color.RED);

#-- END of CODE

 

[Katsu]

Thank you so much!!!!