Karobein Oscillator For ThinkOrSwim

[eagle_ai]

The author states: The Karobein oscillator is an oscillator that aim to rescale smoothed values with more reactivity in a range of (0,1).

How To Use
It is better to use centerline-cross/breakouts/signal line.

In general when we use something smooth as input in oscillators, breakouts are better than reversals, you can see this with the stochastic and rsi.

So a simple approach could be buying when crossing over 0.8 and selling when crossing under 0.2.

Original Tradingview code
https://www.tradingview.com/script/JiNi0f62-Karobein-Oscillator/

For the new ThinkOrSwim code, you must scroll down to the next post

 

[samer800]

https://www.tradingview.com/script/JiNi0f62-Karobein-Oscillator/

Please convert this. Thank you.

check the below

# Indicator for TOS
#//@alexgrover
#study("Karobein Oscillator")
# Converted by Sam4Cok@Samer800    - 11/2024

declare lower;

input timeframe  = AggregationPeriod.MIN;
input movAvgType = AverageType.EXPONENTIAL;
input source = FundamentalType.CLOSE;
input length = 50;
input showSignalLines = yes;
input thresholdBull = 80;
input thresholdBear = 20;
input useSmoothing = no;
input smoothingLength = 9;
input colorBars = yes;

def na = Double.NaN;
def last = IsNaN(close);
def cap = GetAggregationPeriod();
def tf = Max(cap, timeframe);

def ema = MovingAverage(movAvgType, Fundamental(source, Period = tf), length);
def a   = MovingAverage(movAvgType, if ema < ema[1] then ema / ema[1] else 0, length);
def b   = MovingAverage(movAvgType, if ema > ema[1] then ema / ema[1] else 0, length);
def c = (ema / ema[1]) / (ema / ema[1] + b);
def d = 2 * ((ema / ema[1]) / (ema / ema[1] + c * a)) - 1;
def Karobein = d * 100;
def smD = MovingAverage(movAvgType, Karobein, smoothingLength);
#-- Plot
def mid = (thresholdBull + thresholdBear) / 2;
plot KarobeinOsc = if last then na else if useSmoothing then smD else Karobein;
plot zr = if last then na else mid;
plot ob = if last then na else thresholdBull;
plot os = if last then na else thresholdBear;

zr.SetStyle(Curve.SHORT_DASH);
KarobeinOsc.SetLineWeight(2);
KarobeinOsc.SetDefaultColor(Color.GRAY);
zr.SetDefaultColor(Color.DARK_GRAY);
ob.SetDefaultColor(Color.DARK_GREEN);
os.SetDefaultColor(Color.DARK_RED);

AddCloud(KarobeinOsc,  ob,  Color.DARK_GREEN,  Color.CURRENT);
AddCloud(os, KarobeinOsc, Color.DARK_RED, Color.CURRENT);

#-- Bar Color

AssignPriceColor(if !colorBars then Color.CURRENT else
                 if KarobeinOsc > thresholdBull then Color.GREEN else
                 if KarobeinOsc < thresholdBear then Color.RED else
                 if KarobeinOsc > mid then Color.DARK_GREEN else
                 if KarobeinOsc > thresholdBear then Color.DARK_RED else Color.GRAY);
#-- Signals

AddVerticalLine(showSignalLines and (KarobeinOsc Crosses Above thresholdBull), "B", Color.GREEN);
AddVerticalLine(showSignalLines and (KarobeinOsc Crosses Below thresholdBear), "S", Color.RED);

#-- END of CODE