plot shows at the bottom

[randomx]

hello all,

why is the plot not really showing in between the arrows? i'm sure it's a silly thing but i can't figure it out. thank you in advance

if value crosses above overbought (0.9), show a red arrow up underneath the line
if value crosses below overbought (0.9), show a green arrow down on top of the line

declare lower;
#set horizontal line properties
plot overbought = 0.9;
overbought.SetDefaultColor(Color.gray);

#plot line with symbol values
plot vix9d_vix_r = close("VIX9D") / close("VIX");
vix9d_vix_r.setPaintingStrategy(PaintingStrategy.Line_VS_Points);
vix9d_vix_r.AssignValueColor(if vix9d_vix_r >= overbought then color.red else color.green);

plot bearish_vix9d_vix_r = vix9d_vix_r crosses above overbought;
plot bullish_vix9d_vix_r = vix9d_vix_r crosses below overbought;

bearish_vix9d_vix_r.SetDefaultColor(Color.DOWNTICK);
bearish_vix9d_vix_r.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);

bullish_vix9d_vix_r.SetDefaultColor(Color.UPTICK);
bullish_vix9d_vix_r.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);

 

[halcyonguy]

i have noticed that boolean plots don't work as expected in a lower chart. they plot at the close level of the symbol in main chart.
i converted them to normal arrows, and specified a price level.

# plotbetweenarrows_01

declare lower;
#set horizontal line properties
plot overbought = 0.9;
overbought.SetDefaultColor(Color.gray);

#plot line with symbol values
plot vix9d_vix_r = close("VIX9D") / close("VIX");
vix9d_vix_r.setPaintingStrategy(PaintingStrategy.Line_VS_Points);
vix9d_vix_r.AssignValueColor(if vix9d_vix_r >= overbought then color.red else color.green);

# boolean plots dont work in lower
#plot bearish_vix9d_vix_r = vix9d_vix_r crosses above overbought;
#plot bullish_vix9d_vix_r = vix9d_vix_r crosses below overbought;
#bearish_vix9d_vix_r.SetDefaultColor(Color.DOWNTICK);
#bearish_vix9d_vix_r.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
#bullish_vix9d_vix_r.SetDefaultColor(Color.UPTICK);
#bullish_vix9d_vix_r.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);


def na = double.nan;
plot bearish_vix9d_vix_r = if (vix9d_vix_r crosses above overbought) then vix9d_vix_r else na;
plot bullish_vix9d_vix_r = if (vix9d_vix_r crosses below overbought) then vix9d_vix_r else na;

bearish_vix9d_vix_r.SetDefaultColor(Color.DOWNTICK);
bearish_vix9d_vix_r.SetPaintingStrategy(PaintingStrategy.ARROW_UP);

bullish_vix9d_vix_r.SetDefaultColor(Color.UPTICK);
bullish_vix9d_vix_r.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
#

 

[randomx]

aaah no wonder. that explains it. thanks again for your help