SPY candle color based on "reverse VIX" (-VIX) DMI

[KC8]

When I travel I am only able to use my laptop for trading. Naturally this limits my real estate available.

Currently when I day trade SPY I like to trade in the direction of the “reverse VIX” (-VIX) using a DMI indicator. However, I do not have room for this on my laptop screen.

Question: is it possible with thinkscript to color the SPY candles green when (the -VIX) DX+ is above DX- and color the SPY candles red when (the -VIX) DX+ is below DX- (this would suffice for directional trading)??? I would greatly appreciate any help.

MerryDay, I searched the site to see if this question has already been asked/answered, but I did not find any. If I have missed it, please post a link. Thank you very much!

 

[mashume]

Try this and see if it works for you:

declare upper;

input symbol = "-VIX";
input length = 14;
input averageType = AverageType.WILDERS;

def hiDiff = high(symbol = symbol) - high(symbol = symbol)[1];
def loDiff = low(symbol = symbol)[1] - low(symbol = symbol);

def plusDM = if hiDiff > loDiff and hiDiff > 0 then hiDiff else 0;
def minusDM =  if loDiff > hiDiff and loDiff > 0 then loDiff else 0;

def ATR = MovingAverage(averageType, TrueRange(high(symbol = symbol), close(symbol = symbol), low(symbol = symbol)), length);
def "DI+" = 100 * MovingAverage(averageType, plusDM, length) / ATR;
def "DI-" = 100 * MovingAverage(averageType, minusDM, length) / ATR;

def DX = if ("DI+" + "DI-" > 0) then 100 * AbsValue("DI+" - "DI-") / ("DI+" + "DI-") else 0;
def ADX = MovingAverage(averageType, DX, length);

AssignPriceColor(if "DI+" > "DI-" then color.green else if "DI-" > "DI+" then color.red else color.gray);

-mashume

 

[KC8]

Thank you!