Need help plotting horizontal lines as ranges

[cappermac]

Need help to plot horizontal lines. Would like to consider these as current day range. Here are the conditions:

1. (Previous Day ATR / 2) + Previous Day Close = High Line
2. (Previous Day ATR / 2) - Previous Day Close = Low Line

 

[SleepyZ]

Need help to plot horizontal lines. Would like to consider these as current day range. Here are the conditions:

1. (Previous Day ATR / 2) + Previous Day Close = High Line
2. (Previous Day ATR / 2) - Previous Day Close = Low Line

As displayed, this study shows the hline, lline and optional closeline plots. It is defaulted to showonly on the lastday (current).

input showtodayonly = yes;
input lookback = 1;
input hide_closeline = no;
input length = 14;
input averageType = AverageType.WILDERS;
input agg = AggregationPeriod.DAY;

def atr = MovingAverage(averageType, TrueRange(high(period = agg)[lookback], close(period = agg)[lookback], low(period = agg)[lookback]), length);
def pclose = close(period = agg)[lookback];

plot closeline = if showtodayonly and GetDay() != GetLastDay() then Double.NaN
             else pclose;
plot hline = if showtodayonly and GetDay() != GetLastDay() then Double.NaN
             else pclose + (atr / 2);
plot lline = if showtodayonly and GetDay() != GetLastDay() then Double.NaN
             else pclose - (atr / 2);

hline.SetPaintingStrategy(PaintingStrategy.DASHES);
lline.SetPaintingStrategy(PaintingStrategy.DASHES);
closeline.setpaintingStrategy(paintingStrategy.HORIZONTAL);

hline.setdefaultColor(color.green);
lline.setdefaultColor(color.red);
closeline.setdefaultColor(color.white);

closeline.sethiding(hide_closeline);

#

 

[cappermac]

Hello again @SleepyZ. Is there a way to automatically plot horizontal lines within this range on the bodies and/or wicks of 4-hour candles (or any defined timeframe) today? Ideally, I would like to view these 4-hour horizontal lines on a 3-minute chart, but if it's only possible on a 4-hour chart, that's okay too.

Thank you.

 

[SleepyZ]

Hello again @SleepyZ. Is there a way to automatically plot horizontal lines within this range on the bodies and/or wicks of 4-hour candles (or any defined timeframe) today? Ideally, I would like to view these 4-hour horizontal lines on a 3-minute chart, but if it's only possible on a 4-hour chart, that's okay too.

Thank you.

Here is the part of the above code that was modified to change the agg and a mode switch between Wicks/Body.

input agg = AggregationPeriod.DAY;

input mode = {default Wicks, Body};
def h;
def l;
switch (mode) {
case Wicks:
    h = high(period = agg)[lookback];
    l = low(period = agg)[lookback];
case Body:
    h = Max(close(period = agg)[lookback], open(period = agg)[lookback]);
    l = Min(close(period = agg)[lookback], open(period = agg)[lookback]);
}

def atr = MovingAverage(averageType, TrueRange(h, close(period = agg)[lookback], l), length);

The following full code is displayed on a 3m chart, 4hour agg with Body mode.

input showtodayonly = yes;
input lookback = 1;
input hide_closeline = no;
input length = 14;
input averageType = AverageType.WILDERS;
input agg = AggregationPeriod.FOUR_HOURS;

input mode = {default Wicks, Body};
def h;
def l;
switch (mode) {
case Wicks:
    h = high(period = agg)[lookback];
    l = low(period = agg)[lookback];
case Body:
    h = Max(close(period = agg)[lookback], open(period = agg)[lookback]);
    l = Min(close(period = agg)[lookback], open(period = agg)[lookback]);
}

def atr = MovingAverage(averageType, TrueRange(h, close(period = agg)[lookback], l), length);
def pclose = close(period = agg)[lookback];

plot closeline = if showtodayonly and GetDay() != GetLastDay() then Double.NaN
             else pclose;
plot hline = if showtodayonly and GetDay() != GetLastDay() then Double.NaN
             else pclose + (atr / 2);
plot lline = if showtodayonly and GetDay() != GetLastDay() then Double.NaN
             else pclose - (atr / 2);

hline.SetPaintingStrategy(PaintingStrategy.DASHES);
lline.SetPaintingStrategy(PaintingStrategy.DASHES);
closeline.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

hline.SetDefaultColor(Color.GREEN);
lline.SetDefaultColor(Color.RED);
closeline.SetDefaultColor(Color.WHITE);

closeline.SetHiding(hide_closeline);

#