Current price Channel

[britncguy]

Anyone have any ideas on how to make a 5% Current Price channel plot on the chart? I know I've seen similar channels on here before, but I'm on the struggle bus today.


So a price channel with 2 bands. Upper band is 5% above the high of current price and lower band is 5% below the low of the current price.

Thank you all!

 

[BenTen]

Try this:

# BenTen from usethinkscript.com
def difference = 5/100 * close;
plot upper_band = close + difference;
plot lower_band = close - difference;

This will plot two bands, 5% away from the current price.

 

[halcyonguy]

Anyone have any ideas on how to make a 5% Current Price channel plot on the chart? I know I've seen similar channels on here before, but I'm on the struggle bus today.

Thank you all!

if you want horizontal lines, across the whole chart, based on the current close price,

# priceline_channel_0

# draw a line at the last bar close

# a modified version of
#  Line At Price ,  Mobius
#  Alternative to using the HighestAll() function
# https://usethinkscript.com/threads/current-price-line-indicator-for-thinkorswim.8793/

def na = double.nan;

input last_offset = 0;
input show_line_at_last_close = yes;
def barsBack = 1000;
def x = !IsNaN(close[-last_offset]) and IsNaN(close[-(1+last_offset)]);
#def c = if !IsNaN(close[-last_offset]) and IsNaN(close[-(1+last_offset)])
def c = if x
        then close
        else c[1];
plot line = if show_line_at_last_close and isNaN(close[-barsBack])
            then c[-barsBack]
            else Double.NaN;
line.SetLineWeight(1);
line.SetDefaultColor(Color.LIME);
line.SetStyle(Curve.MEDIUM_DASH);

input percent_offset = 5.0;
plot y1 = line * (1 + percent_offset/100);
y1.SetDefaultColor(Color.cyan);
y1.setlineweight(1);
y1.hidebubble();

plot y2 = line * (1 - percent_offset/100);
y2.SetDefaultColor(Color.cyan);
y2.setlineweight(1);
y2.hidebubble();
#

 

[britncguy]

Looks Great, Thank you so much @BenTen!

Thanks for this. Looks Great @halcyonguy