“Impossible” problem: Coding a hourly condition in a daily timeframe study???

[joetimismith]

I’m really stumped on this one.

I have this study that scans for a set of 2 candles that meet certain criteria in the daily time frame, like a bullish engulfing for example. Is there a way I can add a condition in the same study where the second candle's first hourly candle needs to have a greater move from its close minus open than the rest of the candles in that day combined (last hour's close minus second hour's open). Note that this second candle on the daily timeframe has to be green, meaning its close needs to be higher than the open.

If anyone can help me out with this, I really would appreciate it!

 

[MerryDay]

Welcome to the Forum @joetimismith You are right, what you want to do is impossible on the TOS platform

The Peculiarities Of Secondary Aggregations
The secondary aggregation period cannot be less than the chart that it is being displayed on. Higher timeframes can be used on lower timeframe charts but not the other way around.

FYI: The secondary aggregation period can not be referenced in scans on the TOS platform.
https://tlc.thinkorswim.com/center/...hapter-11---Referencing-Secondary-Aggregation

 

[tradecombine]

Note: While what you're asking for isn't possible, I've finagled a way to get a scan for stocks that meet your criteria, in the StockHacker.
Note: This only works end-of-day, as it's not time-of-day aware, and just uses offsets.
Note: You have to use two thinkscripts: one at HOURLY aggregation, and another at DAILY aggregation.
(I use this technique often, comparing the YEARLY/QUARTERLY/MONTHLY/WEEKLY to what's going on at lower time frames (DAILY, 4-HR, etc.), to help me spot good reversal candidates that have a chance of re-gaining their long-term trend.)

In StockHacker,
All of The Following:
Add Filter > Study > Custom > thinkScript Editor
Aggregation: DAILY

input length = 20;
input trendSetup = 3;

def BodyMax = Max(open(period = AggregationPeriod.DAY), close(period = AggregationPeriod.DAY));
def BodyMin = Min(open(period = AggregationPeriod.DAY), close(period = AggregationPeriod.DAY));
def IsEngulfing = BodyMax > BodyMax[1] and
    BodyMin < BodyMin[1];
def IsBlack = open(period = AggregationPeriod.DAY) > close(period = AggregationPeriod.DAY);
def IsWhite = open(period = AggregationPeriod.DAY) < close(period = AggregationPeriod.DAY);
def IsPrevDoji = IsDoji(length)[1];

def BullishEngulfing = IsDescending(close(period = AggregationPeriod.DAY), trendSetup)[1] and
    (IsBlack[1] or IsPrevDoji) and
    IsWhite and
    IsEngulfing;

plot scan = BullishEngulfing;

Then, also under "All of the Following"
Add Filter > Study > Custom > thinkScript Editor
Aggregation: 1h
Include Extended-hours trading session [UNCHECKED]

# SCAN END-OF-DAY
# ONE HOUR
#EXTENDED-HOURS = OFF
# This script assumes you're using an hourly chart, and it's END-OF-DAY, and looks for the last 7 bars on that chart. You might have UNEXPECTED results on different timeframes or different times of day.


## Get the close and open of first hourly candle
rec Bar1Open = open[6];
rec Bar1Close = close[6];

## Get the open of second hourly candle
rec Bar2Open = open[5];

## Get the close of LAST hourly candle
rec Bar7Close = close[0];

## FIRST HOURLY CANDLE has a bigger close to open move than the rest of the candles that day.
def Bar1BigMove = AbsValue(Bar1Close - Bar1Open) > AbsValue(Bar7Close - Bar2Open);

plot scan = Bar1BigMove;

Example of the scan (I sorted the results by Volume):

Hourly criteria met on $BTG:

Daily criteria met on $BTG: