Timestamp "study"

[linced]

Hi guys,
I'd like to add a timestamp on a multi-intraday-chart.

Since I look at multiple timeframes of a ticker (four charts in one window), if I do it with text it's going to show on the other charts. (which I don't want).

Is there a way to create a study for the explicit chart I want and have the DATE, e.g. DDMMYY up/down in a corner?

 

[SleepyZ]

Hi guys,
I'd like to add a timestamp on a multi-intraday-chart.

Since I look at multiple timeframes of a ticker (four charts in one window), if I do it with text it's going to show on the other charts. (which I don't want).

Is there a way to create a study for the explicit chart I want and have the DATE, e.g. DDMMYY up/down in a corner?

Put this in a separate study only on the chart you want it to display in your grid.

def year  = GetYear() - (Round(GetYYYYMMDD() / 1000000, 0) * 100);
def Month = GetMonth();
def Day   = GetDayOfMonth(GetYYYYMMDD());

AddLabel(yes, (if Month < 10 then "0" else "") + Month + "" + (if Day < 10 then "0" else "") + Day + "" + year, Color.YELLOW);

 

[linced]

Thank you so much SleepyZ!!! I'm an absolute ****** when it gets to coding...

Is it possible to get this for the multiple past days, e.g. when I'm looking at the one hour chart over 10 days?

 

[SleepyZ]

Thank you so much SleepyZ!!! I'm an absolute ****** when it gets to coding...

Is it possible to get this for the multiple past days, e.g. when I'm looking at the one hour chart over 10 days?

Yes.

To do that this code uses the addchartbubble function as a label is oriented to the upper left corner and is not related to different days on the chart

To ensure that the bubbles are visible:
The study uses declare lower and requires you to manually move the study to the upper panel.
Click the left axis to turn check box off
Lines are plotted at 105,100 and 0 to orient the bubble placement near the top of the chart. These are defaulted to black to hide them. Change the color to match your chart background

Here is the code and how it will look on your chart. You have an option to show the day of the week as well as the date

declare lower;

def d = GetDayOfWeek(GetYYYYMMDD());
def year  = GetYear() - (Round(GetYYYYMMDD() / 1000000, 0) * 100);
def Month = GetMonth();
def Day   = GetDayOfMonth(GetYYYYMMDD());

input showdayofweek = yes;
def rthstart = GetTime() crosses above RegularTradingStart(GetYYYYMMDD());
def bubble   = if rthstart then BarNumber() else bubble[1];

AddChartBubble( BarNumber() == bubble, 100,
if showdayofweek
then (if d == 1 then "Monday"
      else if d == 2 then "Tuesday"
      else if d == 3 then "Wednesday" 
      else if d == 4 then "Thursday" 
      else if d == 5 then "Friday"     
      else if d == 6 then "Saturday"
      else "Sunday")
      + "\n" + (if Month < 10 then "0" else "") + Month + "" + (if Day < 10 then "0" else "") + Day + "" + year
      
else (if Month < 10 then "0" else "") + Month + "" + (if Day < 10 then "0" else "") + Day + "" + year,
if close(period = AggregationPeriod.DAY) > open(period = AggregationPeriod.DAY)
then Color.GREEN
else Color.RED);

plot line105 = 105;
plot line100 = 100;
plot line0 = 0;
line105.SetDefaultColor(Color.BLACK);
line100.SetDefaultColor(Color.BLACK);
line0.SetDefaultColor(Color.BLACK);

 

[linced]

Thank you x1000 !!!! This is exactly what I'm looking for! Much appreciated!