Highest RSI in last hour

[P3m]

Meant SMA in the title not RSI sorry. (Edit)

For the life of me I can’t figure out how to get the highest value of the sma 200 for the last 60mins

I have read lots of the think or swim website but can’t get it to work.

I just need “what was the highest sma200 in the last hour”

I hope it’s something simple I’m just missing

Any help would be appreciated.

Thanks in advance!!!

 

[halcyonguy]

Meant SMA in the title not RSI sorry. (Edit)

For the life of me I can’t figure out how to get the highest value of the sma 200 for the last 60mins

I have read lots of the think or swim website but can’t get it to work.

I just need “what was the highest sma200 in the last hour”

I hope it’s something simple I’m just missing

Any help would be appreciated.

Thanks in advance!!!

i think i had this working before the TD update stopped my charts from loading.....
i was waiting to test it some more, but... here it is

# hi_ma200_prevhour_0
def na = double.nan;
def bn = barnumber();
def lastbar = if (!isnan(close) and isnan(close[-1])) then 1 else 0;

def barCount = HighestAll(If(IsNaN(close), 0, bn));

input minutes_back = 60;
input show_stat_labels = yes;
def chartagg = GetAggregationPeriod();
def chartmin = (chartagg / 1000) / 60;
AddLabel(show_stat_labels, "chartmin " + chartmin, Color.MAGENTA);
def timebarqty = roundup(minutes_back / chartmin, 0);
AddLabel(show_stat_labels, "bars per " + minutes_back + " min = " + timebarqty, Color.MAGENTA);

input show_avg = yes;
input avg1_len = 200;
input avg1_type =  AverageType.simple;
def ma1 = MovingAverage(avg1_type, close, avg1_len);
plot av = if show_avg then ma1 else na;
av.SetDefaultColor(Color.light_gray);
av.hidebubble();


def hi_ma = if (!isnan(close[-(timebarqty-1)]) and isnan(close[-timebarqty])) then
 highest(ma1[-(timebarqty-1)], timebarqty)
 else hi_ma[1];


AddLabel(show_stat_labels, "highest average value, in past " + minutes_back + " is " + hi_ma, Color.MAGENTA);

def hibarrng = if (!isnan(close) and isnan(close[-timebarqty])) then 1 else 0;
def hibar = if hibarrng and hi_ma == ma1 then 1 else 0;


plot z = hibar;
z.SetPaintingStrategy(PaintingStrategy.boolean_ARROW_DOWN);
z.SetDefaultColor(Color.green);
z.setlineweight(2);
z.hidebubble();

 

[xxnowayoutxx]

null