Repaints Volume Multi Time Frame VMTF For ThinkOrSwim

[stocksniper]

This is a great Multi Time Frame volume indicator. Can anyone convert this to thinkorswim. https://www.tradingview.com/script/...09JOTJaVTIxTjg3aFJlRXJjUlowa0lLR3p5TlpFNVc4ZA..

 

[samer800]

Can anyone help converting this TradingView script above into TOS. Thanks in advance!

try below code. line direction reversed.

#// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
#// © LonesomeTheBlue
#study("Volume Multi Time Frame", "VMTF")
# Converted and mode by Sam4Cok@Samer800 - 11/2022

declare lower;
input ShowLines = yes;
input mode = {default "Auto", "User Defined"};            # "HTF Mode"
input ManualAgg = AggregationPeriod.DAY; # "Resolution (if HTF Mode is user-defined)"

def na = Double.NaN;
def agg = GetAggregationPeriod();
def day = GetDay();
def week = GetWeek();
def month = GetMonth();
def year = GetYear();
def oneMin  = AggregationPeriod.MIN;
def fiveMin = AggregationPeriod.FIVE_MIN;
def fifttenMin = AggregationPeriod.FIFTEEN_MIN;
def hour = AggregationPeriod.HOUR;
def twoHr  = AggregationPeriod.TWO_HOURS;
def fourHr = AggregationPeriod.FOUR_HOURS;
def day1   = AggregationPeriod.DAY;
def week1  = AggregationPeriod.WEEK;
def month1 = AggregationPeriod.MONTH;
def year1  = AggregationPeriod.YEAR;
#//auto higher time frame calculation
def HTFo = if agg == oneMin then fifttenMin / agg else
           if agg <= fiveMin then hour / agg else
           if agg <= twoHr then day1 / agg else
           if agg <= fourHr then week1 / agg else
           if agg <= day1 then month1 / agg else
           if agg <= month1 then year1 / agg else day1 / agg;
def AutoTF = if agg < fourHr then day else
             if agg < day1   then week else
             if agg < month1 then month else
             if agg < year1  then year else day;
def ManTF = if ManualAgg <= day1 then DAY else
            if ManualAgg <= week1 then MONTH else
            if ManualAgg < year1 then YEAR else day;
#--- Calc
def HTF = if mode == mode."Auto" then HTFo else ManualAgg / agg;
def TF  = if mode == mode."Auto" then AutoTF else ManTF;

def count = If(count[1] > HTF - 1 or TF != TF[1], 1, count[1] + 1);
def htfvol = fold i = 0 to count with p do
             p + GetValue(volume, i);
def OpenCandle = if count == 1 then open else OpenCandle[1];
def col = if close >= OpenCandle then 1 else 0;

def volValue = if htfvol > htfvol[1] then htfvol else na;
def line = CompoundValue(1, if htfvol > htfvol[1] then line[1] else volValue[1], volValue);

#--- Plot
def OpenLine = if count==1 then col[1] else OpenLine[1];
def Linecol = if OpenLine then  1 else 0;

plot volLine = if !ShowLines then na else line;
volLine.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
volLine.AssignValueColor(if Linecol then Color.GREEN  else Color.RED);

# Plot Hist
AddChart(high = if col then htfvol else na , low = 0 , open = htfvol,  close = 0,
         type = ChartType.CANDLE, growcolor =  CreateColor(0,152,0));

AddChart(high = if !col then htfvol else na  , low = 0 , open = htfvol,  close = 0,
         type = ChartType.CANDLE, growcolor =  CreateColor(128,0,0));

#--- End Code

 

[stocksniper]

Hey thank you so much

 

[novadolla]

what makes this repaint?

 

[MerryDay]

what makes this repaint?

All MTF indicators (ie: scripts that contain multiple timeframes) repaint.
Why? and what can you do about it?
https://usethinkscript.com/threads/make-mtf-indicators-not-repaint.15440/#post-125067

 

[rigsy1]

Hello All, is it possible to separate buy volume from sell volume? For example on 1.12.24 YMAB buying volume ended the day 689% above 50 day volume average and selling volume ended the day 203% above 50day volume average. I know everyone can caluclate this different. This indicator is really handy in letting me know at what time overall volume crossed above the 50 day volume MA but I would like to know how much cumulative selling volume as a percent of they 50 day volume ma was present at the time of crossing.
I have a separate watch list that tells me the buying volume percent vs the sell volume percent on the day but it would be nice to moniter cumalitvely on smaller timeframe chart.
Most of the day the selling volume as percent of the 50 day volume ma was very low and it wasn't until around 1pm that it exceeded past a certain high percentage like 100%. Knowing when selling volume gets up to a certain cumulative percentage of the 50 day moving average can help in exiting a trimming a position. I know Im talking percent vs share count but I will take either. Appreciate any help.

 

[MerryDay]

Hello All, is it possible to separate buy volume from sell volume? For example on 1.12.24 YMAB buying volume ended the day 689% above 50 day volume average and selling volume ended the day 203% above 50day volume average. I know everyone can caluclate this different. This indicator is really handy in letting me know at what time overall volume crossed above the 50 day volume MA but I would like to know how much cumulative selling volume as a percent of they 50 day volume ma was present at the time of crossing.
I have a separate watch list that tells me the buying volume percent vs the sell volume percent on the day but it would be nice to moniter cumalitvely on smaller timeframe chart.
Most of the day the selling volume as percent of the 50 day volume ma was very low and it wasn't until around 1pm that it exceeded past a certain high percentage like 100%. Knowing when selling volume gets up to a certain cumulative percentage of the 50 day moving average can help in exiting a trimming a position. I know Im talking percent vs share count but I will take either. Appreciate any help.

The ToS datafeeds do not provide buy / sell volume.