Making the bubble color same as plot color

[stormy77]

This is probably a very easy question. I'm using code for EMA that someone here helped me fine tune. In this code I would like the bubble to be the same color as the plot line. I am able to choose the plot color from the options page, but not sure how to make the bubble the same color.
ALTERNATIVELY, if someone can show me how to fix the code so that I can also choose the color of the bubble

input price = close;

input length = 13;

input displace = 0;

input location = {default OffSet, LastBar, RightEdge};

input BubbleOffset = 5;

def bar = BarNumber();

def lb = if !IsNaN(close) and IsNaN(close()[-1]) then bar else Double.Nan;

def lastBar = highestAll(lb);

def position;

switch (location) {

case RightEdge:

position = bar == HighestAll(bar);

case LastBar:

position = bar == lastBar;

CASE Offset:

position = bar == lastbar + BubbleOffset;

}



plot ma1 = MovingAverage(AverageType.EXPONENTIAL, price, length);

#plot ma1 = MovAvgExponential(close (period = AggregationPeriod.DAY), length);

ma1.SetDefaultColor(Color.CYAN);

def data2 = if !IsNaN(ma1) then ma1 else data2[1];

AddChartBubble(position, data2, length + " EMA");

 

[Joshua]

AddChartBubble(position, data2, length + " EMA", ma1.takeValueColor());

plot ma1 = MovingAverage(AverageType.EXPONENTIAL, price, length);
Ma1.DefineColor("Bubble", Color.Red);
Ma1.DefineColor("Line", Color.Cyan);
Ma1.AssignValueColor(Ma1.Color("Line"));
def data2 = if !IsNaN(ma1) then ma1 else data2[1];
AddChartBubble(position, data2, length + " EMA",ma1.Color("Bubble"));

I also got rid of the BarNumber() and HighestAll() stuff for you.

input price = close;
input length = 13;
input displace = 0;
input location = {default OffSet, LastBar, RightEdge};
input BubbleOffset = 5;
def position;

switch (location) {
    case RightEdge:
        position =
            isNaN(close) and
            !isNaN(close[1])
        ;
    case LastBar:
        position =
            !isNaN(close) and
            isNaN(Close[-1])
        ;
    case Offset:
        position =
            isNaN(close) and
            isNaN(close[bubbleoffset - 1]) and
            !isNaN(close[bubbleoffset])
        ;
    ;
}
plot ma1 = MovingAverage(AverageType.EXPONENTIAL, price, length);
ma1.SetDefaultColor(Color.CYAN);
def data2 = if !IsNaN(ma1) then ma1 else data2[1];
AddChartBubble(position, data2, length + " EMA",ma1.takeValueColor());

 

[stormy77]

wow. thanks for cleaning up the code. Did not realize you could use "takeValueColor"..something I can use at other times