PriceTimeFilteringAccVolume For ThinkOrSwim

[8ix]

Is there a way to make the ToS built-in PriceTimeFilteringAccVolume available for tick charts?
https://toslc.thinkorswim.com/cente...udies-library/O-Q/PriceTimeFilteringAccVolume

 

[useThinkScript]

The ToS built-in script PriceTimeFilteringAccVolume is a technical indicator designed to evaluate trend strength. The study identifies trend direction and plots a histogram using cumulative volume.


The PriceTimeFilteringAccVolume reads a WEEKLY aggregation to draw volume calculations.

Tick charts have no time axis and therefore cannot calculate weekly plots.

Here is the script with the MTF component removed.
It won't work the same.

@8ix
There is no guarantee that it will work on all tick charts, all the time.
read more:
https://usethinkscript.com/threads/...enko-charts-in-thinkorswim.18400/#post-140214

declare lower;
input paintBars = yes;

def trend = {default init, uptrend, downtrend};
if (Close[1] > High[2]) {
    trend = trend.uptrend;
} else if (Close[1] < Low[2]) {
    trend = trend.downtrend;
} else {
    trend = trend[1];
}
def count = if (IsNaN(close)) then Double.NaN else if trend != trend[1] then volume else count[1] + volume;

plot AccVolume;
if (trend == trend.uptrend) {
    AccVolume = count;
} else if (trend == trend.downtrend) {
    AccVolume = -count;
} else {
    AccVolume = Double.NaN;
}

AccVolume.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
AccVolume.DefineColor("Uptrend", Color.UPTICK);
AccVolume.DefineColor("Downtrend", Color.DOWNTICK);
AccVolume.AssignValueColor(if AccVolume >= 0 then AccVolume.Color("Uptrend") else AccVolume.Color("Downtrend"));

DefineGlobalColor("Uptrend", Color.UPTICK);
DefineGlobalColor("Downtrend", Color.DOWNTICK);
AssignPriceColor(if !paintBars
    then Color.CURRENT
    else if AccVolume >= 0
        then GlobalColor("Uptrend")
        else GlobalColor("Downtrend"));