Multi-TimeFrame (MTF) MACD Labels

[lindosskier]

Hi @SleepyZ, @tomsk, @BenTen ,

Can you please tell me what I’m doing wrong here?

I have this code painting my candles based on the MACD being above/below zero and also if the Value is above/below Avg (NOT JUST HIGHER/LOWER from the previous bar, but in relation to the Avg line), as you can see from the pic.

But when I try to use it, to create labels which will allow me to see what colors the candles are on higher timeframes (so when I’m on the 5min chart, I’d like to be able to see what colors are the bars on the 15min, 1H, 4H, 1D, 1W etc via colored labels on the top left) it doesn’t pain the correct labels. Can you please help me? Spent countless hours on this and cannot seem to know what’s wrong.

Thank you in advance for your help

input period = AggregationPeriod.HOUR;

input fastLength = 5;
input slowLength = 32;
input MACDLength = 5;
input averageType = AverageType.EXPONENTIAL;

def Value = MovingAverage(averageType, close, fastLength) -
MovingAverage(averageType, close, slowLength);
def Avg = MovingAverage(averageType, Value, MACDLength);

def Diff = Value - Avg;
plot ZeroLine = 0;
addlabel (yes, "H", if Diff >= 0 and Value > Avg then Color.Green else if Diff >= 0
and Value < Avg then Color.Cyan
else if Diff < 0 and Value < Avg then Color.Red else if Diff < 0 and Value > Avg
then Color.Orange else color.white);

 

[SleepyZ]

Hi @SleepyZ, @tomsk, @BenTen ,

Can you please tell me what I’m doing wrong here?

I have this code painting my candles based on the MACD being above/below zero and also if the Value is above/below Avg (NOT JUST HIGHER/LOWER from the previous bar, but in relation to the Avg line), as you can see from the pic.

But when I try to use it, to create labels which will allow me to see what colors the candles are on higher timeframes (so when I’m on the 5min chart, I’d like to be able to see what colors are the bars on the 15min, 1H, 4H, 1D, 1W etc via colored labels on the top left) it doesn’t pain the correct labels. Can you please help me? Spent countless hours on this and cannot seem to know what’s wrong.

Thank you in advance for your help

input period = AggregationPeriod.HOUR;

input fastLength = 5;
input slowLength = 32;
input MACDLength = 5;
input averageType = AverageType.EXPONENTIAL;

def Value = MovingAverage(averageType, close, fastLength) -
MovingAverage(averageType, close, slowLength);
def Avg = MovingAverage(averageType, Value, MACDLength);

def Diff = Value - Avg;
plot ZeroLine = 0;
addlabel (yes, "H", if Diff >= 0 and Value > Avg then Color.Green else if Diff >= 0
and Value < Avg then Color.Cyan
else if Diff < 0 and Value < Avg then Color.Red else if Diff < 0 and Value > Avg
then Color.Orange else color.white);

This uses the script function to help create MTF labels for the requested timeframes.

#MTF_MACD_Labels

script m {
    input agg = AggregationPeriod.HOUR;

    input fastLength = 5;
    input slowLength = 32;
    input MACDLength = 5;
    input averageType = AverageType.EXPONENTIAL;

    def Value = MovingAverage(averageType, close(period = agg), fastLength) -
MovingAverage(averageType, close(period = agg), slowLength);
    def Avg = MovingAverage(averageType, Value, MACDLength);

    def Diff = Value - Avg;

    plot x = if Diff >= 0 and Value > Avg then 1 else if Diff >= 0
and Value < Avg then 2
else if Diff < 0 and Value < Avg then 3 else if Diff < 0 and Value > Avg
then 4 else 0;
    plot ZeroLine = 0;
}

input agg1 = AggregationPeriod.FIFTEEN_MIN;
plot y1 = m(agg1).x;
AddLabel (yes, agg1 / 60000, if y1 == 1 then Color.GREEN else if y1 == 2 then Color.CYAN
else if y1 == 3 then Color.RED else if y1 == 4 then Color.ORANGE else Color.WHITE);

input agg2 = AggregationPeriod.HOUR;
plot y2 = m(agg2).x;
AddLabel (yes, "H", if y2 == 1 then Color.GREEN else if y2 == 2 then Color.CYAN
else if y2 == 3 then Color.RED else if y2 == 4 then Color.ORANGE else Color.WHITE);

input agg3 = AggregationPeriod.FOUR_HOURS;
plot y3 = m(agg3).x;
AddLabel (yes, "4H", if y3 == 1 then Color.GREEN else if y3 == 2 then Color.CYAN
else if y3 == 3 then Color.RED else if y3 == 4 then Color.ORANGE else Color.WHITE);

input agg4 = AggregationPeriod.DAY;
plot y4 = m(agg4).x;
AddLabel (yes, "D", if y4 == 1 then Color.GREEN else if y4 == 2 then Color.CYAN
else if y4 == 3 then Color.RED else if y4 == 4 then Color.ORANGE else Color.WHITE);

input agg5 = AggregationPeriod.WEEK;
plot y5 = m(agg5).x;
AddLabel (yes, "W", if y5 == 1 then Color.GREEN else if y5 == 2 then Color.CYAN
else if y5 == 3 then Color.RED else if y5 == 4 then Color.ORANGE else Color.WHITE);

#