Hindenburg Omen with McClellan Cancellation For ThinkOrSwim

[finnovator]

"Hindenburg's Omen" is a technical indicator in financial analysis designed to predict a potential significant decline or a stock market crash.

How it works

• Hindenburg's Omen is triggered when several conditions are met simultaneously on a stock market:
• A high number of stocks reaching both new highs and lows over 52 weeks (usually more than 2.2% of stocks).
• The number of new highs must not exceed twice the number of new lows.
• The stock index must be in an upward trend (positive 50-day or 10-week moving average).

-The McClellan Oscillator (sentiment indicator) should be negative.

Interpretation
-When these conditions are met, the Omen suggests underlying market instability and an increased risk of a significant decline.
-The signal remains active for 30 trading days.

Reliability
-The indicator has correctly signaled some historical crashes, such as the one in 1987.
-However, its reliability is questionable as it also produces many false signals.

Usage
-Generally used in conjunction with other forms of technical analysis to confirm sell signals.

Here is the original Tradingview code:
https://www.tradingview.com/script/eX8c6PaG-Hindenburg-Omen-with-McClellan-Oscillator-Cancellation/

For the new ThinkOrSwim code, you must scroll down to the next post

 

[samer800]

Hi,

I found another script for HindenBurg Omen Indicator in PineScript. Can someone who is familiar with Thinkscript please convert it to equivalent Thinkscript?

https://www.tradingview.com/script/eX8c6PaG-Hindenburg-Omen-with-McClellan-Oscillator-Cancellation/

Thanks!

check the below:

#// Indicator for TOS
#//The original code by Boombotcom: Hindenburg Omen Clean
#//I just added the signal cancellation criteria if McClellan Oscillator goes above zero as per Sentimentrader
#study("Hindenburg Omen",shorttitle="HOmen",overlay=true)
# Converted by Sam4Cok@Samer800    - 01/2025
def na = Double.NaN;

#//Count of Advancing Issues
def ADV = close(Symbol = "$ADVARC", Period = "DAY");
#//Count of Unchanged Issues
def UNC = close(Symbol = "$UNCAR", Period = "DAY");
#//Count of Declining Issues
def DEC = close(Symbol = "$DECARC", Period = "DAY");
#//Count of Issues Hitting 52Week Highs
def NEWH = close(Symbol = "$NYHGH", Period = "DAY");
#//Count of Issues Hitting 52Week Lows
def NEWL = close(Symbol = "$NYLOW", Period = "DAY");
#//NYSE Index Value
def INDEX = close(Symbol = "NYA", Period = "DAY");

#//Total Number of Issues
def TOTAL = ADV+DEC+UNC;
#//McClelland Oscillator
def RANA = 1000*((ADV-DEC)/(ADV+DEC));
def MA1 = ExpAverage(RANA,19);
def MA2 = ExpAverage(RANA,39);
def MCC = MA1-MA2;
#//Condition 1: % of Issues of hitting New 52W highs and 52W lows is greater than or equal to 2.8%.
def COND1= ((NEWH/TOTAL)>=.028 and (NEWL/TOTAL)>=.028); #?1:na
#//Condition 2: Index is higher or equal in value than when it was 50 days ago.
def COND2=(INDEX>=INDEX[50]); #?1:na
#//Condition 3: McClelland Oscillator must be negative.
def COND3=(MCC<0); #?1:na
#//Condition 4: The ratio of New 52W Highs to New 52W Lows cannot exceed 2
def COND4=((NEWH/NEWL)<2); #?1:na
#//Hindenburg Condition
#//All four conditions are met
def ALL4 = (COND1+COND2+COND3+COND4);
def HOmen= ALL4==4; #?true:false)

#//Plots the Hindenburg Signal above bar

plot signal = if HOmen then highest(high,30) * 1.00250 else na;
signal.SetDefaultColor(Color.WHITE);
signal.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);

#/Hindenburg Omen Signal Period of 30 days
#//If MCC turns positive signal should be cancelled per Sentimentrader. I added this to the code
def barssince = if HOmen then 0 else barssince[1] + 1;
def test= barssince <= 30;
def cancelled = MCC > 0 or (cancelled[1] and !HOmen);
def cond = test and !cancelled;

#bgcolor(test == 1 and cancelled == false ? maroon : na, transp=90)
def pos = Double.POSITIVE_INFINITY;
def neg = Double.NEGATIVE_INFINITY;
AddCloud(if cond or cond[-1] then pos else na, neg, Color.DARK_RED);

#-- END of CODE