Label that counts signals from chart overlay

[jordan]

I need a label that can count the number of signals given from a chart overlay but I can't get the code to work and am wondering if it's possible. For example, I can overlay "LI" to my current chart, give it a 200sma, and plot a potential signal where the low is less than the 200sma but I can't get the total sum of signals. Any advice?

input Security = "LI";
input SecurityType = {"BAR", default"CANDLE", "LINE"};
AddChart(high = high(Security), low = low(Security),open = open(Security), close = close(Security), type = SecurityType);

input LengthMA = 200;
input AvgTypeMA = AverageType.SIMPLE;
plot MA = MovingAverage(AvgTypeMA, close(security), LengthMA);

plot lows = if Low(security) is less than MA then low(security) else double.NaN;
lows.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
lows.SetLineWeight(5);
lows.SetDefaultColor(Color.ORANGE);

AddLabel(yes, "Security Signals: " + TotalSum(Low(security) is less than MA), Color.MAGENTA);


This code works when applied to the current chart but not to chart overlays. When applied to the current chart it looks like

input LengthMA = 200;
input AvgTypeMA = AverageType.SIMPLE;
plot MA = MovingAverage(AvgTypeMA, close, LengthMA);

plot lows = if Low is less than MA then low else double.NaN;
lows.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
lows.SetLineWeight(5);
lows.SetDefaultColor(Color.ORANGE);

AddLabel(yes, "Signals2: " + TotalSum(low is less than MA), Color.MAGENTA);

 

[SleepyZ]

I need a label that can count the number of signals given from a chart overlay but I can't get the code to work and am wondering if it's possible. For example, I can overlay "LI" to my current chart, give it a 200sma, and plot a potential signal where the low is less than the 200sma but I can't get the total sum of signals. Any advice?

input Security = "LI";
input SecurityType = {"BAR", default"CANDLE", "LINE"};
AddChart(high = high(Security), low = low(Security),open = open(Security), close = close(Security), type = SecurityType);

input LengthMA = 200;
input AvgTypeMA = AverageType.SIMPLE;
plot MA = MovingAverage(AvgTypeMA, close(security), LengthMA);

plot lows = if Low(security) is less than MA then low(security) else double.NaN;
lows.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
lows.SetLineWeight(5);
lows.SetDefaultColor(Color.ORANGE);

AddLabel(yes, "Security Signals: " + TotalSum(Low(security) is less than MA), Color.MAGENTA);


This code works when applied to the current chart but not to chart overlays. When applied to the current chart it looks like

input LengthMA = 200;
input AvgTypeMA = AverageType.SIMPLE;
plot MA = MovingAverage(AvgTypeMA, close, LengthMA);

plot lows = if Low is less than MA then low else double.NaN;
lows.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
lows.SetLineWeight(5);
lows.SetDefaultColor(Color.ORANGE);

AddLabel(yes, "Signals2: " + TotalSum(low is less than MA), Color.MAGENTA);

It appears, as is often the case, that the security overlaid on to another security may have blank (nan) periods. So I used a 'recursive' (def) variable to reference itself to assign the prior real value to the missing period. As addchart does not allow 'recursives', a workaround adding a '+ 0' to each variable seems to work,

The 'Signal2' sum varied by the instrument to which 'LI', in this case, is overlaid onto by the number of bars of the overlaid instrument. Make sure to check the 'enable left axis' in chart settings, price axis tab, and check 'left axis' in the input section of your study.

Hope this helps

input Security = "LI";
input SecurityType = {"BAR", default "CANDLE", "LINE"};
def h = if IsNaN(high(Security)) then h[1] else high(Security);
def l = if IsNaN(low(Security)) then l[1] else low(Security);
def o = if IsNaN(open(Security)) then o[1] else open(Security);
def c = if IsNaN(close(Security)) then c[1] else close(Security);
def h1 = h + 0;
def l1 = l + 0;
def o1 = o + 0;
def c1 = c + 0;
AddChart(high = h1, low = l1, open = o1, close = c1, type = SecurityType);

input LengthMA = 200;
input AvgTypeMA = AverageType.SIMPLE;
def MA = if IsNaN(close) then MA[1] else MovingAverage(AvgTypeMA, c1, LengthMA);

plot lows = if l1 is less than MA then l1 else Double.NaN;
lows.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
lows.SetLineWeight(5);
lows.SetDefaultColor(Color.ORANGE);

AddLabel(yes, "Security Signals: " + TotalSum(l1 is less than MA), Color.MAGENTA);

 

[jordan]

This is a huge help and will expand my understanding of thinkscript for future projects. Thank you SleepyZ.