Loken (v4) Bullish Smart Money for ThinkOrSwim

[apdusp]

try this for scan http://tos.mx/hJTSU0Y (code below)
plot it first as an indicator for you to check if you find working
condition for scan => above 0 is for bullish and below 0 for bearish

I tried to clean what was not relevant to the scan and even then it gave error, then, since the code was as clean as it was possible, I cleaned the initial comments and it worked. my conclusion is that some character sequence in the comments, which are supposed to be neutral to the compiler were not so neutral and caused the mess. didn't go further to leave something for our hackers to discover. just left the credits

# @LOKEN94
# Converted by Sam4Cok@Samer800 - 09-2023

declare lower;
input RSIBaseHotMoney = 30;#, "Hot Money RSI Base"
input RSIPeriodHotMoney = 40;#, "Hot Money RSI Period"
input SensitivityHotMoney = 0.7;#, "Sensitivity Hot Money"


def nRSI = RSI(Price = close, Length = RSIPeriodHotMoney);
def rsi_ = SensitivityHotMoney * (nRSI - RSIBaseHotMoney);
def hot = if rsi_ > 20 then 20 else if rsi_ < 0 then 0 else rsi_;

def hotma2 = WildersAverage(hot, 2);
def hotma7 = WildersAverage(hot, 7);
def hotma31 = WildersAverage(hot, 31);

def hotma = ExpAverage(((hotma2 * 34) + (hotma7 * 33) + (hotma31 * 33)) / 100, 2);
def hotsignal = WildersAverage(hotma, 2);


plot sig_updn = if (hotma < hotsignal and hotma[1]>hotsignal[1]) then -1 else if (hotma > hotsignal and hotma[1] < hotsignal[1]) then 1 else 0;

 

[annaie243]

try this for scan http://tos.mx/hJTSU0Y (code below)
plot it first as an indicator for you to check if you find working
condition for scan => above 0 is for bullish and below 0 for bearish

I tried to clean what was not relevant to the scan and even then it gave error, then, since the code was as clean as it was possible, I cleaned the initial comments and it worked. my conclusion is that some character sequence in the comments, which are supposed to be neutral to the compiler were not so neutral and caused the mess. didn't go further to leave something for our hackers to discover. just left the credits

# @LOKEN94
# Converted by Sam4Cok@Samer800 - 09-2023

declare lower;
input RSIBaseHotMoney = 30;#, "Hot Money RSI Base"
input RSIPeriodHotMoney = 40;#, "Hot Money RSI Period"
input SensitivityHotMoney = 0.7;#, "Sensitivity Hot Money"


def nRSI = RSI(Price = close, Length = RSIPeriodHotMoney);
def rsi_ = SensitivityHotMoney * (nRSI - RSIBaseHotMoney);
def hot = if rsi_ > 20 then 20 else if rsi_ < 0 then 0 else rsi_;

def hotma2 = WildersAverage(hot, 2);
def hotma7 = WildersAverage(hot, 7);
def hotma31 = WildersAverage(hot, 31);

def hotma = ExpAverage(((hotma2 * 34) + (hotma7 * 33) + (hotma31 * 33)) / 100, 2);
def hotsignal = WildersAverage(hotma, 2);


plot sig_updn = if (hotma < hotsignal and hotma[1]>hotsignal[1]) then -1 else if (hotma > hotsignal and hotma[1] < hotsignal[1]) then 1 else 0;

Is it possible to scan for the PUMPCANDLE only? I am really liking this one

 

[apdusp]

Is it possible to scan for the PUMPCANDLE only? I am really liking this one

I don't see why it can't be possible but you need to clean the comment problem I mentioned before

 

[apdusp]

I didn't test it. check it out.

#// This source code is subject to the terms of the Mozilla Public License 2.0 at
#// © LOKEN94
#//  I made this indicator as a tribute to the late David Paul.
#//  He mentioned quite a lot about 89 periods moving average, also the 21 and 55.
#indicator("Tribute to David Paul",shorttitle="MA",overlay=tr)
# converted by Sam4Cok@Samer800 - 09/2023
input IR =2;#,minval=-1,maxval=2,tooltip="If -1, no entries zone will be displayed.    
input SDZ = yes;#,title="Show Supply & Demand zone",tooltip="Previous setting need to be set on 2.")
input MA = 4;#,minval=-1,maxval=5,title="Show ma",tooltip="If -1, no MA will be displayed.      
input enableTrendColors = no;

def na = Double.NaN;
DefineGlobalColor("up", CreateColor(33,150,243));
DefineGlobalColor("dn", CreateColor(179, 52, 52));#CreateColor(255,82,82));
DefineGlobalColor("dup", CreateColor(19, 92, 151));
DefineGlobalColor("ddn", Color.DARK_RED);#CreateColor(155, 28, 28));
def ma21 = Average(close, 21);
def ma55 = Average(close, 55);
def ma89 = Average(close, 89);


def BULL = ma21 <= close and ma55 <= close and ma89 <= close;
def BEAR = ma21 > close and ma55 > close and ma89 > close;

#float lowest_ma=ma89
def lowest_ma = if ma21 <= ma55 and ma21 <= ma89 then ma21 else
                if ma55 <= ma21 and ma55 <= ma89 then ma55 else ma89;
def highest_ma = if ma21 >= ma55 and ma21 >= ma89 then ma21 else
                 if ma55 >= ma21 and ma55 >= ma89 then ma55 else ma89;
#float IDEAL_LONG_ENTRY=na
def IDEAL_LONG_ENTRY = if BULL and !BULL[1] then low else IDEAL_LONG_ENTRY[1];
#float IDEAL_SHORT_ENTRY=na
def IDEAL_SHORT_ENTRY = if BEAR and !BEAR[1] then high else IDEAL_SHORT_ENTRY[1];
#float REAL_LONG_ENTRY=na
def REAL_LONG_ENTRY = if BULL and !BULL[1] then highest_ma else REAL_LONG_ENTRY[1];
#float REAL_SHORT_ENTRY=na
def REAL_SHORT_ENTRY = if BEAR and !BEAR[1] then lowest_ma else REAL_SHORT_ENTRY[1];

#--
def iLP = if IDEAL_LONG_ENTRY!=IDEAL_LONG_ENTRY[1] then na else Average(IDEAL_LONG_ENTRY, 1);
def iSP = if IDEAL_SHORT_ENTRY!=IDEAL_SHORT_ENTRY[1] then na else Average(IDEAL_SHORT_ENTRY, 1);
def rLP = if REAL_LONG_ENTRY!=REAL_LONG_ENTRY[1] then na else Average(REAL_LONG_ENTRY, 1);
def rSP = if REAL_SHORT_ENTRY!=REAL_SHORT_ENTRY[1] then na else Average(REAL_SHORT_ENTRY, 1);

def ilong  = if BULL then iLP else na;#ilong[1];
def ishort = if BEAR then iSP else na;#ishort[1];
def rlong  = if BULL then rLP else na;#rlong[1];
def rshort = if BEAR then rSP else na;#rshort[1];

plot botdemand = if IR==1 or IR==2 then ilong else na;#,"Ideal Long entry"
plot topsupply = if IR==1 or IR==2 then ishort else na;#,"Ideal Short entry"
plot topdemand = if IR==0 or IR==2 then rlong else na;#,"Real Long entry"
plot botsupply = if IR==0 or IR==2 then rshort else na;#,"Real Short entry"
botdemand.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
topsupply.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
topdemand.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
botsupply.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

botdemand.SetDefaultColor(GlobalColor("up"));
topsupply.SetDefaultColor(GlobalColor("dn"));
topdemand.SetDefaultColor(GlobalColor("up"));
botsupply.SetDefaultColor(GlobalColor("dn"));

AddCloud(if !SDZ then na else topdemand,botdemand, GlobalColor("up"), GlobalColor("up"));
AddCloud(if !SDZ then na else topsupply,botsupply,GlobalColor("dn"), GlobalColor("dn"));

#//
def ama = (ma21 + ma55 + ma89) / 3;

def AC = if close > ama then 1 else
         if close < ama then -1 else AC[1];
#//
def FLAT = if AC==1 and AC[1]!=1 then ama else
           if AC==-1 and AC[1]!=-1 then ama else FLAT[1];
#//
#float entries=rlong+rshort
def entries = if IR then ilong + ishort else rlong+rshort;
#//
def flat1_ = Average(FLAT,1);
def FLAT1  = if flat1_!=flat1_[1] then na else flat1_;

def col= if ama<=close then (if ilong==iLP then 2 else 1) else
                            (if ishort==iSP then -2 else -1);

plot amaLine = if MA==1 or MA==4 or MA==5 then ama else  na;#,"AMA",color=ama<=close?color.rgb(0, 25, 45):color.rgb(10, 0, 0))
amaLine.AssignValueColor(if ama<=close then Color.CYAN else Color.MAGENTA);

def FA = FLAT1;# ,color=ama<=close?color.blue:color.red,style=plot.style_linebr,display=display.none,editable=false)


def FHL = hl2;#,display=display.none,editable=false)

AddCloud(if col==2 then FA else na,FHL, GlobalColor("up"), GlobalColor("up"));
AddCloud(if col==1 then FA else na,FHL, GlobalColor("dup"), GlobalColor("dup"));
AddCloud(if col==-2 then FA else na,FHL, GlobalColor("dn"), GlobalColor("dn"));
AddCloud(if col==-1 then FA else na,FHL, GlobalColor("ddn"), GlobalColor("ddn"));

#//
plot sma21 = if MA==0 or MA==4 then ma21 else na;
sma21.AssignValueColor(if ma21<=close then GlobalColor("up") else GlobalColor("dn"));

plot sma55 = if MA==0 or MA==4 or MA==5 then ma55 else na;
sma55.AssignValueColor(if ma55<=close then GlobalColor("up") else GlobalColor("dn"));

plot sma89 = if MA==0 or MA==4 then ma89 else na;
sma89.AssignValueColor(if ma89<=close then GlobalColor("up") else GlobalColor("dn"));

plot hiMa = if (MA==3 and (BULL==1 or ama<=close)) or (MA==2 and (BEAR==1 or ama>=close)) then highest_ma else na;
hiMa.AssignValueColor(if highest_ma<=close then GlobalColor("up") else GlobalColor("dn"));

plot loMa = if (MA==3 and (BEAR==1 or ama>=close)) or (MA==2 and (BULL==1 or ama<=close)) then lowest_ma else na;
loMa.AssignValueColor(if lowest_ma<=close then GlobalColor("up") else GlobalColor("dn"));

#-- Bar Color
def barCol = if ilong==iLP then 1 else
             if ishort==iSP then -1 else
             if !BULL and !BEAR then 0 else barCol[1];

AssignPriceColor(if !enableTrendColors then Color.CURRENT else
                 if barCol > 0 then Color.CYAN else
                 if barCol < 0 then Color.MAGENTA else Color.GRAY);


# -- END of CODE

@samer800 , is there a way to avoid this apparent graphic distortion as you can see in the picture ?

 

[samer800]

@samer800 , is there a way to avoid this apparent graphic distortion as you can see in the picture ? View attachment 19943

change the below line 88 from:
def FA = FLAT1;

to:
def FA = if FLAT1 then FLAT1 else na;

 

[apdusp]

change the below line 88 from:
def FA = FLAT1;

to:
def FA = if FLAT1 then FLAT1 else na;

You nailed it. Thank you so much

 

[Piper2808t]

great indicator can it be put into MTF version?

@samer800 is it possible to have this as an mtf version thanks

 

[samer800]

great indicator can it be put into MTF version?

@samer800 is it possible to have this as an mtf version thanks

check the below

# https://www.tradingview.com/v/DlWtErRh/
#// © LOKEN94
#// Custom version based of [M2J] Indicator | MCDX
#study("LOKEN ? (v4) BULLISH MCDX v2.2", "?",precision=2)
# Converted by Sam4Cok@Samer800    - 09/2023
# Updated by Sam4Cok@Samer800    - 11/2023 - added MTF option
declare lower;
#declare zerobase;
input timeframe = {Default "Chart", "Custom"};
input customTimeframe = AggregationPeriod.FIFTEEN_MIN;
input RSIBaseBanker       = 50;#,  "Banker Base"
input RSIPeriodBanker     = 50;#,  "Banker RSI Period"
input RSIBaseHotMoney     = 30;#,  "Hot Money RSI Base"
input RSIPeriodHotMoney   = 40;#,  "Hot Money RSI Period"
input SensitivityBanker   = 1.5;#, "Sensitivity Banker"
input SensitivityHotMoney = 0.7;#, "Sensitivity Hot Money"
input threshold = 8.5;

def na = Double.NaN;
def last = isNaN(Close);
def chart = timeframe==timeframe."Chart";
def c = if chart then close else close(Period = customTimeframe);
def v = if chart then volume else volume(Period = customTimeframe);

DefineGlobalColor("nor", CreateColor(132, 175, 201));
#vwma(source, length)
script VWMA {
    input src = close;
    input len = 15;
    input v_ = volume;
    def v = if isNaN(v_) then 1 else v_;
    def srcV = src * v;
    def VWMA = Average(srcV, len) / Average(v, len);
    plot result = VWMA;
}
#rsi_function(sensitivity, rsiPeriod, rsiBase) =>
script rsi_function {
    input src = close;
    input sensitivity = 1;
    input rsiPeriod = 50;
    input rsiBase = 1;
    def nRSI = RSI(Price = src, Length = rsiPeriod);
    def rsi_ = sensitivity * (nRSI - rsiBase);
    def rsi = if rsi_ > 20 then 20 else
              if rsi_ < 0 then 0 else rsi_;
    plot out = rsi;
}

def rsi_Banker   = rsi_function(c, SensitivityBanker,   RSIPeriodBanker,   RSIBaseBanker);
def rsi_HotMoney = rsi_function(c, SensitivityHotMoney, RSIPeriodHotMoney, RSIBaseHotMoney);
def hot  = rsi_HotMoney;
def bank = rsi_Banker;
def hotMoney = hot;#, "Hot Money"

def hotma2   = WildersAverage(hot, 2);
def bankma2  = Average(bank, 2);
def hotma7   = WildersAverage(hot, 7);
def bankma7  = ExpAverage(bank, 7);
def hotma31  = WildersAverage(hot, 31);
def bankma31 = ExpAverage(bank, 31);

def hotma  = ExpAverage(((hotma2 * 34) + (hotma7 * 33) + (hotma31 * 33)) / 100, 2);
def bankma = Average(((bankma2 * 70) + (bankma7 * 20) + (bankma31 * 10)) / 100, 2);
def hotsignal  = WildersAverage(hotma, 2);
def banksignal = WildersAverage(bankma, 4);

def hotline = hotma; # "Hot Money MA"
def bankline = bankma;# "Banker MA"
def hotline2 = hotsignal;# "Hot Money MA2"
def bankline2 = banksignal; # "Banker MA2"
#//
AddCloud(hotline , hotline2, Color.DARK_GREEN, Color.DARK_RED);
AddCloud(bankline, bankline2, Color.VIOLET, Color.DARK_ORANGE);
AddCloud(hot, hotline, Color.GREEN, Color.RED);

#//
def hbAvg = ((hot*10)+(hotma*35)+(hotsignal*15)+(bankma*35)+(banksignal* 5))/ 100;
def hbma = vwma(hbAvg, 2, v);

plot HBMA2 = hbma; # "Trend Tracker"
HBMA2.AssignValueColor(if hbma > threshold then Color.CYAN else Color.MAGENTA);
plot h1 = if last then na else threshold;#, "Bullish Confirmation Line"
h1.SetDefaultColor(Color.GRAY);
h1.SetStyle(Curve.SHORT_DASH);

#//Crossing signals

def downtrendsignal = Crosses(hotma, hotsignal, CrossingDirection.BELOW);
def uptrendsignal = Crosses(hotma, hotsignal, CrossingDirection.ABOVE);
  

plot dnSig = if downtrendsignal then hbma else na;# "Downtrend signal"
plot upSig = if uptrendsignal  then hbma else na; # "Uprend signal"
dnSig.SetStyle(Curve.POINTS);
upSig.SetStyle(Curve.POINTS);
dnSig.SetDefaultColor(Color.RED);
upSig.SetDefaultColor(Color.GREEN);

def dnCond = Bank<Bank[1] and Bank<Bank[2] and Bank[1]<Bank[2] and Bank<Bank[3] and Bank<Bank[4] and Bank[3]<Bank[4] and Bank[6]>8.5 and Bank<10;

plot Dump = if Bank<Bank[1]/1.75 then Bank else na;#, "Dump Candles"
plot DnCandle = if dnCond then Bank else na;#, "Down Candles"
plot PumpCandle = if Bank>hbma then Bank else na;# "Pump Candles"
plot Retest = if banksignal>bankma and Bank>0 then Bank else na; # "Retest Candles"

Dump.SetPaintingStrategy(PaintingStrategy.SQUARED_HISTOGRAM);
Retest.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
PumpCandle.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
DnCandle.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);

Dump.SetDefaultColor(Color.RED);
Retest.SetDefaultColor(Color.DARK_RED);
PumpCandle.SetDefaultColor(Color.GREEN);
DnCandle.SetDefaultColor(Color.DARK_GRAY);

plot Banker = bank;#,   "Banker"
Banker.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Banker.AssignValueColor(if bank > 0 then GlobalColor("nor") else Color.DARK_GRAY);



#-- END of CODE

 

[Kermit]

Brilliant indicator @LOKEN94. Thanks a ton to you, as well as to our great @samer800 for helping convert to ToS platform use. Simply the best!!

 

[Bingy]

This is the best indicator on this entire forum IMHO. The more you look at it, the more you realize it's revealing to you...

I still think this is one of the best indicators on this forum. I've been looking at it for weeks now. I noticed a few opportunities it presents and I'll share a simple on here. Whenever the HBMA line is below a certain point, if you see the red cloud that's typically above it dip below it, it's presenting you with a possible scalp opportunity.

As seen in the image I've attached.

I still love this indicator. It works really well with "discretion trading", but I haven't yet been able to quantify why I'm able to make such good decisions with it in a rules based system for back-testing purposes.

 

[pooka99]

check the below

# https://www.tradingview.com/v/DlWtErRh/
#// © LOKEN94
#// Custom version based of [M2J] Indicator | MCDX
#study("LOKEN ? (v4) BULLISH MCDX v2.2", "?",precision=2)
# Converted by Sam4Cok@Samer800    - 09/2023
# Updated by Sam4Cok@Samer800    - 11/2023 - added MTF option
declare lower;
#declare zerobase;
input timeframe = {Default "Chart", "Custom"};
input customTimeframe = AggregationPeriod.FIFTEEN_MIN;
input RSIBaseBanker       = 50;#,  "Banker Base"
input RSIPeriodBanker     = 50;#,  "Banker RSI Period"
input RSIBaseHotMoney     = 30;#,  "Hot Money RSI Base"
input RSIPeriodHotMoney   = 40;#,  "Hot Money RSI Period"
input SensitivityBanker   = 1.5;#, "Sensitivity Banker"
input SensitivityHotMoney = 0.7;#, "Sensitivity Hot Money"
input threshold = 8.5;

def na = Double.NaN;
def last = isNaN(Close);
def chart = timeframe==timeframe."Chart";
def c = if chart then close else close(Period = customTimeframe);
def v = if chart then volume else volume(Period = customTimeframe);

DefineGlobalColor("nor", CreateColor(132, 175, 201));
#vwma(source, length)
script VWMA {
    input src = close;
    input len = 15;
    input v_ = volume;
    def v = if isNaN(v_) then 1 else v_;
    def srcV = src * v;
    def VWMA = Average(srcV, len) / Average(v, len);
    plot result = VWMA;
}
#rsi_function(sensitivity, rsiPeriod, rsiBase) =>
script rsi_function {
    input src = close;
    input sensitivity = 1;
    input rsiPeriod = 50;
    input rsiBase = 1;
    def nRSI = RSI(Price = src, Length = rsiPeriod);
    def rsi_ = sensitivity * (nRSI - rsiBase);
    def rsi = if rsi_ > 20 then 20 else
              if rsi_ < 0 then 0 else rsi_;
    plot out = rsi;
}

def rsi_Banker   = rsi_function(c, SensitivityBanker,   RSIPeriodBanker,   RSIBaseBanker);
def rsi_HotMoney = rsi_function(c, SensitivityHotMoney, RSIPeriodHotMoney, RSIBaseHotMoney);
def hot  = rsi_HotMoney;
def bank = rsi_Banker;
def hotMoney = hot;#, "Hot Money"

def hotma2   = WildersAverage(hot, 2);
def bankma2  = Average(bank, 2);
def hotma7   = WildersAverage(hot, 7);
def bankma7  = ExpAverage(bank, 7);
def hotma31  = WildersAverage(hot, 31);
def bankma31 = ExpAverage(bank, 31);

def hotma  = ExpAverage(((hotma2 * 34) + (hotma7 * 33) + (hotma31 * 33)) / 100, 2);
def bankma = Average(((bankma2 * 70) + (bankma7 * 20) + (bankma31 * 10)) / 100, 2);
def hotsignal  = WildersAverage(hotma, 2);
def banksignal = WildersAverage(bankma, 4);

def hotline = hotma; # "Hot Money MA"
def bankline = bankma;# "Banker MA"
def hotline2 = hotsignal;# "Hot Money MA2"
def bankline2 = banksignal; # "Banker MA2"
#//
AddCloud(hotline , hotline2, Color.DARK_GREEN, Color.DARK_RED);
AddCloud(bankline, bankline2, Color.VIOLET, Color.DARK_ORANGE);
AddCloud(hot, hotline, Color.GREEN, Color.RED);

#//
def hbAvg = ((hot*10)+(hotma*35)+(hotsignal*15)+(bankma*35)+(banksignal* 5))/ 100;
def hbma = vwma(hbAvg, 2, v);

plot HBMA2 = hbma; # "Trend Tracker"
HBMA2.AssignValueColor(if hbma > threshold then Color.CYAN else Color.MAGENTA);
plot h1 = if last then na else threshold;#, "Bullish Confirmation Line"
h1.SetDefaultColor(Color.GRAY);
h1.SetStyle(Curve.SHORT_DASH);

#//Crossing signals

def downtrendsignal = Crosses(hotma, hotsignal, CrossingDirection.BELOW);
def uptrendsignal = Crosses(hotma, hotsignal, CrossingDirection.ABOVE);
 

plot dnSig = if downtrendsignal then hbma else na;# "Downtrend signal"
plot upSig = if uptrendsignal  then hbma else na; # "Uprend signal"
dnSig.SetStyle(Curve.POINTS);
upSig.SetStyle(Curve.POINTS);
dnSig.SetDefaultColor(Color.RED);
upSig.SetDefaultColor(Color.GREEN);

def dnCond = Bank<Bank[1] and Bank<Bank[2] and Bank[1]<Bank[2] and Bank<Bank[3] and Bank<Bank[4] and Bank[3]<Bank[4] and Bank[6]>8.5 and Bank<10;

plot Dump = if Bank<Bank[1]/1.75 then Bank else na;#, "Dump Candles"
plot DnCandle = if dnCond then Bank else na;#, "Down Candles"
plot PumpCandle = if Bank>hbma then Bank else na;# "Pump Candles"
plot Retest = if banksignal>bankma and Bank>0 then Bank else na; # "Retest Candles"

Dump.SetPaintingStrategy(PaintingStrategy.SQUARED_HISTOGRAM);
Retest.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
PumpCandle.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
DnCandle.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);

Dump.SetDefaultColor(Color.RED);
Retest.SetDefaultColor(Color.DARK_RED);
PumpCandle.SetDefaultColor(Color.GREEN);
DnCandle.SetDefaultColor(Color.DARK_GRAY);

plot Banker = bank;#,   "Banker"
Banker.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Banker.AssignValueColor(if bank > 0 then GlobalColor("nor") else Color.DARK_GRAY);



#-- END of CODE

Hi @samer800

For some reason the green wave is chopped, any way we can fix it? Thanks!

I think it's more of a visual fix and not a logical/model fix that i'm searching if anyone could help here. Thanks!

 

[MerryDay]

Hi @samer800

For some reason the green wave is chopped, any way we can fix it? Thanks!

The formation of the cloud is correct based on the calculations.
It does not require fixing.
If you are asking for some sort of smoothing. That would add to the complexity of the script which wouldn't makes sense, if you are only looking for a visual fix.

 

[jonesjb]

@LOKEN94 could you please kindly share a Bearish equivalent of this script?

 

[useThinkScript]

@LOKEN94 could you please kindly share a Bearish equivalent of this script?

@LOKEN94 is the TRADINGVIEW author of this script.
Unfortunately, he does NOT provide ThinkOrSwim scripts.

If you are looking for a Tradingview script, please contact him on Tradingview.
If you are looking for a Bearish ThinkOrSwim version of this script; sorry there is not one.

 

[jonesjb]

@LOKEN94 is the TRADINGVIEW author of this script.
Unfortunately, he does NOT provide ThinkOrSwim scripts.

If you are looking for a Tradingview script, please contact him on Tradingview.
If you are looking for a Bearish ThinkOrSwim version of this script; sorry there is not one.

Thank you

 

[andre.muhammad]

This is the best indicator on this entire forum IMHO. The more you look at it, the more you realize it's revealing to you...

I still think this is one of the best indicators on this forum. I've been looking at it for weeks now. I noticed a few opportunities it presents and I'll share a simple on here. Whenever the HBMA line is below a certain point, if you see the red cloud that's typically above it dip below it, it's presenting you with a possible scalp opportunity.

As seen in the image I've attached.

I still love this indicator. It works really well with "discretion trading", but I haven't yet been able to quantify why I'm able to make such good decisions with it in a rules based system for back-testing purposes.

Have you noticed anything specific when it comes to bearish scalps? If so, do share.

 

[MerryDay]

Have you noticed anything specific when it comes to bearish scalps? If so, do share.

Did you know that by clicking on a member's name, you can easily check when they were last seen on the uTS forum? It's a great way to keep track of who's been around recently, and who hasn't. Speaking of which, it looks like @Bingy has not been around in a while.