Laguerre ZigZag - A Responsive, Non-Repainting ZigZag Indicator

[whoDAT]

I'm a big fan of ZigZag indicators. A general problem is they are repainters.

A notable exception is the QQE ZigZag, an indicator that I find very useful.
https://usethinkscript.com/threads/...ncl-qqe-non-repainting-for-thinkorswim.12546/

Laguerre filters are fast-acting methods to smooth inputs. John Eulers described a fast Laguerre method to smooth financial market data in his article entitled "Time Warp - Without Space Travel". Speed is good; speed with market data is fast money.
https://www.mesasoftware.com/papers/TimeWarp.pdf

The below code uses a Eulers High-Low Laguerre Filter (EHLLF) to find uptrends and downtrends, creating a responsive, non-repainting ZigZag.

The plots include the LaguerreZigZag, along with Eulers' Filter and Finite ImpulseResponse (FIR).

All plots except the LaguerreZigZag work in TOS Mobile apps (due to the EnableApproximation function). Use the UpSignal and DownSignal with Boolean value, up or down arrows to see where the Zig Zags.

The image shows the QQE ZigZag on the left and the LaguerreZigZag on the right. Both for SPX, 5 minute time frame for the last 5 days.

Enjoy!

# Laguerre ZigZag - A responsive, non-repainting ZigZag indicator
# Authored by whoDAT - April 1, 2025

# A HL2 input is typically better to reduce the number of zigs and zags.
# The Gamma is the dampening function.
#  - Increasing Gamma values (approaching 1.0) will dampen the input more, reducing the number of zigs and zags.
#  - Lower Gamma values (approaching 0.0) will make a noisy output with more zigs and zags.
# The LowHighLookBack defines the how far back to look for the lowest or highest value to use when painting the ZigZag line.

input Price = HL2;
input Gamma = 0.80;
input LowHighLookback = 10;

# Laguerre filter
def L0 = (1 - Gamma) * Price + (Gamma * L0[1]);
def L1 = (-1 * Gamma * L0) + L0[1] + (Gamma * L1[1]);
def L2 = (-1 * Gamma * L1) + L1[1] + (Gamma * L2[1]);
def L3 = (-1 * Gamma * L2) + L2[1] + (Gamma * L3[1]);

def Filt = (L0 + (2 * L1) + (2 * L2) + L3) / 6;
def FIR = (Price + (2 * Price[1]) + (2 * Price[2]) + Price[3]) / 6;

# If the Laguerre filter is increasing (or decreasing), this is an uptick (downtick). That is used to make the upward or downward signal to find the zigs and zags.
def Uptick = if (L0 > Filt) then 1 else Double.NaN;
def Downtick = if (L0 < Filt) then 1 else Double.NaN;

def UpSig = if Downtick[1] == 1 and Uptick[0] == 1 then Lowest(low, LowHighLookback) else Double.NaN;
def DnSig = if Uptick[1] == 1 and Downtick[0] == 1 then Highest(high, LowHighLookback) else Double.NaN;

def ZZL = if !IsNaN(UpSig) then UpSig else if !IsNaN(DnSig)  then DnSig else Double.NaN;

plot ZigZagLaguerre = ZZL;
ZigZagLaguerre.EnableApproximation();

plot FilterResponse = Filt;
plot FiniteImpulseResponse = FIR;
plot UpSignal = UpSig;
plot DownSignal = DnSig;

# END OF CODE

 

[netarchitech]

@whoDAT...I didn't know you could do that...

Nicely done! Thanks for sharing...