How do I scan for this kind of over extended stock?

[JJJJJJ11111]

how do i scan for stock

short :
high outside 2 std dev of bollinger band + 4 ATR up in less than 5 days

long :
low outside 2 std dev of bolloging band + 4 ATR down in less than 5 days

any help with this ?
thanks in advance.

mean reversion play

#short version
#BB
input price = close;
input displace = 0;
input length = 20;
input Num_Dev_Dn = -2.0;
input Num_Dev_up = 2.0;
input averageType = AverageType.Simple;

def sDev = stdev(data = price[-displace], length = length);

def MidLine = MovingAverage(averageType, data = price[-displace], length = length);
def LowerBand = MidLine + num_Dev_Dn * sDev;
def UpperBand = MidLine + num_Dev_Up * sDev;


#ATR

def ATR = MovingAverage(AverageType.WILDERS, TrueRange(high, close, low), 14);

plot scan = high[1]> upperband[1] and close/close[5] > 4*ATR ;



#longversion

#BB
input price = close;
input displace = 0;
input length = 20;
input Num_Dev_Dn = -2.0;
input Num_Dev_up = 2.0;
input averageType = AverageType.Simple;

def sDev = stdev(data = price[-displace], length = length);

def MidLine = MovingAverage(averageType, data = price[-displace], length = length);
def LowerBand = MidLine + num_Dev_Dn * sDev;
def UpperBand = MidLine + num_Dev_Up * sDev;


#ATR

def ATR = MovingAverage(AverageType.WILDERS, TrueRange(high, close, low), 14);

plot scan = low[1]< lowerband[1] and close/close[5] > 4*ATR ;

not sure if i'm getting the code right. but seem like it. anybody would like to try it out? or improve?

 

[traderLK]

Hi JJ, this script places a blue arrow for long signals and a red one for short signals. See chart below.

The Bollinger bands' parameters can be adjusted in the inputs and the ATR multiple (default is 4) and number of days ago (default = 5) are adjustable as well.

Set Long to be True in the stock scanner to scan for buy signals. Set Short to be True to scan for sell signals.

# ATRplusBBs_Scan
# question from JJJJJJ11111 - scanner for stocks, e.g., long signals when low is below the lower Bollinger band and close has decreased by 4 times the ATR in the last 5 price bars.

input price = close;
input length = 20;
input Num_Dev_Dn = -2.0;
input Num_Dev_Up = 2.0;
input averageType = AverageType.SIMPLE;
input atrlength = 14;
input averageType2 = AverageType.WILDERS;
input offset = 5;
input ATRmultiple = 4;

def sDev = stdev(data = price, length = length);
def MidLine = MovingAverage(averageType, data = price, length = length);
def LowerBand = MidLine + num_Dev_Dn * sDev;
def UpperBand = MidLine + num_Dev_Up * sDev;

def ATR = MovingAverage(averageType2, TrueRange(high, close, low), atrlength);

plot Long = low < LowerBand and close <= (close[offset] - (ATR[offset] * ATRmultiple));

plot Short = high > UpperBand and close > (close[offset] + (ATR[offset] * ATRmultiple));

Long.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
Long.SetDefaultColor(Color.BLUE);
Long.SetLineWeight(4);
Short.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
Short.SetDefaultColor(Color.RED);
Short.SetLineWeight(4);