accumulation distribution overbought/sold

[SJP07]

Would it be possible to edit this accumulation distribution buy percentage code to have overbought & oversold levels based off of the last 14 periods?
declare lower;

def data = if close > close[1] then close - Min(close[1], low) else if close < close[1] then close - Max(close[1], high) else 0;

Plot AccDist = TotalSum(data);

Thanks in advance!

 

[SleepyZ]

Would it be possible to edit this accumulation distribution buy percentage code to have overbought & oversold levels based off of the last 14 periods?
declare lower;

def data = if close > close[1] then close - Min(close[1], low) else if close < close[1] then close - Max(close[1], high) else 0;

Plot AccDist = TotalSum(data);

Thanks in advance!

This might help get you a starting point for OB/OS levels that you can adjust, if necessary. The OB is the max acctdist and OS is the min accdist during the lookback period in the code below

declare lower;

input lookback = 14;

def data = if close > close[1] then close - Min(close[1], low) else if close < close[1] then close - Max(close[1], high) else 0;

plot AccDist = TotalSum(data);
def bn  = BarNumber();
def lbn = HighestAll(if IsNaN(close[-1]) and !IsNaN(close)
          then bn else Double.NaN);
def ob  = if bn < lbn - lookback
          then Double.NaN
          else if bn == lbn - lookback 
          then AccDist
          else if bn <= lbn - 1
          then Max(ob[1], AccDist)
          else ob[1];
def os  = if bn < lbn - lookback
          then Double.NaN
          else if bn == lbn - lookback
          then AccDist
          else if bn <= lbn - 1
          then Min(os[1], AccDist)
          else os[1];

plot xob = highestAll(ob);
xob.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
plot xos = lowestAll(os);
xos.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

AddLabel(1, "OB: " + ob + " OS: " + os);