Levels & ATR for ThinkorSwim

[RWalks]

Hey All - Looking to write a script for thinkorswim to do the following:

• Apply two horizontal white lines:
  • High line = Last closing price + (ATR * 0.2)
  • Low line = Last closing price - (ATR * 0.2)
• Apply two horizontal yellow lines:
  • High line = Price at open + (ATR * 0.2)
  • Low line = Price at open- (ATR * 0.2)

I've tried unsuccessfully to merge code from the following two posts:
https://usethinkscript.com/threads/atr-cloud-levels-for-thinkorswim.2763/
https://usethinkscript.com/threads/atr-horizontal-line.9295/

Hoping someone might be able to help me script this as manually plotting is very time consuming.

 

[halcyonguy]

Hey All - Looking to write a script for thinkorswim to do the following:

• Apply two horizontal white lines:
  • High line = Last closing price + (ATR * 0.2)
  • Low line = Last closing price - (ATR * 0.2)
• Apply two horizontal yellow lines:
  • High line = Price at open + (ATR * 0.2)
  • Low line = Price at open- (ATR * 0.2)

I've tried unsuccessfully to merge code from the following two posts:
https://usethinkscript.com/threads/atr-cloud-levels-for-thinkorswim.2763/
https://usethinkscript.com/threads/atr-horizontal-line.9295/

Hoping someone might be able to help me script this as manually plotting is very time consuming.

i think this is what you want. it plots lines after the last bar.

# atr_lines_00

#https://usethinkscript.com/threads/levels-atr-for-thinkorswim.9670/
#Levels & ATR for ThinkorSwim

def na = Double.NaN;
def bn = BarNumber();

#def istoday = if GetLastDay() == GetDay() then 1 else 0;
#def lastcls = if IsNaN(close) then lastcls[1] else close;
def lastbar = !IsNaN(close[0]) and IsNaN(close[-1]);

#---------------------------------
# ATR
input length = 14;
input averageType = AverageType.WILDERS;
def ATR = MovingAverage(averageType, TrueRange(high, close, low), length);
#---------------------------------

# reference bars after last bar
input line_length = 10;
input line_offset = 1;
def x = !IsNaN(close[line_offset + line_length - 1]) and IsNaN(close[line_offset - 1]);

input atr_factor = 0.2;


# lines
def clshi = if lastbar then (close + (ATR * atr_factor)) else clshi[1];
def clslo = if lastbar then (close - (ATR * atr_factor)) else clslo[1];
def opnhi = if lastbar then (open + (ATR * atr_factor)) else opnhi[1];
def opnlo = if lastbar then (open - (ATR * atr_factor)) else opnlo[1];

plot zchi = if x then clshi else na;
plot zclo = if x then clslo else na;
plot zohi = if x then opnhi else na;
plot zolo = if x then opnlo else na;

zchi.SetDefaultColor(Color.WHITE);
zclo.SetDefaultColor(Color.WHITE);
zohi.SetDefaultColor(Color.YELLOW);
zolo.SetDefaultColor(Color.YELLOW);

#---------------------------------------
#input testline = no;
#plot zl = if testline and x then lastcls else na;
#

 

[RWalks]

this is exactly what I was looking for! You are amazing, thank you!!