Price Action Indicator

[woulf1004]

Hi team,

Is there anyway possible to code a script that plots a line based on each closing of the candle or tick for any time frame that is being used?
Please see the attached for your reference.

https://imgur.com/a/UhnvZiE

Thanks in advance.

 

[Joshua]

Based on how I am reading the question, it would just be:

Plot X = Close;

But I suspect, based on the image, that its more complicated than that.

Could you provide more detail?

 

[woulf1004]

Hi Joshua,

Yes, I need and indicator that plots a line which is followed by each closing candle just like the white color line in the image (left side) attached. The chart on the right side is the regular candle chart so we can compare it, and the way I am currently getting this line is by adjusting the chart settings which is forcing me choose between a regular candle or any line plotting. I would like to have both, the candles and the lines plotted based on each candle that closes and there fore I would like to have a separate indicator that plots the line for me.

https://imgur.com/a/qxHqGot

 

[Joshua]

Running it on tick itself:

Plot X = Close;
X.setdefaultColor(color.white);
Plot Y = Close;
Y.setPaintingStrategy(paintingStrategy.SQUARES);
Y.setdefaultColor(color.white);

Running it separate:

Declare Lower;
Plot X = Close("$TICK");
X.setdefaultColor(color.white);
Plot Y = Close("$TICK");
Y.setPaintingStrategy(paintingStrategy.SQUARES);
Y.setdefaultColor(color.white);

You can also add in something like...

plot T = 1000;
plot Z = 0;
plot B = -1000;

 

[woulf1004]

The First one works and it's what I was looking for. You are all geniuses! Thank you so much.
Oh and I have added your code at the end and this is what I can share for anyone who's interested in using the $TICK chart which is very useful. Happy trading.

input ShowDistArrows = yes;
input ShowCloud = no;
input UpThreshold = 1000;
input UpThreshold2 = 700;
input DownThreshold = -1000;
input DownThreshold2 = -700;
input DistArrowLevel = 1500;
input ShowHiLo = yes;

def Above = if close > UpThreshold then 1 else 0;
def Below = if close < DownThreshold then 1 else 0;

plot pline;
plot pline2;
plot nline;
plot nline2;
pline = UpThreshold;
pline2 = UpThreshold2;
nline = DownThreshold;
nline2 = DownThreshold2;

pline.SetStyle(Curve.LONG_DASH);
pline.SetDefaultColor(Color.RED);
pline2.SetStyle(Curve.LONG_DASH);
pline2.SetDefaultColor(Color.RED);
nline.SetStyle(Curve.LONG_DASH);
nline.SetDefaultColor(Color.GREEN);
nline2.SetStyle(Curve.LONG_DASH);
nline2.SetDefaultColor(Color.GREEN);

Def cloudhigh = if ShowCloud then pline else Double.NaN;
Def cloudlow = if ShowCloud then nline else Double.NaN;

AddCloud (cloudhigh, cloudlow, Color.DARK_GRAY, Color.DARK_GRAY);
AddLabel(ShowHiLo,“HI ”+AsText(high(“$TICK”, ”Day”, ”LAST”)), Color.ORANGE);
AddLabel(ShowHiLo,“LO ”+AsText(low(“$TICK”, ”Day”, ”LAST”)), Color.ORANGE);
AddLabel(close >= 0 and close <= UpThreshold,close+ ” ”,Color.GREEN);
AddLabel(close < 0 and close >= DownThreshold,close+ ” ”,Color.RED);
AddLabel(close > UpThreshold,”[+1k] = “+ close, Color.GREEN);
AddLabel(close < DownThreshold,”[-1k] = “+close, Color.RED);

#Distribution Function
def Less = If((close < 0), 1, 0); def Greater = If((close > 0), 1, 0);
def closeByPeriod = close(period = “DAY”)[-1];
def newDay = if !IsNaN(closeByPeriod) then 0 else 1;
plot DistributionUp;
plot DistributionDown;

if !IsNaN(close(period = “DAY”)[-1])
then {

DistributionUp = Double.NaN;
DistributionDown = Double.NaN;

} else {

DistributionUp = if newDay and ShowDistArrows and Greater then +DistArrowLevel else Double.NaN;
DistributionDown = if newDay and ShowDistArrows and Less then -DistArrowLevel else Double.NaN;
}

DistributionUp.SetStyle(Curve.POINTS);
DistributionUp.SetPaintingStrategy(PaintingStrategy.LINE_VS_TRIANGLES);
DistributionUp.SetDefaultColor(Color.GREEN);
DistributionUp.SetLineWeight(3);
DistributionDown.SetStyle(Curve.POINTS);
DistributionDown.SetPaintingStrategy(PaintingStrategy.LINE_VS_TRIANGLES);
DistributionDown.SetDefaultColor(Color.RED);
DistributionDown.SetLineWeight(3);

#ZeroLine
plot zeroline = 0;
zeroline.SetDefaultColor(Color.CYAN);
zeroline.SetStyle(Curve.LONG_DASH);
zeroline.HideTitle();
zeroline.HideBubble();

#PriceLine
Plot P = Close;
P.setdefaultColor(color.white);
Plot PC = Close;
PC.setPaintingStrategy(paintingStrategy.SQUARES);
PC.setdefaultColor(color.white);

 

[drasp]

This indicator is made better if instead of plotting the close, plot the HLC3.
Easier to spot divergences

 

[Zlotko]

This indicator is made better if instead of plotting the close, plot the HLC3.
Easier to spot divergences

could you show how to plot the close, plot the HLC3? Thanks

 

[drasp]

could you show how to plot the close, plot the HLC3? Thanks

Declare Lower;

Plot X = HLC3("$TICK");

X.setdefaultColor(color.white);

Plot Y = HLC3("$TICK");

Y.setPaintingStrategy(paintingStrategy.SQUARES);

Y.setdefaultColor(color.white);



plot T = 1000;

plot Z = 0;

plot B = -1000;

change the close under PLOT X to HLC3 instead of "close"

 

[woulf1004]

This is the same as TOS TypicalPrice Indicator which is also useful but the main plan and idea for me was getting the histogram of the closing of the candles in the $TICK chart. Thank you.
Oh and I use the closing as squares and the typical price indicator as lines to see the divergences which is a great combination.

https://imgur.com/a/PQlBHuh