Need help for background shading a range from previous trading day

[hey]

Would anyone know how to create a code which put imple white background shading on today's chart covering a range of the following 6 items;

THE LAST 30 MINUTES OF PREVIOUS DAY'S:

1) 20 sma
2) 20 ema
3) 200 sma
4) 200 ema
5) closing price

6nd

THE LAST 45 MINUTES OF THE PREVIOUS DAY'S:

6) Price action (the candlestick price info range)

 

[halcyonguy]

Would anyone know how to create a code which put imple white background shading on today's chart covering a range of the following 6 items;

THE LAST 30 MINUTES OF PREVIOUS DAY'S:

1) 20 sma
2) 20 ema
3) 200 sma
4) 200 ema
5) closing price

6nd

THE LAST 45 MINUTES OF THE PREVIOUS DAY'S:

6) Price action (the candlestick price info range)

sorry i don't know what you want. your description is vague.

go find windows 'snipping tool' and grab a screen shot of a chart.
then draw on the image to show what you want to see.

a range is between 2 numbers. but you list 5+? between what 2 price levels do you want shading?

6) price action is meaningless. you are asking people to write a program. a program uses math, which uses absolute values. there is only open, high, low, close. use those to describe what you want.

 

[halcyonguy]

here is something to experiment with.

it draws 4 average lines

during the last 30 minutes of the day, it draws the 4 average lines, from yesterday

4 labels, that show the average parameters and line colors

# prev_days_avgs

#https://usethinkscript.com/threads/need-help-for-background-shading-a-range-from-previous-trading-day.22388/
#Need help for background shading a range from previous trading day
#hey  5/14

#Would anyone know how to create a code which put imple white background shading on today's chart covering a range of the following 6 items;

#THE LAST 30 MINUTES OF PREVIOUS DAY'S:

#1) 20 sma
#2) 20 ema
#3) 200 sma
#4) 200 ema
#5) closing price

#6nd

#THE LAST 45 MINUTES OF THE PREVIOUS DAY'S:

#6) Price action (the candlestick price info range)


def na = Double.NaN;
def bn = BarNumber();
def data = close;


input start = 1530;
input end = 1600;
def time1 = (secondsfromTime(start) >= 0 and secondstillTime(end) > 0);
def start30 = (secondsfromTime(start) == 0);


def startbn;
if start30 then {
 startbn = bn;
} else {
 startbn = startbn[1];
}


input avg1_type = AverageType.SIMPLE;
input avg1_length = 20;
def avg1 = MovingAverage(avg1_type, data, avg1_length);

input avg2_type = AverageType.exponential;
input avg2_length = 20;
def avg2 = MovingAverage(avg2_type, data, avg2_length);

input avg3_type = AverageType.SIMPLE;
input avg3_length = 200;
def avg3 = MovingAverage(avg3_type, data,  avg3_length);

input avg4_type = AverageType.exponential;
input avg4_length = 200;
def avg4 = MovingAverage(avg4_type, data,  avg4_length);


input show_avg_lines = yes;
plot zavg1 = if show_avg_lines and avg1_length > 0 then avg1 else na;
plot zavg2 = if show_avg_lines and avg2_length > 0 then avg2 else na;
plot zavg3 = if show_avg_lines and avg3_length > 0 then avg3 else na;
plot zavg4 = if show_avg_lines and avg4_length > 0 then avg4 else na;

zavg1.SetDefaultColor(Color.CYAN);
#zavg1.SetLineWeight(1);
zavg1.HideBubble();
zavg2.SetDefaultColor(Color.YELLOW);
#zavg2.SetLineWeight(1);
zavg2.HideBubble();
zavg3.SetDefaultColor(Color.MAGENTA);
#zavg3.SetLineWeight(1);
zavg3.HideBubble();
zavg4.SetDefaultColor(Color.WHITE);
#zavg4.SetLineWeight(1);
zavg4.HideBubble();

#---------------------------------------

# find prev day avg values

def off;
def prev1;
def prev2;
def prev3;
def prev4;
if bn == 1 then {
 off = 0;
 prev1 = 0;
 prev2 = 0;
 prev3 = 0;
 prev4 = 0;

} else if start30 then {
 off = (startbn - startbn[1]);
 prev1 = getvalue(avg1, off);
 prev2 = getvalue(avg2, off);
 prev3 = getvalue(avg3, off);
 prev4 = getvalue(avg4, off);

} else if time1 then {
 off = off[1];
 prev1 = getvalue(avg1, off);
 prev2 = getvalue(avg2, off);
 prev3 = getvalue(avg3, off);
 prev4 = getvalue(avg4, off);

} else {
 off = 0;
 prev1 = 0;
 prev2 = 0;
 prev3 = 0;
 prev4 = 0;
}


plot zp1 = if prev1 > 0 then prev1 else na;
plot zp2 = if prev2 > 0 then prev2 else na;
plot zp3 = if prev3 > 0 then prev3 else na;
plot zp4 = if prev4 > 0 then prev4 else na;
zp1.SetDefaultColor(Color.CYAN);
zp1.SetLineWeight(2);
zp1.HideBubble();
zp2.SetDefaultColor(Color.YELLOW);
zp2.SetLineWeight(2);
zp2.HideBubble();
zp3.SetDefaultColor(Color.MAGENTA);
zp3.SetLineWeight(2);
zp3.HideBubble();
zp4.SetDefaultColor(Color.WHITE);
zp4.SetLineWeight(2);
zp4.HideBubble();


#-----------------------

AddLabel(avg1_length > 0,  "1. " + 
(if avg1_type == AverageType.SIMPLE then "SMA"
 else if avg1_type == AverageType.EXPONENTIAL then "EMA"
 else if avg1_type == AverageType.HULL then "HULL"
 else if avg1_type == AverageType.WEIGHTED then "WT"
 else if avg1_type == AverageType.WILDERS then "WILD"
 else "---") + avg1_length 
, zavg1.TakeValueColor());

AddLabel(avg2_length > 0,  "2. " + 
(if avg2_type == AverageType.SIMPLE then "SMA"
 else if avg2_type == AverageType.EXPONENTIAL then "EMA"
 else if avg2_type == AverageType.HULL then "HULL"
 else if avg2_type == AverageType.WEIGHTED then "WT"
 else if avg2_type == AverageType.WILDERS then "WILD"
 else "---") + avg2_length 
, zavg2.TakeValueColor());

AddLabel(avg3_length > 0,  "3. " + 
(if avg3_type == AverageType.SIMPLE then "SMA"
 else if avg3_type == AverageType.EXPONENTIAL then "EMA"
 else if avg3_type == AverageType.HULL then "HULL"
 else if avg3_type == AverageType.WEIGHTED then "WT"
 else if avg3_type == AverageType.WILDERS then "WILD"
 else "---") + avg3_length 
, zavg3.TakeValueColor());

AddLabel(avg4_length > 0,  "4. " + 
(if avg4_type == AverageType.SIMPLE then "SMA"
 else if avg4_type == AverageType.EXPONENTIAL then "EMA"
 else if avg4_type == AverageType.HULL then "HULL"
 else if avg4_type == AverageType.WEIGHTED then "WT"
 else if avg4_type == AverageType.WILDERS then "WILD"
 else "---") + avg4_length 
, zavg4.TakeValueColor());

#

 

[Morgmorgan]

sorry i don't know what you want. your description is vague.

go find windows 'snipping tool' and grab a screen shot of a chart.
then draw on the image to show what you want to see.

a range is between 2 numbers. but you list 5+? between what 2 price levels do you want shading?

6) price action is meaningless. you are asking people to write a program. a program uses math, which uses absolute values. there is only open, high, low, close. use those to describe what you want.

thx will do.

 

[hey]

Thank you. I'm just seeing your response now. I'm relatively unfamiliar with this site and the last I checked, the question was still unanswered.

I was looking for a highlighted range with the upper level being the highest of the six elements listed and the lowest level being the lowest of all six of those elements. When I saw that noone answered the question, I kept trying on my own until I came upon a code which would encompass them.

I thank you for your response and for the code which you provided me.

Here is the code:

# Previous Day Market Close Range (30min EMA/SMA + 45min Price)
# Excludes Premarket and Aftermarket

# --- Inputs ---
input emaFastLength = 20;
input emaSlowLength = 200;
input priceMinutes = 45;
input emaMinutes = 30;

# --- Define Regular Trading Hours (RTH) ---
def isRTH = RegularTradingStart(GetYYYYMMDD()) <= SecondsFromTime(0);
def rthEnd = SecondsTillTime(1600) == 0;

# --- Define Previous Day ---
def lastDay = GetDay() == GetLastDay() - 1;

# --- Data Acquisition (Previous Day RTH Only) ---
def prevDayRTH = lastDay and isRTH;

# --- Calculate Indicators & Price (Last X Minutes) ---
# Price High/Low last 45 mins
def prevPriceHigh = if rthEnd then highest(high[1], priceMinutes) else prevPriceHigh[1];
def prevPriceLow = if rthEnd then lowest(low[1], priceMinutes) else prevPriceLow[1];

# 20/200 EMA/SMA last 30 mins
def ma20 = ExpAverage(close, emaFastLength);
def sm20 = Average(close, emaFastLength);
def ma200 = ExpAverage(close, emaSlowLength);
def sm200 = Average(close, emaSlowLength);

# Find the highest/lowest of all 4 MAs in the last 30 mins
def maHighest = if rthEnd then Max(Max(highest(ma20[1], emaMinutes), highest(sm20[1], emaMinutes)), Max(highest(ma200[1], emaMinutes), highest(sm200[1], emaMinutes))) else maHighest[1];
def maLowest = if rthEnd then Min(Min(lowest(ma20[1], emaMinutes), lowest(sm20[1], emaMinutes)), Min(lowest(ma200[1], emaMinutes), lowest(sm200[1], emaMinutes))) else maLowest[1];

# --- Define Final Range Boundaries ---
plot TopRange = Max(prevPriceHigh, maHighest);
plot BotRange = Min(prevPriceLow, maLowest);

# Styling for boundaries
TopRange.SetDefaultColor(Color.WHITE);
BotRange.SetDefaultColor(Color.WHITE);
TopRange.SetStyle(Curve.LONG_DASH);
BotRange.SetStyle(Curve.LONG_DASH);

# --- Create White Background Cloud ---
AddCloud(TopRange, BotRange, Color.WHITE, Color.WHITE);