input TakeProfitPct = .5; #hint, 1 is 1 pct, .5 is 1/2 percent, etc
def takeprofitconverstionLong = 1 + (TakeProfitPct / 100);
addlabel(1,(takeprofitconverstionLong*close)-close, color.white);
def takeprofitconverstionshort = 1 - (TakeProfitPct / 100);
addlabel(1,(takeprofitconverstionshort*close)-close, color.white);
input Major_bubbleoffset = .0005;
input Major_percentamount = .15;
input Major_revAmount = .2;
input Major_atrreversal = 3.75;
input Major_atrlength = 5;
def BN = BarNumber();
def zz = ZigZagHighLow("price h" = high, "price l" = low, "percentage reversal" = Major_percentamount, "absolute reversal" = Major_revAmount, "atr length" = Major_atrlength, "atr reversal" = Major_atrreversal);
def reversalAmount = if (close * Major_percentamount / 100) > Max(Major_revAmount < Major_atrreversal * Major_atrlength, Major_revAmount) then (close * Major_percentamount / 100) else if Major_revAmount < Major_atrreversal * Major_atrlength then Major_atrreversal * Major_atrlength else Major_revAmount;
rec zzSave = if !IsNaN(zz) then zz else GetValue(zzSave, 1);
def chg = (if zzSave == high then high else low) - GetValue(zzSave, 1);
def isUp = chg >= 0;
rec isConf = AbsValue(chg) >= reversalAmount or (IsNaN(GetValue(zz, 1)) and GetValue(isConf, 1));
def zzd = if isUp then 1 else 0;
plot zzp = if zzd <= 1 then zz else Double.NaN;
zzp.AssignValueColor(if zzd == 1 then Color.GREEN else if zzd == 0 then Color.RED else Color.DARK_ORANGE);
zzp.SetStyle(Curve.FIRM);
zzp.EnableApproximation();
zzp.SetLineWeight(1);
#Price Change between zigzags
def xxhigh = if zzSave == high then high else xxhigh[1];
def chghigh = high - xxhigh[1];
def xxlow = if zzSave == low then low else xxlow[1];
def chglow = low - xxlow[1];
input showMagnitudeBubbles = yes;
AddChartBubble(showMagnitudeBubbles and !IsNaN(zz) and BarNumber() != 1, if isUp then high * (1 + Major_bubbleoffset) else low * (1 - Major_bubbleoffset) , "$" + chg , if isUp and chghigh > 0 then Color.GREEN else if isUp and chghigh < 0 then Color.RED else if isUp then Color.YELLOW else if !isUp and chglow > 0 then Color.GREEN else if !isUp and chglow < 0 then Color.RED else Color.YELLOW, isUp);
#Price at High/Low
input Major_showBubblesprice = no;
AddChartBubble(Major_showBubblesprice and !IsNaN(zz) and BarNumber() != 1, if isUp then high * (1 + Major_bubbleoffset) else low * (1 - Major_bubbleoffset) , if isUp then "$" + high else "$" + low , if isUp and chghigh > 0 then Color.GREEN else if isUp and chghigh < 0 then Color.RED else if isUp then Color.YELLOW else if !isUp and chglow > 0 then Color.GREEN else if !isUp and chglow < 0 then Color.RED else Color.YELLOW, isUp);
input Minor_bubbleoffset2 = .0005;
input Minor_percentamount2 = .01;
input Minor_revAmount2 = .1;
input Minor_atrreversal2 = 2.0;
input Minor_atrlength2 = 9;
def zz2 = ZigZagHighLow("price h" = high, "price l" = low, "percentage reversal" = Minor_percentamount2, "absolute reversal" = Minor_revAmount2, "atr length" = Minor_atrlength2, "atr reversal" = Minor_atrreversal2);
def reversalAmount2 = if (close * Minor_percentamount2 / 100) > Max(Minor_revAmount2 < Minor_atrreversal2 * Minor_atrlength2, Minor_revAmount2) then (close * Minor_percentamount2 / 100) else if Minor_revAmount2 < Minor_atrreversal2 * Minor_atrlength2 then Minor_atrreversal2 * Minor_atrlength2 else Minor_revAmount2;
rec zzSave2 = if !IsNaN(zz2) then zz2 else GetValue(zzSave2, 1);
def chg2 = (if zzSave2 == high then high else low) - GetValue(zzSave2, 1);
def isUp2 = chg2 >= 0;
rec isConf2 = AbsValue(chg2) >= reversalAmount2 or (IsNaN(GetValue(zz2, 1)) and GetValue(isConf2, 1));
def zzd2 = if isUp2 then 1 else 0;
plot zzp2 = if zzd2 <= 1 then zz2 else Double.NaN;
#zzp.AssignValueColor(if zzd == 1 then Color.GREEN else if zzd == 0 then Color.RED else Color.DARK_ORANGE);
zzp2.SetDefaultColor(Color.WHITE);
zzp2.SetStyle(Curve.FIRM);
zzp2.EnableApproximation();
zzp2.SetLineWeight(1);
#Arrows
def zzL = if !IsNaN(zz) and !isUp then low else GetValue(zzL, 1);
def zzH = if !IsNaN(zz) and isUp then high else GetValue(zzH, 1);
def dir = CompoundValue(1, if zzL != zzL[1] or low == zzL[1] and low == zzSave then 1 else if zzH != zzH[1] or high == zzH[1] and high == zzSave then -1 else dir[1], 0);
def signal = CompoundValue(1, if dir > 0 and low > zzL then if signal[1] <= 0 then 1 else signal[1] else if dir < 0 and high < zzH then if signal[1] >= 0 then -1 else signal[1] else signal[1], 0);
input showarrows = yes;
plot U1 = showarrows and signal > 0 and signal[1] <= 0;
U1.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
U1.SetDefaultColor(Color.GREEN);
U1.SetLineWeight(4);
plot D1 = showarrows and signal < 0 and signal[1] >= 0;
D1.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
D1.SetDefaultColor(Color.RED);
D1.SetLineWeight(4);
#Alerts
input usealerts = no;
Alert(usealerts and U1, "ZIG-UP", Alert.BAR, Sound.Bell);
Alert(usealerts and D1, "ZAG-DOWN", Alert.BAR, Sound.Chimes);
#Supply Demand Areas
rec data1 = CompoundValue(1, if (zzSave == high or zzSave == low) then data1[1] + 1 else data1[1], 0);
def datacount1 = (HighestAll(data1) - data1[1]);
input numbersuppdemandtoshow = 1;
input showSupplyDemand = {default Pivot, Arrow, None};
def idx = if showSupplyDemand == showSupplyDemand.Pivot then 1 else 0;
def rLow;
def rHigh;
if signal crosses 0 {
rLow = low[idx];
rHigh = high[idx];
} else {
rLow = rLow[1];
rHigh = rHigh[1];
}
plot HighLine = if datacount1 <= numbersuppdemandtoshow and showSupplyDemand != showSupplyDemand.None and !IsNaN(close) and rHigh != 0 then rHigh else Double.NaN;
HighLine.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
HighLine.AssignValueColor(if signal > 0 then Color.GREEN else Color.RED);
plot LowLine = if datacount1 <= numbersuppdemandtoshow and showSupplyDemand != showSupplyDemand.None and !IsNaN(close) and rLow != 0 then rLow else Double.NaN;
LowLine.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
LowLine.AssignValueColor(if signal > 0 then Color.GREEN else Color.RED);
def hlUp = if signal > 0 then HighLine else Double.NaN;
def hlDn = if signal < 0 then HighLine else Double.NaN;
def zzL_Minor = if !IsNaN(zz2) and !isUp2 then low else GetValue(zzL_Minor, 1);
def zzH_Minor = if !IsNaN(zz2) and isUp2 then high else GetValue(zzH_Minor, 1);
def dir_Minor = CompoundValue(1, if zzL_Minor != zzL_Minor[1] or low == zzL_Minor[1] and low == zzSave2 then 1 else if zzH_Minor != zzH_Minor[1] or high == zzH_Minor[1] and high == zzSave2 then -1 else dir_Minor[1], 0);
def signal_Minor = CompoundValue(1, if dir_Minor > 0 and low > zzL_Minor then if signal_Minor[1] <= 0 then 1 else signal_Minor[1] else if dir_Minor < 0 and high < zzH_Minor then if signal_Minor[1] >= 0 then -1 else signal_Minor[1] else signal_Minor[1], 0);
#Minor Supply Demand Areas
rec data1_Minor = CompoundValue(1, if (zzSave2 == high or zzSave2 == low) then data1_Minor [1] + 1 else data1_Minor [1], 0);
def datacount1_Minor = (HighestAll(data1_Minor) - data1_Minor[1]);
input numbersuppdemandtoshow_Minor = 3;
input showSupplyDemand_Minor = {default Pivot, Arrow, None};
def idx_Minor = if showSupplyDemand_Minor == showSupplyDemand_Minor .Pivot then 1 else 0;
def rLow_Minor;
def rHigh_Minor;
if signal_Minor crosses 0 {
rLow_Minor = low[idx_Minor];
rHigh_Minor = high[idx_Minor];
} else {
rLow_Minor = rLow_Minor[1];
rHigh_Minor = rHigh_Minor[1];
}
#Minor
def zzh_minorBN = if high == zzH_Minor then BN else zzh_minorBN[1];
#addchartbubble(bn == zzh_minorBN, zzh_minorval, zzh_minorval,color.yellow);
def zzhcount = if BN == 1 then 0 else if BN == zzh_minorBN then zzhcount[1] + 1 else zzhcount[1];
def zzhcountMax = HighestAll(zzhcount);
def zzhRevCount = zzhcountMax - zzhcount + 1;
def ThirdPHCount = if zzhRevCount[1] == 5 and zzhRevCount == 4 then high else ThirdPHCount[1] ;
def ThirdPHCountBN = if zzhRevCount[1] == 5 and zzhRevCount == 4 then BN else ThirdPHCountBN[1] ;
AddChartBubble(BN == ThirdPHCountBN, ThirdPHCount, " 3 ", Color.GREEN);
def ThirdPH = ThirdPHCount;
def SecondPHCount = if zzhRevCount[1] == 4 and zzhRevCount == 3 then high else SecondPHCount[1] ;
def SecondPHCountBN = if zzhRevCount[1] == 4 and zzhRevCount == 3 then BN else SecondPHCountBN[1] ;
AddChartBubble(BN == SecondPHCountBN, SecondPHCount, " 2 ", Color.GREEN);
def SecondPH = SecondPHCount;
def FirstPHCount = if zzhRevCount[1] == 3 and zzhRevCount == 2 then high else FirstPHCount[1];
def FirstPHCountbn = if zzhRevCount[1] == 3 and zzhRevCount == 2 then BN else FirstPHCountbn[1] ;
AddChartBubble(BN == FirstPHCountbn, FirstPHCount, " 1 ", Color.GREEN);
def FirstPHHighestBN = highestall(FirstPHCountBN);
#def FirstPH = if bn == FirstPHCountbn then high else FirstPH[1];;
def FirstPH = FirstPHCount;
def zzl_minorBN = if low == zzL_Minor then BN else zzl_minorBN[1];
#addchartbubble(bn == zzl_minorBN, zzl_minorval, zzl_minorval,color.yellow);
def zzlcount = if BN == 1 then 0 else if BN == zzl_minorBN then zzlcount[1] + 1 else zzlcount[1];
def zzlcountMax = HighestAll(zzlcount);
def zzlRevCount = zzlcountMax - zzlcount + 1;
def ThirdPLCount = if zzlRevCount[1] == 5 and zzlRevCount == 4 then low else ThirdPLCount[1] ;
def ThirdPLCountBN = if zzlRevCount[1] == 5 and zzlRevCount == 4 then BN else ThirdPLCountBN[1] ;
AddChartBubble(BN == ThirdPLCountBN, ThirdPLCount, " 3 ", Color.RED, no);
def ThirdPL = ThirdPLCount;
def SecondPLCount = if zzlRevCount[1] == 4 and zzlRevCount == 3 then low else SecondPLCount[1] ;
def SecondPLCountBN = if zzlRevCount[1] == 4 and zzlRevCount == 3 then BN else SecondPLCountBN[1] ;
AddChartBubble(BN == SecondPLCountBN, SecondPLCount, " 2 ", Color.RED, no);
def SecondPL = SecondPLCount;
def FirstPLCount = if zzlRevCount[1] == 3 and zzlRevCount == 2 then low else FirstPLCount[1] ;
def FirstPLCountbn = if zzlRevCount[1] == 3 and zzlRevCount == 2 then BN else FirstPLCountBN[1] ;
AddChartBubble(BN == FirstPLCountbn, FirstPLCount, " 1 ", Color.RED, no);
def FirstPL = FirstPLCount;
input showsupplydemandcloud = yes;
AddCloud(if showsupplydemandcloud then hlUp else Double.NaN, LowLine, Color.LIGHT_GREEN, Color.LIGHT_GREEN);
AddCloud(if showsupplydemandcloud then hlDn else Double.NaN, LowLine, Color.LIGHT_RED, Color.LIGHT_RED);
#Store Previous Major Data
def zzsave1Major = if !IsNaN(zzSave) then zzSave else zzsave1Major[1];
def zzsave2Major = zzsave1Major;
rec priorzz1Major = if zzsave2Major != zzsave2Major[1] then zzsave2Major[1] else priorzz1Major[1];
rec priorzz2Major = if priorzz1Major != priorzz1Major[1] then priorzz1Major[1] else priorzz2Major[1];
rec priorzz3Major = if priorzz2Major != priorzz2Major[1] then priorzz2Major[1] else priorzz3Major[1];
#Highestall and Lowestall Major lines
def zzsave2highbn = if high == HighestAll(zzsave2Major) then BN else zzsave2highbn[1];
def highestall = HighestAll(zzsave2highbn);
def highestallprice = if BN == highestall then high else highestallprice[1];
plot highestallpriceline = if BN > highestall then highestallprice else Double.NaN;
#addchartbubble(bn==highestall,high,highestall,color.yellow);
highestallpriceline.SetDefaultColor(Color.LIGHT_GREEN);
highestallpriceline.SetPaintingStrategy(PaintingStrategy.LINE);
highestallpriceline.SetStyle(Curve.SHORT_DASH);
def zzsave2lowbn = if low == LowestAll(zzsave2Major) then BN else zzsave2lowbn[1];
def lowestall = HighestAll(zzsave2lowbn);
def lowestallprice = if BN == lowestall then low else lowestallprice[1];
plot lowestallpriceline = if BN > lowestall then lowestallprice else Double.NaN;
#addchartbubble(bn==lowestall,low,lowestall,color.white);
lowestallpriceline.SetDefaultColor(Color.PINK);
lowestallpriceline.SetPaintingStrategy(PaintingStrategy.LINE);
lowestallpriceline.SetStyle(Curve.SHORT_DASH);
#Volume at Reversals
def vol = if BarNumber() == 0 then 0 else volume + vol[1];
def vol1 = if BarNumber() == 1 then volume else vol1[1];
def xxvol = if zzSave == high or zzSave == low then TotalSum(volume) else xxvol[1];
def chgvol = if xxvol - xxvol[1] + vol1 == vol then vol else xxvol - xxvol[1];
input showBubblesVolume = no;
AddChartBubble(showBubblesVolume and !IsNaN(zz) and BarNumber() != 1, if isUp then high * (1 + Major_bubbleoffset) else low * (1 - Major_bubbleoffset), chgvol, if isUp and chghigh > 0 then Color.GREEN else if isUp and chghigh < 0 then Color.RED else if isUp then Color.YELLOW else if !isUp and chglow > 0 then Color.GREEN else if !isUp and chglow < 0 then Color.RED else Color.YELLOW, if isUp then yes else no );
########################################################
def h = high;
def L = low;
def UpH = HighestAll(FirstPH);
def Prev1UpH = HighestAll(SecondPH);
def Prev2UpH = HighestAll(ThirdPH);
def DnL = highestall(FirstPL);
def Prev1DnL = highestall(SecondPL);
def Prev2DnL = highestall(ThirdPL);
def FracLong = Prev2DnL < Prev1DnL and Prev1DnL > DnL and DnL > Prev2DnL and h[1] < h[2] and h > h[1] ;
def FracShort = Prev2UpH > Prev1UpH and Prev1UpH < UpH and UpH < Prev2UpH and l[1] > l[2] and l < l[1] ;
#Test Bubbles
#AddChartBubble(FracLong, high, "Signal Long", Color.GREEN);
#AddChartBubble(FracShort, low, "Signal Short", Color.RED);
def Entry = EntryPrice();
def EntryBN = if Entry then BN else EntryBN[1];
def FracLongAlert = Prev2DnL < Prev1DnL and Prev1DnL > L and L > Prev2DnL;
def FracShortAlert = Prev2UpH > Prev1UpH and Prev1UpH < h and h < Prev2UpH;
#def LE = FracLong;
def LE = if IsNaN(Entry) then FracLong else 0 ;
def LEBN = if LE then BN else LEBN[1];
def LowStop = if BN == LEBN then l else LowStop[1];
#def SE = FracShort;
def SE = if IsNaN(Entry) then FracShort else 0 ;
def SEBN = if SE then BN else SEBN[1];
def HighStop = if BN == SEBN then h else HighStop[1];
def lxstop = L < LowStop;
def lx = h > Entry * takeprofitconverstionLong ;
def sxstop = h > HighStop;
def sx = L < Entry * takeprofitconverstionshort ;
AddOrder(OrderType.BUY_TO_OPEN, Le[-1], arrowcolor = Color.WHITE, tickcolor = Color.CYAN, name = "LE", price = h);
AddOrder(OrderType.SELL_TO_CLOSE, lxstop[-1], tickcolor = Color.WHITE, arrowcolor = Color.MAGENTA, name = "LX Stop", price = l);
AddOrder(OrderType.SELL_TO_CLOSE, lx[-1], tickcolor = Color.WHITE, arrowcolor = Color.GREEN, name = "LX Profit", price = h);
AddOrder(OrderType.SELL_TO_OPEN, SE[-1], arrowcolor = Color.WHITE, tickcolor = Color.YELLOW, name = "SE", price = l);
AddOrder(OrderType.BUY_TO_CLOSE, sxstop[-1], tickcolor = Color.WHITE, arrowcolor = Color.MAGENTA, name = "SX Stop", price = h);
AddOrder(OrderType.BUY_TO_CLOSE, sx[-1], tickcolor = Color.WHITE, arrowcolor = Color.GREEN, name = "SX Profit", price = l);
