Expansion Area MA Lines & Bubble

[Whistler]

I’ve seen the ability to plot the moving average for a timeframe other than the current chart as a short straight line with its chart bubble in the far right portion of the expansion area. The attached chart has daily timeframe EMAs plotted on a 1 minute chart. To me this seems like it would be a great way of tracking those levels without interfering with price plots. But I have a hard time understanding how thinkscript handles time designations, especially time periods beyond the current. Does anybody have any ideas on how to go about coding a way of doing this?

This is my first time trying to post an image. I don't see it in the preview even though I followed the usethinkscript directions. But the image should be viewable at

https://imgur.com/a/RsH7lju

 

[halcyonguy]

I’ve seen the ability to plot the moving average for a timeframe other than the current chart as a short straight line with its chart bubble in the far right portion of the expansion area. The attached chart has daily timeframe EMAs plotted on a 1 minute chart. To me this seems like it would be a great way of tracking those levels without interfering with price plots. But I have a hard time understanding how thinkscript handles time designations, especially time periods beyond the current. Does anybody have any ideas on how to go about coding a way of doing this? hal_bub

to draw objects after the last bar, you can use offsets on variables to reference the last bar, x number of bars back.

here is an example to,
draw a line after the last bar.
..can pick how many bars after last bar.
..can pick how long the line is, in bars.

draw a bubble after the last bar

# future_line_02

# plot a line, x bars after last bar, y bars long
def na = double.nan;
def bn = barnumber();

# set this to the desired signal
def data = close;

# last bar
def lastbar = !isnan(close[0]) and isnan(close[-1]);
def lastbarnum = if barnumber() == 1 then 0 else if lastbar then barnumber() else lastbarnum[1];

# get price from last bar, and keep
def lastdata = if barnumber() == 1 then 0 else if lastbar then data else lastdata[1];

input bars_after_last_bar = 3;
def ba = bars_after_last_bar;

input line_x_bars_long = 7;
def bl = line_x_bars_long;

def line_en = !isnan(close[ba + bl - 1]) and isnan(close[ba - 1]);

plot z = if line_en then lastdata else na;
#z.SetStyle(Curve.MEDIUM_DASH);
z.SetDefaultColor(Color.cyan);
#z.setlineweight(1);
z.hidebubble();

# --------------------------

# plot a bubble, x bars after last bar
input show_bubble = yes;

# calc future bar
input bars_in_future = 5;
def bif = bars_in_future;

def cl = close;
def x = IsNaN(cl[bif]) and !IsNaN(cl[bif + 1]);

# read price level from the last bar
def vert = close[bif + 1];
AddChartBubble(show_bubble and x, vert, "$" + vert, Color.WHITE, yes);
#

 

[Whistler]

halcyonguy - Wow! Thank you so much. This is doing exactly what I wanted it to do. And now I have a much better idea of how thinkscipt handles some of these concepts. I'll work with it some and get back with any questions, but I think you've left it pretty self-explanatory at this point. Thanks again!

 

[krahsloop]

Using this to cleanup my daily chart, thank you! Specifying after which bar the line begins is awesome, I don't recall seeing that before.

 

[bryceln]

Love it but is there a way to put daily levels on a smaller timeframe - 5m chart for example showing me what the yesterdays close for example.

 

[halcyonguy]

Love it but is there a way to put daily levels on a smaller timeframe - 5m chart for example showing me what the yesterdays close for example.

sure, just need to change a couple formulas, replace close with a different variable.

line data
def data = close;

bubble data
def vert = close[bif + 1];

just be aware that close , or whatever, has an offset to point back at the last bar, to read a valid price.

i think that already exists on here somewhere... or somethingthing similar. i'm remembering several colored, horizontal lines, after the last bar. will see if i can find it.