2B Reversal Pattern (Expo) For ThinkOrSwim

[convertiblejay]

The author states:
█ Overview
The 2B reversal pattern, also called the "spring pattern", is a popular chart pattern professional traders use to identify potential trend reversals. It occurs when the price appears to be breaking down or up and then suddenly bounces back up/down, forming a "spring" or "false breakout" pattern. This pattern indicates that the trend is losing momentum and that a reversal is coming.

In a bearish market, the "spring pattern" occurs when the price of an asset breaks below a support level, causing many traders to sell their positions and causing the price to drop even further. However, the selling pressure eases at some point, and the price begins to rebound, "springing" back above the support level. This rebound creates a long opportunity for traders who can enter the market at a lower price.

In a bullish market, the "spring pattern" occurs when the price of an asset breaks above a resistance level, causing many traders to buy into the asset and drive the price up even further. However, the buying pressure eases at some point, and the price begins to decline, "springing" below the resistance level. This decline creates a selling opportunity for traders who can short the market at a higher price.

█ What are the benefits of using the 2B Reversal Pattern?
The benefits of using the 2B Reversal pattern as a trader include identifying potential buying or selling opportunities with reduced risk. By waiting for the price to "spring back" to the initial breakout level, traders can avoid entering the market too soon and minimize the risk of potential losses.

█ How to use
Traders can use the 2B reversal pattern to identify reversals. If the pattern occurs after an uptrend, traders may sell their long positions or enter a short position, anticipating a reversal to a downtrend. If the pattern occurs after a downtrend, traders may sell their short positions or enter a long position, anticipating a reversal to an uptrend.


█ Consolidation Strategy

First, traders should identify a period of price consolidation or a trading range where the price has been trading sideways for some time. The key feature of the "spring pattern" is a sudden, sharp move downward/upwards through the lower/upper boundary of this trading range, often accompanied by high volume.

However, instead of continuing to move lower/higher, the price then quickly recovers and moves back into the trading range, often on low volume. This quick recovery is the "spring" part of the pattern and suggests that the market has rejected the lower/higher price and that buying/selling pressure is building.

Traders may use the "spring pattern" as a signal to buy/sell the asset, suggesting strong demand/supply for the stock at the lower/higher price level. However, as with all trading strategies, it is important to use other indicators and to manage risk to minimize potential losses carefully.

I don't know if you guys are familiar with Vic Sperandeo. But I had some of his indicators a while back on MT4. Read more about this indicator here:
https://www.tradingview.com/script/dHb3Hn12-2B-Reversal-Pattern-Expo/?aff_id=27627

 

[samer800]

Hi guys,

I don't know if you guys are familiar with Vic Sperandeo. But I had some of his indicators a while back on MT4. But I did find some in trading view and was wondering if I can provide the link can someone please transcribe them to me for TOS? If they are already links out there I am sorry I missed them when searching and can someone provide them for me please.

This is one I found on TradingView if someone can covert it to TOS I would appreciate it.

https://www.tradingview.com/script/dHb3Hn12-2B-Reversal-Pattern-Expo/?aff_id=27627



Thank you,

check the below:

#//Indicator for TOS
#// © Zeiierman
#indicator("2B Reversal Pattern (Expo)",overlay=true,max_lines_count=500)
# Converted by Sam4Cok@Samer800    - 07/2024
#// ~~ Inputs {
input lookbackPeriod = 20;        # "Period"
input MaximumBreakLength = 10;    # "Maximum Break Length"
input MinimumBreakLengt = 3;      # "Minimum Break Length"

#// ~~ Variables
def na = Double.NaN;
def last = isNaN(close);

#//~~Funtions~~~~~}
Script Pivots {
    input series    = close;
    input leftBars  = 10;
    input rightBars = 10;
    input isHigh = yes;
    def na = Double.NaN;
    def HH = series == Highest(series, leftBars + 1);
    def LL = series == Lowest(series, leftBars + 1);
    def pivotRange = (leftBars + rightBars + 1);
    def leftEdgeValue = if series[pivotRange] ==0 then na else series[pivotRange];
    def pvtCond = !isNaN(series) and leftBars > 0 and rightBars > 0 and !isNaN(leftEdgeValue);
    def barIndexH = if pvtCond then
                    fold i = 1 to rightBars + 1 with p=1 while p do
                    series > GetValue(series, - i) else na;
    def barIndexL = if pvtCond then
                    fold j = 1 to rightBars + 1 with q=1 while q do
                    series < GetValue(series, - j) else na;
    def PivotPoint;
if isHigh {
    PivotPoint = if HH and barIndexH then series else na;
    } else {
    PivotPoint = if LL and barIndexL then series else na;
    }
    plot pvt = PivotPoint;
}
def pvtHi_ = Pivots(high[lookbackPeriod], lookbackPeriod, lookbackPeriod, yes);
def pvtLo_ = Pivots(low[lookbackPeriod], lookbackPeriod, lookbackPeriod, no);
def pvtHi = !isNaN(pvtHi_);
def pvtLo = !isNaN(pvtLo_);
def ph;
def pl;
def ph_ = if pvtHi then high[lookbackPeriod] else ph[1];
def pl_ = if pvtLo then low[lookbackPeriod] else pl[1];

#def breakout;
def bo;# = float(na)
def breakoutUp;
def breakoutDn;
def col;
def active;
def phCrossUp = (close > ph_) and (close[1] <= ph_[1]);
def plCrossDn = (close < pl_) and (close[1] >= pl_[1]);
def bo1;
def cnt;
#// ~~ Pattern Detection {
if phCrossUp {
    bo = low;
    cnt = 0;
    col = -1;
    ph = na;
    pl = pl_;
} else
if plCrossDn {
    bo = high;
    cnt = 0;
    col = 1;
    ph = ph_;
    pl = na;
 } else {
    cnt = cnt[1] + 1;
    bo =  if !active[1] then na else if(bo1[1], bo1[1], hl2);
    col = col[1];
    ph = ph_;
    pl = pl_;
}
def boCrossUp = (close > bo) and (close[1] <= bo[1]);
def boCrossDn = (close < bo) and (close[1] >= bo[1]);
def AnyCross  = boCrossUp or boCrossDn;

def plotCond =  cnt <= MaximumBreakLength and cnt >= MinimumBreakLengt;

if boCrossDn and plotCond {
    breakoutUp = no;
    breakoutDn = yes;
    bo1  = na;
} else
if boCrossUp and plotCond {
    breakoutUp = yes;
    breakoutDn = no;
    bo1  = na;
} else
if AnyCross {
    breakoutUp = no;
    breakoutDn = no;
    bo1  = na;
} else {
    breakoutUp = no;
    breakoutDn = no;
    bo1  = bo;
}
if !isNaN(bo1) {
    active = if cnt > MaximumBreakLength then no else yes;
} else {
    active = active[1];
}

#// ~~ Plots {
plot breakLine = if !last and bo1 and active then bo1 else na;#line1;
breakLine.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
breakLine.AssignValueColor(if col>0 then Color.GREEN else Color.RED);

AddChartBubble(BreakoutDn, high, "Break", Color.RED);
AddChartBubble(BreakoutUp, low, "Break", Color.GREEN, no);


#--- END