Closing price of a Bar at a specific time

[kiwikev]

Hi,

I'm new here. Sorry for possibly asking something that's already been answered a million times.
How would I get the closing price at a specific time.

I am looking to grab the closing price of any bar at any random time that I specify.

So, what is the closing price at time 1655 est yesterday?
or What is the closing price at time 0937 est today?

This seem incredibly complicated than I thought it should be.

Thank you very much in advance!

 

[SleepyZ]

Hi,

I'm new here. Sorry for possibly asking something that's already been answered a million times.
How would I get the closing price at a specific time.

I am looking to grab the closing price of any bar at any random time that I specify.

So, what is the closing price at time 1655 est yesterday?
or What is the closing price at time 0937 est today?

This seem incredibly complicated than I thought it should be.

Thank you very much in advance!

With the following code, you can choose the method (manual date input or periods and how many), Time of Day, Pricetype and the closest price to the Time of Day. The chart you are using to find this should ideally have the Date or Period as part of the chart's timeframe displayed.

input timeofday   = 1032;
input pricetype   = {default close, high, low, open};


input method      = {Date, default Periods};
###
input Date        = 20220726;
###
input periodsback = 1;
def ymd           = GetYYYYMMDD();
def candles       = !IsNaN(close);
def capture       = candles and ymd != ymd[1];
def periodCount   = CompoundValue(1, if capture then periodCount[1] + 1 else periodCount[1], 0);
def thisperiod    = (HighestAll(periodCount) - periodCount) ;
###

def timewhen      = if SecondsTillTime(timeofday)[1] > 0 and
                       SecondsTillTime(timeofday) <= 0 or
                      (SecondsTillTime(timeofday)[1] < SecondsTillTime(timeofday) and
                       SecondsTillTime(timeofday)[1] > 0)
                    then 1
                    else 0                  
 ;


def pricewhen   = if method == method.Periods and            
                     thisperiod == periodsback and
                     timewhen
                  then Fundamental(pricetype)
                  else if method == method.Date and            
                          ymd == Date and
                          timewhen
                  then Fundamental(pricetype)
                  else pricewhen[1];

input showlabel   = yes;
AddLabel(showlabel, "When: " + method + " " + 
                    (if method == method.Date    
                     then AsPrice(Date) 
                     else periodsback + " days ago ") +
                     "@ " + asprice(timeofday) + " | Price: " + pricetype + ": " + pricewhen, Color.YELLOW);