American Bulls

[haha54]

Hello,
I was just looking at the American Bulls website. Looking at the information posted they list "Buy Levels" and "Stop Loss Levels" Is there any program here that would replicate those Buy and Stop Loss levels with lines on a Daily Thinkorswim chart?
https://www.americanbulls.com/SignalPage.aspx?lang=en&Ticker=TSLA
Thanks for any help,

 

[traderLK]

haha54, according to their website's description and chart this appears to be a bullish Harami that generates a buy signal at the close of the current bar and stoploss at the close of the previous bar. It's an interesting little buying pattern. I believe it needs more filters for context and maybe stricter definition of the nature of the Harami to find the best versions of the pattern.

I've pasted a chart and script that recreates this signal. Buy at the blue line with stop at the red line.

I should note that TOS does have a Harami arrow indicator. It's not obvious because it's not in the regular list of indicators; it's under "Patterns" --> "Select Patterns" on the upper right side of the chart.

# Harami_AmBulls
# Question from haha54 on 10-17-23; bullish Harami with buy at close and sell at prev bar’s close

input price = close;
input offset1 = 1;

def Upclose = close > open;
def LastBarIsBear = close[1] < open[1];
def BodyEngulfed = close < open[1] and open > close[1];
def HighBar = high[2] > high[1];

plot Harami_AmBulls = Upclose and LastBarIsBear and BodyEngulfed and HighBar;
plot Buy = if Harami_AmBulls then close else double.NaN;
plot Buy01 = Buy[offset1];

plot Stop = if Harami_AmBulls then close[1] else double.NaN;
plot Stop01 = Stop[offset1];

Harami_AmBulls.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
Harami_AmBulls.SetDefaultColor(Color.MAGENTA);
Harami_AmBulls.SetLineWeight(3);

Buy.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Buy.SetDefaultColor(Color.BLUE);
Buy.SetLineWeight(2);
Stop.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Stop.SetDefaultColor(Color.RED);
Stop.SetLineWeight(2);

Buy01.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Buy01.SetDefaultColor(Color.BLUE);
Buy01.SetLineWeight(2);
Stop01.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Stop01.SetDefaultColor(Color.RED);
Stop01.SetLineWeight(2);