RSI with On Balance Volume OBV For ThinkorSwim?

[diazlaz]

@jon this looked interesting, not sure if it was the same scripts/code in this thread, but I quickly ported it. I added a 50 line to it, and quick observations on lower time frames, you can trade this with high probably, crossing from OB or OS to the 50 line, quick intraday trading.

#On Balance Volume RSI (OBV RSI) by @robswc
#An RSI, using OBV as the source, use to find divergence in the OBV to indicate reversals.
#Tutorial on youtube: https://youtu.be/klC8U2XLovs
#
# 2019.11.24 1.0 @diazlaz - Original Port
#

declare lower;

input length = 14;
input over_Bought = 70;
input over_Sold = 30;
input src = close;
input averageType = AverageType.WILDERS;
input showBreakoutSignals = no;

#net volume of positive and negative volume
def obv = if (src - src[1]) > 0 then volume else
if (src - src[1]) < 0 then -volume else 0 * volume;
def cnv = TotalSum(obv); #cumulative net volume
def price = cnv;

def NetChgAvg = MovingAverage(averageType, price - price[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(price - price[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

plot RSI = 50 * (ChgRatio + 1);
plot OverSold = over_Sold;
plot OverBought = over_Bought;
plot UpSignal = if RSI crosses above OverSold then OverSold else Double.NaN;
plot DownSignal = if RSI crosses below OverBought then OverBought else Double.NaN;

plot mid = 50;
mid.SetPaintingStrategy(paintingStrategy = PaintingStrategy.DASHES);
mid.AssignValueColor(COLOR.DARK_GRAY);

UpSignal.SetHiding(!showBreakoutSignals);
DownSignal.SetHiding(!showBreakoutSignals);

RSI.DefineColor("OverBought", GetColor(5));
RSI.DefineColor("Normal", GetColor(7));
RSI.DefineColor("OverSold", GetColor(1));
RSI.AssignValueColor(if RSI > over_Bought then RSI.color("OverBought") else
  if RSI < over_Sold then RSI.color("OverSold") else RSI.color("Normal"));

OverSold.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(8));
UpSignal.SetDefaultColor(Color.UPTICK);
UpSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignal.SetDefaultColor(Color.DOWNTICK);
DownSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

AddCloud(over_Bought, Over_Sold, Color.Light_Gray, Color.Light_Gray);

#END OF OBV RSI

 

[diazlaz]

Quick scalp system to the 50

If anyone improves it, test it or add more criteria please reply.

 

[tomsk]

Quick scalp system to the 50

If anyone improves it, test it or add more criteria please reply.

@diazlaz To make the OB/OS visually apparent, you might like to consider adding the following one liner to the end

AddCloud(over_Bought, Over_Sold, Color.Light_Gray, Color.Light_Gray);

 

[diazlaz]

@diazlaz To make the OB/OS visually apparent, you might like to consider adding the following one liner to the end

AddCloud(over_Bought, Over_Sold, Color.Light_Gray, Color.Light_Gray);

updated the script to include the AddCloud. thanks tomsk.

 

[tomsk]

updated the script to include the AddCloud. thanks tomsk.

Glad it helped

 

[roger80k]

Hi Guys,

Does anyone know if there is On Balance Volume (OBV) combined together with the RSI indicator for TOS?

Thank You

 

[roger80k]

Is there a way to have a divergence line plotted automatically on the OBV with RSI? If anyone can code it would be a life saver.

 

[Trading51]

stage three sell no Red arrows on the chart for Globex or cash on futures or stocks, the above code in post #24 must-have errors

 

[Trading51]

updated the script to include the AddCloud. thanks tomsk.

Is it possible to add another cloud so I can have the option to determine the upper and lower area separate basically two separate shaded areas one at the top and one at the bottom?

 

[venus360]

Thank you for sharing this code. Can someone help me made a few tweaks to this code?

Instead of plotting the RSI using Average.Wilders, I need to plot the following:

First I want to get sum of ticks gained for the periods that price went up for let us say 14 days (which can be stored in UpPoints)
Second, I want to get sum of ticks lost for the periods that price went down for the same 14 days (which can be stored in DownPoints)
Third I want to get the ratio of UpPoints/DownPoints.

I was looking for code snippets that can get me that sum. I am new to thinkscript.

Appreciate it.