AAPL MSFT AMZN cumulative % change (from the open)

[grapetux]

Im attempting to make a label that will calculate the sum of the percentage change (from the open) on
MSFT, AAPL, AMZN. While this is a crude tool it will be nice to have a cumulative look at the market change in terms of these big 3 tickers (which make up ~30% of QQQ

example - MSFT +1%, AAPL -1%, AMZN +2% -- Label will show a positive 2% reading on the day.

Thanks for the help
cheers

 

[mashume]

Here's a lower and an upper for you. These only work on time charts (no tick charts)

declare lower;

def aapl = close(symbol = "AAPL");
def msft = close(symbol = "MSFT");
def amzn = close(symbol = "AMZN");

# addLabel(yes, "   " + aapl + "     " + msft + "      " + amzn);

def day_open = if secondsFromTime(0930) == 0
#  and secondsFromTime(0930)[1] < 0 
then 1 else 0;

def aapl_open = if day_open == 1 then aapl else aapl_open[1];
def msft_open = if day_open == 1 then msft else msft_open[1];
def amzn_open = if day_open == 1 then amzn else amzn_open[1];

# addLabel(yes, "   " + aapl_open + "     " + msft_open + "      " + amzn_open);

def aapl_change = (aapl - aapl_open) / aapl_open;
def msft_change = (msft - msft_open) / msft_open;
def amzn_change = (amzn - amzn_open) / amzn_open;

plot total_change = 
# if secondsFromTime(0930) >= 0 and secondsTillTime(1600) >= 0 then 
(aapl_change + msft_change + amzn_change) * 100
#  else double.nan
;

plot zero = 0;

AddLabel(yes, aspercent(total_change / 100), if total_change > 0 then color.green else if total_change < 0 then color.red else color.gray);

declare upper;

def aapl = close(symbol = "AAPL");
def msft = close(symbol = "MSFT");
def amzn = close(symbol = "AMZN");

def day_open = if secondsFromTime(0930) == 0 then 1 else 0;

def aapl_open = if day_open == 1 then aapl else aapl_open[1];
def msft_open = if day_open == 1 then msft else msft_open[1];
def amzn_open = if day_open == 1 then amzn else amzn_open[1];

def aapl_change = (aapl - aapl_open) / aapl_open;
def msft_change = (msft - msft_open) / msft_open;
def amzn_change = (amzn - amzn_open) / amzn_open;

def total_change = (aapl_change + msft_change + amzn_change);

AddLabel(yes, aspercent(total_change), if total_change > 0 then color.green else if total_change < 0 then color.red else color.gray);

the lower has some extra code in it for debugging that I removed from the cleaned up upper.

Happy Trading,
-mashume