Jman Donchian Bounded Volume Oscillator For ThinkOrSwim

[Jman831]

Hey fellow traders,

I finally came up with a new indicator to share with you all that I call the "Donchian Bounded Volume Oscillator". To understand how it works please read the description starting at line 3 in the code itself.

Edit: I meant to say when initially making this post that the copyright in the code allows for anyone to reuse, make adaptations, or changes to the code for both personal and commercial use as long as you include the first line of this code in the code somewhere. In other words, you're free to do with it as you please as long as you give credit where credit is due.

#Donchian Bounded Volume Oscillator © 2025 by Jman831 @ usethinkscript.com is licensed under Creative Commons Attribution-ShareAlike 4.0 International.

#This code calculates the percentage difference between two averages of volume specified by the user. It then finds the highest and lowest percentage differences of the last so many bars ("DonchianLength") specified by the user. Finally it plots the percentage difference as a percentage between the highest and the lowest percentage differences forcing an upper boundary of 100% and a lower boundary of -100%. If the oscillator tops off at 100% or bottoms out at -100% the oscillator is making new highs or new lows respectively.

declare lower;

#Short Average Inputs
input ShortAvgType = averageType.SIMPLE;
input ShortAvgLength = 9;
#Long Average Inputs
input LongAvgType = averageType.SIMPLE;
input LongAvgLength = 12;
#Length of Donchian Channel Within Which Oscillator Percentage Is Bound
input DonchianLength = 72;

#Short Average Of Volume
def shavg = MovingAverage(ShortAvgType, volume, ShortAvgLength);
#Long Average Of Volume
def loavg = MovingAverage(LongAvgType, volume, LongAvgLength);
#Raw Difference Between Short And Long Averages
def avgdiff = shavg - loavg;
#Percentage Difference Between Short And Long Averages
def diffper = Round(avgdiff / loavg * 100, 2);
#Highest Percentage Difference
def donhigh = highest(diffper, DonchianLength);
#Lowest Percentage Difference
def donlow = lowest(diffper, DonchianLength);
#Middle Of Highest And Lowest Percentage Differences
def donmid = (donhigh + donlow) / 2;

#Bounded Percentage Based On Highest And Lowest
def boundedosc = Round((diffper - donmid) / (donhigh - donmid) * 100, 2);

#Upper Boundary Percentage
plot OneHundred = 100;
#Middle
plot Zero = 0;
#Lower Boundary Percentage
plot NegativeOneHundred = -100;
#Donchian Bounded Volume Oscillator
plot DonchianBoundedVolumeOsc = boundedosc;

#Default Color For Upper Boundary
OneHundred.setDefaultColor(color.VIOLET);
#Default Color For Middle
Zero.setDefaultColor(color.CYAN);
#Default Color For Lower Boundary
NegativeOneHundred.setDefaultColor(color.VIOLET);
#Histogram Painting Strategy For Bounded Oscillator
DonchianBoundedVolumeOsc.setPaintingStrategy(paintingStrategy.HISTOGRAM);
#Conditional Colors Of Bounded Oscillator
DonchianBoundedVolumeOsc.assignValueColor(if boundedosc > 0 then color.LIGHT_GREEN else if boundedosc == 0 then color.GRAY else color.LIGHT_RED);

Here are a couple screenshots of the indicator on a daily chart of SPY:

Please don't hesitate to share insights or questions about the indicator you might have. As always, happy trading! =-) <3