Need a bit of help

[Dean]

I am trying to create an indicator, but the code I am working with I cannot get to work. I want to create a moving midpoint line of the high and low for the first 2 hours of a 5m chart. This is what I have so far:

((Highest High of intraday) + (Lowest Low of Intraday)/2)

It would be a moving average of the first 2 hours of a 5m chart from 8:30 cst to 10:30 cst. Thanks for the help, I s-ck at this.

 

[SleepyZ]

I am trying to create an indicator, but the code I am working with I cannot get to work. I want to create a moving midpoint line of the high and low for the first 2 hours of a 5m chart. This is what I have so far:

((Highest High of intraday) + (Lowest Low of Intraday)/2)

It would be a moving average of the first 2 hours of a 5m chart from 8:30 cst to 10:30 cst. Thanks for the help, I s-ck at this.

The midpoint moves within the timeframe input at which point it will stop plotting unless you want to extend it at the input. If you choose to extend it, the value of the midpoint at the end of 2 hours will plot to the end of regular trading hours (1600).

You have options to just show only the last day and whether to show the plots of the high and low lines.

The image below has extended lines selected.

input ShowTodayOnly = yes;
input ORBegin       = 0930;
input OREnd         = 1130;
input extended      = yes;
input showhigh_low  = yes;

def ORActive = if SecondsTillTime(OREnd) > 0 and
                  SecondsFromTime(ORBegin) >= 0
               then 1
               else if SecondsFromTime(ORBegin)[1] < 0 and
                       SecondsFromTime(ORBegin) >= 0
               then 1
               else 0;

def ORHigh   = if ORHigh[1] == 0 or
                  ORActive[1] == 0 and
                  ORActive == 1
               then high
               else if ORActive and
                       high > ORHigh[1]
               then high
               else ORHigh[1];

def ORLow    = if ORLow[1] == 0 or
                  ORActive[1] == 0 and
                  ORActive == 1
               then low
               else if ORActive and
                       low < ORLow[1]
               then low
               else ORLow[1];

def ORHexp = if IsNaN(close)
             then ORHexp[1]
             else ORHigh;

def ORLexp = if IsNaN(close)
             then ORLexp[1]
             else ORLow;

plot ORH = if (ShowTodayOnly and
               GetDay() != GetLastDay())                
           then Double.NaN
           else if extended and SecondsFromTime(0930) > 0 and SecondsTillTime(1600) > 0
           then ORHexp[1]
           else if !extended and ORActive
           then ORHigh
           else Double.NaN;

plot ORL = if (ShowTodayOnly and
               GetDay() != GetLastDay())
           then Double.NaN
           else if extended and SecondsFromTime(0930) > 0 and SecondsTillTime(1600) > 0
           then ORLexp[1]
           else if !extended and ORActive
           then ORLow
           else Double.NaN;


plot MID = if (ShowTodayOnly and
               GetDay() != GetLastDay())
           then Double.NaN
           else (ORH + ORL) / 2;

ORH.SetDefaultColor(Color.GREEN);
ORH.SetPaintingStrategy(PaintingStrategy.LINE);
ORH.SetLineWeight(2);
ORH.sethiding(!showhigh_low);
ORL.sethiding(!showhigh_low);
ORL.SetDefaultColor(Color.RED);
ORL.SetPaintingStrategy(PaintingStrategy.LINE);
ORL.SetLineWeight(2);
MID.SetDefaultColor(Color.LIGHT_ORANGE);
MID.SetPaintingStrategy(PaintingStrategy.LINE);
MID.SetLineWeight(2);