Previous Large Move

[a1cturner]

Can't seem to figure out how to add an indicator for a previous large move. All I need is the coding to mark any prior move of 10% or more; up or down.

Keep getting an arrow on every candle with every code I try to write.

End goal is to mark every candle that has a large move and then add a label that shows RSI, MACD, Volume Increase, EMA Status, etc. Trying to make it easier to see a pattern.

I think I can handle the label part if I can just get some help coding the initial signal.

 

[halcyonguy]

Can't seem to figure out how to add an indicator for a previous large move. All I need is the coding to mark any prior move of 10% or more; up or down.

Keep getting an arrow on every candle with every code I try to write.

End goal is to mark every candle that has a large move and then add a label that shows RSI, MACD, Volume Increase, EMA Status, etc. Trying to make it easier to see a pattern.

I think I can handle the label part if I can just get some help coding the initial signal.

EDIT - i accidently pasted in boolean arrows. i deleted the word boolean , in the setpainting...

this will draw an arrow when there is a price change, greater than the set percent. default is 10%.

can pick 1 of 3 types of price changes,
bar_to_bar_close
open_to_close
low_to_high

a label shows the % and the change type

test bubbles show price and % change amount

# xpercent_move_0

# find 10% move

def bn = barnumber();
def na = double.nan;
input trigger_percent = 10.0;

def isup = open < close;
def isdwn = open > close;

input data_type = { default bar_to_bar_close, open_to_close, low_to_high };

def chg;
def per;
def type;
switch(data_type) {
case bar_to_bar_close:
  chg = if bn ==1 then 0 else close - close[1];
  per = round(100*chg/close[1],1);
  type = 1;
case open_to_close:
  chg = (close - open);
  per = round(100*chg/open, 1);
  type = 2;
case low_to_high:
  chg = if isdwn then (low - high) else (high - low);
  per = round(100*chg/low, 1);
  type = 3;
}

input show_label = yes;
addlabel( show_label, trigger_percent + "% move: " + (
     if data_type == data_type.bar_to_bar_close then "bar to bar close"
else if data_type == data_type.open_to_close then "open to close"
else if data_type == data_type.low_to_high then "low to high"
else "-") , color.yellow);

input show_arrows = yes;
def triggerup = if (show_arrows and per >= trigger_percent) then 1 else 0;
plot up = if triggerup then low else na;
up.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
up.SetDefaultColor(Color.green);
up.SetLineWeight(2);

def triggerdwn = if (show_arrows and per <= -trigger_percent) then 1 else 0;
plot dwn = if triggerdwn then high else na;
dwn.SetPaintingStrategy(PaintingStrategy.ARROW_down);
dwn.SetDefaultColor(Color.red);
dwn.SetLineWeight(2);

input test1_bubbles = yes;
addchartbubble(test1_bubbles and triggerup , low*0.99,
#bn + "\n" +
chg + "\n" +
per + "%"
, color.green, no);

addchartbubble(test1_bubbles and triggerdwn, high*1.01,
#bn + "\n" +
chg + "\n" +
per + "%"
, color.red, yes);
#

this has the bubbles turned on

 

[a1cturner]

That’s magic! Awesome work brother! I really appreciate that. Look forward to sharing my findings!

 

[ddtav478]

@halcyonguy do I make this code into a scanner only for bearish moves of 10% or more?