High low band MTF

[kc5560]

hello
can I have the High low band in multi time frame , (15 min, 5 min, 1 min)
This is SMA 20

def Period = AggregationPeriod.DAY;
def varhigh = high(period = Period);
def varlow = low(period = Period);

plot SMAH = SimpleMovingAvg(varhigh,20);
SMAH.AssignValueColor(Color.Green);
plot SMAL = SimpleMovingAvg(varlow,20);
SMAL.AssignValueColor(Color.Red);

 

[SleepyZ]

hello
can I have the High low band in multi time frame , (15 min, 5 min, 1 min)
This is SMA 20

def Period = AggregationPeriod.DAY;
def varhigh = high(period = Period);
def varlow = low(period = Period);

plot SMAH = SimpleMovingAvg(varhigh,20);
SMAH.AssignValueColor(Color.Green);
plot SMAL = SimpleMovingAvg(varlow,20);
SMAL.AssignValueColor(Color.Red);

You can change your def period to input period and add it multiple times as a study and change the input to the timeframes you want.

Or, you can use the script function as in the following code to create one study with varying timeframes.

Remember that the chart timeframe must be equal to or greater than the lowest timeframe in your code for the code to display on your chart.

script sma {
    input period = AggregationPeriod.DAY;

    def varhigh = high(period = period);
    def varlow = low(period = period);

    plot SMAH = SimpleMovingAvg(varhigh, 20);
    SMAH.AssignValueColor(Color.GREEN);
    plot SMAL = SimpleMovingAvg(varlow, 20);
    SMAL.AssignValueColor(Color.RED);
}
DefineGlobalColor("H", Color.GREEN);
DefineGlobalColor("L", Color.RED);

plot sma1h = sma(period = "MIN");
plot sma1l = sma(period = "MIN").SMAL;

plot sma5h = sma(period = "FIVE_MIN");
plot sma5l = sma(period = "FIVE_MIN").SMAL;

plot sma15h = sma(period = "FIFTEEN_MIN");
plot sma15l = sma(period = "FIFTEEN_MIN").SMAL;

sma1h.SetDefaultColor(GlobalColor("H"));
sma1l.SetDefaultColor(GlobalColor("L"));

sma5h.SetDefaultColor(GlobalColor("H"));
sma5l.SetDefaultColor(GlobalColor("L"));

sma15h.SetDefaultColor(GlobalColor("H"));
sma15l.SetDefaultColor(GlobalColor("L"));

input showbubbles = yes;
input bubblemover = 3;
def bm = bubblemover;
def bm1 = bm + 1;

AddChartBubble(showbubbles and IsNaN(close[bm]) and !IsNaN(close[bm1]), sma1h[bm1], "1m", GlobalColor("H"));
AddChartBubble(showbubbles and IsNaN(close[bm]) and !IsNaN(close[bm1]), sma1l[bm1], "1m", GlobalColor("L"));

AddChartBubble(showbubbles and IsNaN(close[bm]) and !IsNaN(close[bm1]), sma5h[bm1], "5m", GlobalColor("H"));
AddChartBubble(showbubbles and IsNaN(close[bm]) and !IsNaN(close[bm1]), sma5l[bm1], "5m", GlobalColor("L"));

AddChartBubble(showbubbles and IsNaN(close[bm]) and !IsNaN(close[bm1]), sma15h[bm1], "15m", GlobalColor("H"));
AddChartBubble(showbubbles and IsNaN(close[bm]) and !IsNaN(close[bm1]), sma15l[bm1], "15m", GlobalColor("L"));