Hyper MA Loop | QuantEdgeB For ThinkOrSwim

lovetotrade20024 · Feb 16, 2025

Author states: Hyper MA Loop | QuantEdgeB is an advanced trend-following indicator that leverages a custom Hyper Moving Average (HyMA) and an innovative loop-based scoring system to assess trend strength and direction. This tool is designed to provide a dynamic perspective on market momentum, allowing traders to capture trends effectively while filtering out market noise.

Use Cases:

Ideal for trend-following traders looking for solid trends confirmation.

Helps filter out choppy market conditions by adjusting sensitivity dynamically.

Works well with other indicators (e.g., ADX, volume-based filters) for added confirmation.

Suitable for both short-term and long-term trend analysis.

Here is the original Tradingview code:
https://www.tradingview.com/v/zGVsD0sB/

For the new ThinkOrSwim code, you must scroll down to the next post

samer800 · Feb 18, 2025

lovetotrade20024 said:
https://www.tradingview.com/v/zGVsD0sB/

Upper Study:

CSS:

#// Indicator for TOS
#// © QuantEdgeB
#indicator("Hyper MA Loop | QuantEdgeB", overlay = false)
# Converted by Sam4Cok@Samer800    - 02/2025

input colorBars = yes;
input HyperMaSource = close; # "HyperMA Source"
input HyperMaLength = 2;     # "Hyper MA Length"
input strat_loop  = 1;       # 'Start'
input end_loop    = 60;      # 'End'
input ThresholdForLong = 40; # 'Threshold for long'
input ThresholdForShort = 8; # 'Threshold for short'

def na = Double.NaN;
def last = isNaN(close);

#// Hyper MA Calculation
Script f_HyMA {
input src = close;
input len = 2;
    def sum_hyp = fold i = 0 to len with p do
                  p + src[i] * (1 / (len - i));
    def sum_weights = fold j = 0 to len with q do
                     q + (1 / (len - j));
    def f_HyMA = if sum_weights > 0 then sum_hyp / sum_weights else Double.NaN;
    plot out = f_HyMA;
}
#// Loop Function
Script loop_f {
input a = 1;
input b = 60;
input ma = close;
    def sum2 = fold i = a to b + 1 with p do
               p + (if ma > ma[i] then 1 else -1);
    plot out = sum2;
}
def HyMa = f_HyMA(HyperMaSource, HyperMaLength);
def hyma_loop = loop_f(strat_loop , end_loop, HyMa);
#// Final Signal
def Long_C  = hyma_loop > ThresholdForLong;
def Short_C = hyma_loop < ThresholdForShort;
def QB = if Long_C and !Short_C then 1 else
         if Short_C then -1 else QB[1];
#// Color
def col = if QB > 0 then 1 else if QB < 0 then -1 else 0;
#// Extra Plots
def plotline1 = ExpAverage(close,3);
def plotline2 = ExpAverage(plotline1, 16*2);
def plotline3 = ExpAverage(plotline1, 16*3);
def plotline4 = ExpAverage(plotline1, 14);
def band_width = AbsValue(plotline2 - plotline4) / close;

#// Plots
def upCol = (col > 0 or col[-1] > 0);
def dnCol = (col < 0 or col[-1] < 0);
plot Line4 = if !last then plotline4 else na;

Line4.AssignValueColor(if col>0 then Color.CYAN else if col<0 then Color.MAGENTA else Color.GRAY);

AddCloud(if upCol then plotline4 else na, plotline3, Color.CYAN, Color.CYAN);
AddCloud(if upCol then plotline2 else na, plotline3, Color.CYAN, Color.CYAN);
AddCloud(if dnCol then plotline4 else na, plotline3, Color.PLUM, Color.PLUM);
AddCloud(if dnCol then plotline2 else na, plotline3, Color.PLUM, Color.PLUM);

AddCloud(if col > 0 and last[-2] then plotline2 else na, plotline3, Color.CYAN, Color.CYAN);
AddCloud(if col < 0 and last[-2] then plotline4 else na, plotline3, Color.PLUM, Color.PLUM);
AddCloud(if col < 0 and last[-2] then plotline2 else na, plotline3, Color.PLUM, Color.PLUM);

#-- Bar Color
AssignPriceColor(if !colorBars then Color.CURRENT else
                 if col>0 then Color.CYAN else if col<0 then Color.MAGENTA else Color.GRAY);

#-- END of CODE

Lower Study:

CSS:

#// Indicator for TOS
#// © QuantEdgeB
#indicator("Hyper MA Loop | QuantEdgeB", overlay = false)
# Converted by Sam4Cok@Samer800    - 02/2025
Declare lower;

input colorBars = yes;
input HyperMaSource = close; # "HyperMA Source"
input HyperMaLength = 2;     # "Hyper MA Length"
input strat_loop  = 1;       # 'Start'
input end_loop    = 60;      # 'End'
input ThresholdForLong = 40; # 'Threshold for long'
input ThresholdForShort = 8; # 'Threshold for short'

def na = Double.NaN;
def last = isNaN(close);

#// Hyper MA Calculation
Script f_HyMA {
input src = close;
input len = 2;
    def sum_hyp = fold i = 0 to len with p do
                  p + src[i] * (1 / (len - i));
    def sum_weights = fold j = 0 to len with q do
                     q + (1 / (len - j));
    def f_HyMA = if sum_weights > 0 then sum_hyp / sum_weights else Double.NaN;
    plot out = f_HyMA;
}
#// Loop Function
Script loop_f {
input a = 1;
input b = 60;
input ma = close;
    def sum2 = fold i = a to b + 1 with p do
               p + (if ma > ma[i] then 1 else -1);
    plot out = sum2;
}
def HyMa = f_HyMA(HyperMaSource, HyperMaLength);
def hyma_loop = loop_f(strat_loop , end_loop, HyMa);
#// Final Signal
def Long_C  = hyma_loop > ThresholdForLong;
def Short_C = hyma_loop < ThresholdForShort;
def QB = if Long_C and !Short_C then 1 else
         if Short_C then -1 else QB[1];
#// color
def col = if QB > 0 then 1 else if QB < 0 then -1 else 0;

#-- plot
plot HyperMALoop = if !last then hyma_loop else na; #"Hyper MA Loop"
plot LongTh = if !last then ThresholdForLong else na; #"Long Threshold"
plot ShortTh = if !last then ThresholdForShort else na ; # "Short Threshold"
HyperMALoop.SetLineWeight(2);
HyperMALoop.AssignValueColor(if col>0 then Color.CYAN else if col<0 then Color.MAGENTA else Color.GRAY);
LongTh.SetDefaultColor(Color.GREEN);
ShortTh.SetDefaultColor(Color.RED);

#-- Bar Color
AssignPriceColor(if !colorBars then Color.CURRENT else
                 if col>0 then Color.CYAN else if col<0 then Color.MAGENTA else Color.GRAY);

#-- END of CODE

chewie76 · Mar 15, 2025

Nice indicator!! I added some support and resistance bands.

Code:

#// Indicator for TOS
#// © QuantEdgeB
#indicator("Hyper MA Loop | QuantEdgeB", overlay = false)
# Converted by Sam4Cok@Samer800    - 02/2025
# Added Support/Resistance bands -Chewie76 03/2025

input colorBars = no;
input HyperMaSource = close; # "HyperMA Source"
input HyperMaLength = 2;     # "Hyper MA Length"
input strat_loop  = 1;       # 'Start'
input end_loop    = 60;      # 'End'
input ThresholdForLong = 40; # 'Threshold for long'
input ThresholdForShort = 8; # 'Threshold for short'
input inner = yes;
input factor = 1.0;
input factor2 = 1.6;
input factor3 = 2.0;
input factor4 = 3.0;
input factor5 = 4.2;
input trueRangeAverageType = AverageType.EXPONENTIAL;

def displace = 0;
def na = Double.NaN;
def last = IsNaN(close);

#// Hyper MA Calculation
script f_HyMA {
    input src = close;
    input len = 2;
    def sum_hyp = fold i = 0 to len with p do
                  p + src[i] * (1 / (len - i));
    def sum_weights = fold j = 0 to len with q do
                     q + (1 / (len - j));
    def f_HyMA = if sum_weights > 0 then sum_hyp / sum_weights else Double.NaN;
    plot out = f_HyMA;
}
#// Loop Function
script loop_f {
    input a = 1;
    input b = 60;
    input ma = close;
    def sum2 = fold i = a to b + 1 with p do
               p + (if ma > ma[i] then 1 else -1);
    plot out = sum2;
}
def HyMa = f_HyMA(HyperMaSource, HyperMaLength);
def hyma_loop = loop_f(strat_loop , end_loop, HyMa);
#// Final Signal
def Long_C  = hyma_loop > ThresholdForLong;
def Short_C = hyma_loop < ThresholdForShort;
def QB = if Long_C and !Short_C then 1 else
         if Short_C then -1 else QB[1];
#// Color
def col = if QB > 0 then 1 else if QB < 0 then -1 else 0;
#// Extra Plots
def plotline1 = ExpAverage(close, 3);
plot plotline2 = ExpAverage(plotline1, 16 * 2);
def plotline3 = ExpAverage(plotline1, 16 * 3);
def plotline4 = ExpAverage(plotline1, 25); #14
def band_width = AbsValue(plotline2 - plotline4) / close;

plotline2.SetDefaultColor(Color.YELLOW);
plotline2.SetLineWeight(1);

def shift = factor * MovingAverage(trueRangeAverageType, TrueRange(high, close, low), 34);
def shift2 = factor2 * MovingAverage(trueRangeAverageType, TrueRange(high, close, low), 34);
def shift3 = factor3 * MovingAverage(trueRangeAverageType, TrueRange(high, close, low), 34);
def shift4 = factor4 * MovingAverage(trueRangeAverageType, TrueRange(high, close, low), 34);
def shift5 = factor5 * MovingAverage(trueRangeAverageType, TrueRange(high, close, low), 34);

#// Plots
def upCol = (col > 0 or col[-1] > 0);
def dnCol = (col < 0 or col[-1] < 0);
def Line4 = if !last then plotline4 else na;

#Line4.AssignValueColor(if col > 0 then Color.CYAN else if col < 0 then Color.MAGENTA else Color.GRAY);

plot Upper_Band = if inner then plotline2[-displace] + shift[-displace] else double.nan;
#Upper_Band.SetDefaultColor(CreateColor(255, 51, 153));
Upper_Band.SetDefaultColor(Color.dark_gray);
plot Lower_Band = if inner then plotline2[-displace] - shift[-displace] else double.nan;
#Lower_Band.SetDefaultColor(CreateColor(102, 255, 153));
Lower_Band.SetDefaultColor(Color.dark_gray);

plot Upper_Band2 = if inner then plotline2[-displace] + shift2[-displace] else double.nan;
#Upper_Band2.SetDefaultColor(CreateColor(255, 51, 153));
Upper_Band2.SetDefaultColor(Color.dark_orange);
Upper_Band2.setlineWeight(1);
plot Lower_Band2 = if inner then plotline2[-displace] - shift2[-displace] else double.nan;
#Lower_Band2.SetDefaultColor(CreateColor(102, 255, 153));
Lower_Band2.SetDefaultColor(Color.lime);
Lower_Band2.setlineWeight(1);

plot Upper_Band3 = plotline2[-displace] + shift3[-displace];
Upper_Band3.SetDefaultColor(color.magenta);
Upper_Band3.setlineWeight(1);
plot Lower_Band3 = plotline2[-displace] - shift3[-displace];
Lower_Band3.SetDefaultColor(Color.cyan);
Lower_Band3.setlineWeight(1);

plot Upper_Band4 = plotline2[-displace] + shift4[-displace];
Upper_Band4.SetDefaultColor(Createcolor(153,0,153));
Upper_Band4.setlineWeight(2);
plot Lower_Band4 = plotline2[-displace] - shift4[-displace];
Lower_Band4.SetDefaultColor(Createcolor(0,153,153));
Lower_Band4.setlineWeight(2);

plot Upper_Band5 = plotline2[-displace] + shift5[-displace];
Upper_Band5.SetDefaultColor(Color.dark_gray);
Upper_Band5.setlineWeight(2);
plot Lower_Band5 = plotline2[-displace] - shift5[-displace];
Lower_Band5.SetDefaultColor(Color.dark_gray);
Lower_Band5.setlineWeight(2);

AddCloud(upper_band3, upper_band4 , CreateColor(204,102,255), CreateColor(204,102,255));
AddCloud(lower_band3, lower_band4, CreateColor(153,255,255), CreateColor(153,255,255));

AddCloud(if upCol then plotline4 else na, plotline3, Color.CYAN, Color.CYAN);
AddCloud(if upCol then plotline2 else na, plotline3, Color.CYAN, Color.CYAN);
AddCloud(if dnCol then plotline4 else na, plotline3, Color.PLUM, Color.PLUM);
AddCloud(if dnCol then plotline2 else na, plotline3, Color.PLUM, Color.PLUM);

AddCloud(if col > 0 and last[-2] then plotline2 else na, plotline3, Color.CYAN, Color.CYAN);
AddCloud(if col < 0 and last[-2] then plotline4 else na, plotline3, Color.PLUM, Color.PLUM);
AddCloud(if col < 0 and last[-2] then plotline2 else na, plotline3, Color.PLUM, Color.PLUM);

#-- Bar Color
AssignPriceColor(if !colorBars then Color.CURRENT else
                 if col > 0 then Color.CYAN else if col < 0 then Color.MAGENTA else Color.GRAY);

#-- END of CODE

Thread starter	Similar threads	Forum	Replies	Date
S	Zero Lag Signals For Loop [QuantAlgo] For ThinkOrSwim	Custom	3	Dec 29, 2024
	Gaussian SWMA For Loop [By Coff3eG] for ThinkOrSwim	Custom	0	Nov 17, 2024

Hyper MA Loop | QuantEdgeB For ThinkOrSwim

lovetotrade20024

New member

samer800

Moderator - Expert

chewie76

Well-known member

Similar threads

Not the exact question you're looking for?

Similar threads

Similar threads

The Market Trading Game Changer

Frequently Asked Questions